R_CentralReqForQuotationItem

@VDM.viewType: #BASIC
@EndUserText.label: 'Restricted View for Central Request For Quotation Item'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@VDM.lifecycle.contract.type:#SAP_INTERNAL_API

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AbapCatalog.sqlViewName: 'RCNTRLRFQITEM'

@ObjectModel:{ representativeKey: 'CentralRequestForQuotationItem',
               semanticKey: 'CentralRequestForQuotationItem',
               usageType.dataClass: #TRANSACTIONAL,
               usageType.serviceQuality: #A,
               usageType.sizeCategory: #M
             }


define view R_CentralReqForQuotationItem
  as select from R_PurchasingDocumentItem

  association [1..1] to R_CentralRequestForQuotation  as _CentralRequestForQuotation  on  $projection.CentralRequestForQuotation = _CentralRequestForQuotation.CentralRequestForQuotation

  association [0..1] to I_PurchasingDocumentCategory  as _PurchasingDocumentCategory  on  $projection.PurchasingDocumentCategory = _PurchasingDocumentCategory.PurchasingDocumentCategory

  association [0..1] to I_IncotermsClassification     as _IncotermsClassification     on  $projection.IncotermsClassification = _IncotermsClassification.IncotermsClassification

  association [0..1] to I_Plant                       as _Plant                       on  $projection.Plant = _Plant.Plant

  association [0..1] to I_UnitOfMeasure               as _OrderQuantityUnit           on  $projection.OrderQuantityUnit = _OrderQuantityUnit.UnitOfMeasure

  association [0..*] to R_CntrlSupplierQuotationItem  as _CntrlSupplierQuotationItem  on  $projection.CentralRequestForQuotation     = _CntrlSupplierQuotationItem.CentralRequestForQuotation
                                                                                      and $projection.CentralRequestForQuotationItem = _CntrlSupplierQuotationItem.CentralRequestForQuotationItem
  association [0..1] to R_CntrlReqForQtanScheduleLine as _CntrlReqForQtanScheduleLine on  $projection.CentralRequestForQuotation     = _CntrlReqForQtanScheduleLine.CentralRequestForQuotation
                                                                                      and $projection.CentralRequestForQuotationItem = _CntrlReqForQtanScheduleLine.CentralRequestForQuotationItem
                                                                                      and _CntrlReqForQtanScheduleLine.ScheduleLine  = '0001'

  association [0..*] to R_CentralRFQItemDistribution  as _CentralRFQItemDistribution  on  $projection.CentralRequestForQuotation     = _CentralRFQItemDistribution.CentralRequestForQuotation
                                                                                      and $projection.CentralRequestForQuotationItem = _CentralRFQItemDistribution.CentralRequestForQuotationItem

{
      @ObjectModel: { readOnly: true,
                      foreignKey.association: '_CentralRequestForQuotation' }
  key R_PurchasingDocumentItem.PurchasingDocument                                                              as CentralRequestForQuotation,

      @ObjectModel: { readOnly: true }
  key cast (R_PurchasingDocumentItem.PurchasingDocumentItem as vdm_centralreqforquotationitem preserving type) as CentralRequestForQuotationItem,

      @ObjectModel: { readOnly: true,
                      foreignKey.association: '_PurchasingDocumentCategory' }
      R_PurchasingDocumentItem.PurchasingDocumentCategory,

      R_PurchasingDocumentItem.PurchasingDocumentItemText,

      @ObjectModel.foreignKey.association: '_ProductType'
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ProductTypeCode'
      ProductType,

      R_PurchasingDocumentItem.ProductTypeCode                                                                 as ProductTypeCode,

      R_PurchasingDocumentItem.ManufacturerMaterial,

      R_PurchasingDocumentItem.ManufacturerPartNmbr,

      R_PurchasingDocumentItem.Manufacturer,

      R_PurchasingDocumentItem.MaterialGroup,

      @ObjectModel: { foreignKey.association: '_Plant' }
      R_PurchasingDocumentItem.Plant,

      R_PurchasingDocumentItem.ManualDeliveryAddressID,

      R_PurchasingDocumentItem.ReferenceDeliveryAddressID,
      _Plant.AddressID,
      case
       when ManualDeliveryAddressID = '' or ManualDeliveryAddressID is null then
         case
         when ReferenceDeliveryAddressID = '' or ReferenceDeliveryAddressID is null then
            _Plant.AddressID
          else ReferenceDeliveryAddressID
        end
      else ManualDeliveryAddressID
      end                                                                                                      as ItemDeliveryAddressID,
      @ObjectModel: { foreignKey.association: '_IncotermsClassification' }
      R_PurchasingDocumentItem.IncotermsClassification,

      R_PurchasingDocumentItem.IncotermsTransferLocation,
      R_PurchasingDocumentItem.IncotermsLocation1,
      R_PurchasingDocumentItem.IncotermsLocation2,

      @Semantics.unitOfMeasure: true
      @ObjectModel: { foreignKey.association: '_OrderQuantityUnit' }
      R_PurchasingDocumentItem.OrderQuantityUnit,

      R_PurchasingDocumentItem.OrderItemQtyToBaseQtyNmrtr,
      R_PurchasingDocumentItem.OrderItemQtyToBaseQtyDnmntr,

      R_PurchasingDocumentItem.OrderPriceUnitToOrderUnitNmrtr,
      R_PurchasingDocumentItem.OrdPriceUnitToOrderUnitDnmntr,

      @Semantics.unitOfMeasure: true
      R_PurchasingDocumentItem.BaseUnit,

      R_PurchasingDocumentItem.PurchaseRequisition,
      R_PurchasingDocumentItem.PurchaseRequisitionItem,
      R_PurchasingDocumentItem.RequirementTracking,
      R_PurchasingDocumentItem.PurchasingCentralMaterial,

      @ObjectModel: { readOnly: true }
      R_PurchasingDocumentItem.PurchasingDocumentItemCategory,

      R_PurchasingDocumentItem.NetPriceAmount,
      R_PurchasingDocumentItem._ProductType,

      @Semantics.currencyCode: true
      DocumentCurrency,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
      _CentralRFQItemDistribution,

      /*Associations*/
      _CentralRequestForQuotation,
      _IncotermsClassification,
      _PurchasingDocumentCategory,
      _ManufacturerMaterial,
      _Manufacturer,
      _MaterialGroup,
      _Plant,
      _ManualDeliveryAddress_2 as _ManualDeliveryAddress,
      _ReferenceDeliveryAddress_2 as _ReferenceDeliveryAddress,
      _BaseUnit,
      _OrderQuantityUnit,
      _CntrlSupplierQuotationItem,
      _PurgDocumentItemCategory,
      _CntrlReqForQtanScheduleLine
}
where
  R_PurchasingDocumentItem.PurchasingDocumentCategory = 'N'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PLANT",
"R_PURCHASINGDOCUMENTITEM"
],
"ASSOCIATED":
[
"I_ADDRESS_2",
"I_INCOTERMSCLASSIFICATION",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_ORGANIZATIONADDRESS",
"I_PLANT",
"I_PRODUCTTYPECODE",
"I_PURCHASINGDOCUMENTCATEGORY",
"I_PURGDOCUMENTITEMCATEGORY",
"I_SUPPLIER",
"I_UNITOFMEASURE",
"R_CENTRALREQUESTFORQUOTATION",
"R_CENTRALRFQITEMDISTRIBUTION",
"R_CNTRLREQFORQTANSCHEDULELINE",
"R_CNTRLSUPPLIERQUOTATIONITEM"
],
"BASE":
[
"R_PURCHASINGDOCUMENTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/