R_CollsHeadOfficePromiseToPay

@AbapCatalog: { sqlViewName: 'RCLLHOBP2P',
                compiler:    { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #PRIVILEGED_ONLY,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED },
                  privilegedAssociations: [ '_CreatedByContactCard',
                                            '_ChangedByContactCard',
                                            '_ClosedByContactCard' ] }
@EndUserText: { label: 'Head Ofice Promise to Pay' }
@VDM: { viewType:  #COMPOSITE,
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType:         { serviceQuality: #X,
                                     sizeCategory:   #L,
                                     dataClass:      #TRANSACTIONAL },
                semanticKey:       [ 'PromiseToPayUUID',
                                     'Customer',
                                     'CompanyCode' ],
                representativeKey: 'PromiseToPayUUID' }

define root view R_CollsHeadOfficePromiseToPay
  as select from I_CollsSgmtCompanyCodeAssgmt
    inner join   P_CollsPromiseToPayDraft on I_CollsSgmtCompanyCodeAssgmt.CompanyCode = P_CollsPromiseToPayDraft.CompanyCode

{

      // VDM Fields

  key I_CollsSgmtCompanyCodeAssgmt.CollectionSegment,
  key P_CollsPromiseToPayDraft.PromiseToPayUUID,
  key P_CollsPromiseToPayDraft.Customer,
  
      P_CollsPromiseToPayDraft.DraftUUID,
      P_CollsPromiseToPayDraft.CompanyCode,    
      P_CollsPromiseToPayDraft.ObjectType,
      P_CollsPromiseToPayDraft.LinkedInvoiceKey,

      @Semantics: { amount: { currencyCode: 'Currency' } }
      P_CollsPromiseToPayDraft.PromisedAmount,

      @Semantics: { amount: { currencyCode: 'Currency' } }
      P_CollsPromiseToPayDraft.PaidAmount,

      @Semantics: { currencyCode: true }
      P_CollsPromiseToPayDraft.Currency,

      P_CollsPromiseToPayDraft.DueDate,
      P_CollsPromiseToPayDraft.PromiseToPayDate,
      P_CollsPromiseToPayDraft.LastPaymentDate,
      P_CollsPromiseToPayDraft.PromiseToPayStatus,
      P_CollsPromiseToPayDraft.PromiseToPayLevel,
      P_CollsPromiseToPayDraft.PromiseToPayGivenByPersonName,

      @Semantics: { eMail: { address: true } }
      P_CollsPromiseToPayDraft.ContactPersonEmailAddress,

      @Semantics: { telephone: { type: [ #PREF ] } }
      P_CollsPromiseToPayDraft.ContactPersonPhoneNumber,

      @Semantics: { telephone: { type: [ #FAX ] } }
      P_CollsPromiseToPayDraft.ContactPersonFaxNumber,

      P_CollsPromiseToPayDraft.ContactPersonFaxCountry,
      cast( P_CollsPromiseToPayDraft.ContactPerson as parnr ) as ContactPerson,
      P_CollsPromiseToPayDraft.NumberOfInstallments,

      @Semantics: { amount: { currencyCode: 'Currency' } }
      P_CollsPromiseToPayDraft.PaidOnScheduleAmount,

      @Semantics: { amount: { currencyCode: 'Currency' } }
      P_CollsPromiseToPayDraft.PaidOffScheduleAmount,

      P_CollsPromiseToPayDraft.NextInstallmentDueDate,

      @Semantics: { amount: { currencyCode: 'Currency' } }
      P_CollsPromiseToPayDraft.NextInstallmentAmount,

      P_CollsPromiseToPayDraft.Prms2PToInvoiceGroupRefUUID,
      P_CollsPromiseToPayDraft.CaseID,
      P_CollsPromiseToPayDraft.CaseExternalReference,

      @ObjectModel: { foreignKey: { association: '_CreatedByContactCard' } }
      P_CollsPromiseToPayDraft.CaseCreatedBy,

      P_CollsPromiseToPayDraft.CaseCreatedOn,

      @ObjectModel: { foreignKey: { association: '_ChangedByContactCard' } }
      P_CollsPromiseToPayDraft.CaseLastChangedBy,

      P_CollsPromiseToPayDraft.CaseLastChangedOn,

      @ObjectModel: { foreignKey: { association: '_ClosedByContactCard' } }
      P_CollsPromiseToPayDraft.CaseClosedBy,

      P_CollsPromiseToPayDraft.CaseClosedTime,
      P_CollsPromiseToPayDraft.IsActiveEntity,
      P_CollsPromiseToPayDraft.HasActiveEntity,
      P_CollsPromiseToPayDraft.DraftCreationDateTime,
      P_CollsPromiseToPayDraft.DraftLastChangedDateTime,
      P_CollsPromiseToPayDraft.DraftAdministrativeDataUUID,
      P_CollsPromiseToPayDraft.CaseType,

      // Exposed Associations

      I_CollsSgmtCompanyCodeAssgmt._CollectionSegment,
      P_CollsPromiseToPayDraft._CaseAttribute,
      P_CollsPromiseToPayDraft._ChangedByContactCard,
      P_CollsPromiseToPayDraft._ClosedByContactCard,
      P_CollsPromiseToPayDraft._CollsPromiseToPayStatus,
      P_CollsPromiseToPayDraft._CompanyCode,
      P_CollsPromiseToPayDraft._Country,
      P_CollsPromiseToPayDraft._CreatedByContactCard,
      P_CollsPromiseToPayDraft._Currency,
      P_CollsPromiseToPayDraft._Customer,
      P_CollsPromiseToPayDraft._DraftAdministrativeData

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_COLLSSGMTCOMPANYCODEASSGMT",
"P_COLLSPROMISETOPAYDRAFT"
],
"ASSOCIATED":
[
"I_CASEATTRIBUTE",
"I_COLLECTIONSEGMENT",
"I_COLLSPROMISETOPAYSTATUS",
"I_COMPANYCODE",
"I_COUNTRY",
"I_CURRENCY",
"I_CUSTOMER",
"I_DRAFTADMINISTRATIVEDATA",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_COLLSSGMTCOMPANYCODEASSGMT",
"P_COLLSPROMISETOPAYDRAFT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/