R_PURCHASINGDOCUMENTITEM
Purchasing Document Item
R_PURCHASINGDOCUMENTITEM is a CDS View in S/4HANA. Purchasing Document Item. It contains 139 fields. 17 CDS views read from this table.
CDS Views using this table (17)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_MaintOrdOpOutlineAgrmtItemVH | view_entity | from | CONSUMPTION | Outline Agreement Item |
| I_PPS_PurchaseOrderItem | view_entity | from | BASIC | Interface for purchase order items |
| I_PurchaseOrderItem | view | from | BASIC | Purchase Order Item |
| I_RequestForQuotationItem | view | from | BASIC | Request For Quotation Item |
| I_SchedgAgrmtItm | view | from | BASIC | Scheduling Agreement Item |
| I_SupplierQuotationItem | view | from | BASIC | Supplier Quotation Item |
| P_LogcDocPurchaseItem | view_entity | from | CONSUMPTION | |
| P_PurContractItemMassUpdt | view | from | CONSUMPTION | Purchase Contract Item |
| P_PurContrHistory | view | from | CONSUMPTION | Purchase Contract History |
| P_PurDocItem | view | from | CONSUMPTION | View for Purchasing Document Item |
| R_CentralReqForQuotationItem | view | from | BASIC | Restricted View for Central Request For Quotation Item |
| R_CntrlPurchaseContractItem | view | from | BASIC | Central Purchase Contract Item |
| R_CntrlSupplierQuotationItem | view | from | BASIC | Restricted View for Central Supplier Quotation Item |
| R_PurchaseContractItem | view | from | BASIC | Purchase Contract Item Base view |
| R_PurchaseOrderItem | view | from | BASIC | Purchase Order Item Internal View |
| R_PurOrdHasItemHierarchy | view | from | COMPOSITE | Hierarchical items in Purchase order |
| R_PurOrdHasItemHierarchy | view | union_all | COMPOSITE | Hierarchical items in Purchase order |
Fields (139)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | PurchasingDocument | CentralRequestForQuotation,CentralSupplierQuotation,PurchaseContract,PurchasingDocument,RequestForQuotation,SchedulingAgreement,SupplierQuotation | 7 |
| KEY | PurchasingDocumentItem | PurchaseContractItem,PurchasingDocumentItem,SchedulingAgreementItem | 3 |
| _CompanyCode | _CompanyCode | 1 | |
| _IncotermsClassification | _IncotermsClassification | 1 | |
| _ProductType | _ProductType | 2 | |
| AccountAssignmentCategory | AccountAssignmentCategory | 3 | |
| BaseUnit | BaseUnit | 2 | |
| CompanyCode | CompanyCode | 3 | |
| CumulativeQuantityIsNotSent | CumulativeQuantityIsNotSent | 1 | |
| Customer | Customer | 2 | |
| DocumentCurrency | DocumentCurrency | 6 | |
| EvaldRcptSettlmtIsAllowed | EvaldRcptSettlmtIsAllowed | 3 | |
| FirmTradeOffZoneBindMRP | FirmTradeOffZoneBindMRP | 1 | |
| GoodsReceiptIsExpected | GoodsReceiptIsExpected | 3 | |
| GoodsReceiptIsNonValuated | GoodsReceiptIsNonValuated | 3 | |
| GrossAmount | GrossAmount | 1 | |
| IncotermsClassification | IncotermsClassification | 6 | |
| IncotermsLocation1 | IncotermsLocation1 | 6 | |
| IncotermsLocation2 | IncotermsLocation2 | 6 | |
| IncotermsSupChnDvtgLocAddlUUID | IncotermsSupChnDvtgLocAddlUUID | 2 | |
| IncotermsSupChnLoc1AddlUUID | IncotermsSupChnLoc1AddlUUID | 2 | |
| IncotermsSupChnLoc2AddlUUID | IncotermsSupChnLoc2AddlUUID | 2 | |
| IncotermsTransferLocation | IncotermsTransferLocation | 5 | |
| InternationalArticleNumber | InternationalArticleNumber | 1 | |
| InvoiceIsExpected | InvoiceIsExpected | 3 | |
| InvoiceIsGoodsReceiptBased | InvoiceIsGoodsReceiptBased | 3 | |
| IsEndOfPurposeBlocked | IsEndOfPurposeBlocked | 2 | |
| IsInfoAtRegistration | IsInfoAtRegistration | 1 | |
| IsOrderAcknRqd | IsOrderAcknRqd | 3 | |
| IsRelevantForJITDelivSchedule | IsRelevantForJITDelivSchedule | 1 | |
| IsStatisticalItem | IsStatisticalItem | 4 | |
| IsToBeAcceptedAtOrigin | IsToBeAcceptedAtOrigin | 2 | |
| ItemLastTransmissionDate | ItemLastTransmissionDate | 1 | |
| ItemNetWeight | ItemNetWeight | 1 | |
| LoadingPointForDelivery | LoadingPointForDelivery | 1 | |
| ManualDeliveryAddressID | ManualDeliveryAddressID | 5 | |
| Manufacturer | Manufacturer | 6 | |
| ManufacturerMaterial | ManufacturerMaterial | 5 | |
| ManufacturerPartNmbr | ManufacturerPartNmbr | 6 | |
| Material | Material | 5 | |
| MaterialGroup | MaterialGroup | 7 | |
| MaterialType | MaterialType | 3 | |
| MinRemainingShelfLife | MinRemainingShelfLife | 1 | |
| MRPArea | MRPArea | 1 | |
| MultipleAcctAssgmtDistribution | MultipleAcctAssgmtDistribution | 2 | |
| NetPriceAmount | ContractNetPriceAmount,NetPriceAmount | 4 | |
| NetPriceQuantity | NetPriceQuantity | 3 | |
| NextFcstDelivSchedSendingDate | NextFcstDelivSchedSendingDate | 1 | |
| NextJITDelivSchedSendingDate | NextJITDelivSchedSendingDate | 1 | |
| NoDaysReminder1 | NoDaysReminder1 | 3 | |
| NoDaysReminder2 | NoDaysReminder2 | 3 | |
| NoDaysReminder3 | NoDaysReminder3 | 3 | |
| OrderItemQtyToBaseQtyDnmntr | OrderItemQtyToBaseQtyDnmntr | 2 | |
| OrderItemQtyToBaseQtyNmrtr | OrderItemQtyToBaseQtyNmrtr | 2 | |
| OrderPriceUnit | OrderPriceUnit,OrdPrcUnitToOrderUnitNmrtrUoM | 3 | |
| OrderPriceUnitToOrderUnitNmrtr | OrderPriceUnitToOrderUnitNmrtr | 2 | |
| OrderQuantityUnit | OrderQuantityUnit,OrdPrcUnitToOrderUnitDnmntrUoM | 6 | |
| OrdPriceUnitToOrderUnitDnmntr | OrdPriceUnitToOrderUnitDnmntr | 4 | |
| OverdelivTolrtdLmtRatioInPct | OverdelivTolrtdLmtRatioInPct | 3 | |
| PartialInvoiceDistribution | PartialInvoiceDistribution | 2 | |
| PlannedDeliveryDurationInDays | PlannedDeliveryDurationInDays | 1 | |
| Plant | Plant | 8 | |
| PlndOrderReplnmtElmntType | PlndOrderReplnmtElmntType,SchedgAgrmtItmReplnmtElmntType | 2 | |
| PriceIsToBePrinted | PriceIsToBePrinted | 3 | |
| ProcmtHubExtReferencedMaterial | ProcmtHubExtReferencedMaterial | 1 | |
| ProcmtHubRefcdConnectedSystem | ProcmtHubRefcdConnectedSystem | 1 | |
| Product | Product | 1 | |
| ProductCharacteristic1 | ProductCharacteristic1 | 1 | |
| ProductCharacteristic2 | ProductCharacteristic2 | 1 | |
| ProductCharacteristic3 | ProductCharacteristic3 | 1 | |
| ProductCollection | ProductCollection | 1 | |
| ProductGroup | ProductGroup | 1 | |
| ProductSeason | ProductSeason | 1 | |
| ProductSeasonYear | ProductSeasonYear | 1 | |
| ProductTheme | ProductTheme | 1 | |
| ProductType | ProductType,ProductTypeCode | 2 | |
| ProductTypeCode | ProductTypeCode | 4 | |
| PurchaseContract | PurchaseContract | 1 | |
| PurchaseContractItem | PurchaseContractItem | 1 | |
| PurchaseRequisition | PurchaseRequisition | 7 | |
| PurchaseRequisitionItem | PurchaseRequisitionItem | 7 | |
| PurchasingCentralMaterial | PurchasingCentralMaterial | 3 | |
| PurchasingDocumentCategory | PurchasingDocumentCategory | 6 | |
| PurchasingDocumentDeletionCode | PurchasingContractDeletionCode,PurchasingDocumentDeletionCode | 3 | |
| PurchasingDocumentItemCategory | PurchasingDocumentItemCategory | 7 | |
| PurchasingDocumentItemText | PurchaseContractItemText,PurchasingDocumentItemText | 7 | |
| PurchasingDocumentItemUniqueID | PurchaseContractItemUniqueID | 1 | |
| PurchasingInfoRecord | PurchasingInfoRecord | 4 | |
| PurchasingInfoRecordUpdateCode | IsInfoRecordUpdated,PurchasingInfoRecordUpdateCode | 5 | |
| PurchasingIsCatalogRelevant | PurchasingIsCatalogRelevant | 1 | |
| PurchasingParentItem | PurchasingParentItem | 5 | |
| PurchasingPriceIsEstimated | PurchasingPriceIsEstimated,PurgDocEstimatedPrice | 3 | |
| PurgConfigurableItemNumber | PurgConfigurableItemNumber | 4 | |
| PurgDocAggrgdSubitemCategory | PurgDocAggrgdSubitemCategory | 4 | |
| PurgDocItemRenegotiationStatus | PurgDocItemRenegotiationStatus | 1 | |
| PurgDocItmBlkRsnCode | PurgDocItmBlkRsnCode | 1 | |
| PurgDocItmTargetAmount | CntrlPurContrItmTargetAmount | 1 | |
| PurgDocOrderAcknNumber | PurgDocOrderAcknNumber | 3 | |
| PurgDocPriceDate | PurgDocPriceDate | 2 | |
| PurgDocReleaseOrderQuantity | PurgDocReleaseOrderQuantity | 2 | |
| PurgExternalSortNumber | PurgExternalSortNumber | 4 | |
| PurgProdCmplncDngrsGoodsStatus | PurgProdCmplncDngrsGoodsStatus | 1 | |
| PurgProdCmplncSupplierStatus | PurgProdCmplncSupplierStatus | 2 | |
| PurgProductMarketabilityStatus | PurgProductMarketabilityStatus | 1 | |
| PurgSafetyDataSheetStatus | PurgSafetyDataSheetStatus | 1 | |
| QualityCertificateType | QualityCertificateType | 1 | |
| QualityMgmtCtrlKey | QualityMgmtCtrlKey | 1 | |
| ReferenceDeliveryAddressID | ReferenceDeliveryAddressID | 5 | |
| RequestForQuotation | CentralRequestForQuotation,RequestForQuotation | 2 | |
| RequestForQuotationItem | CentralRequestForQuotationItem,RequestForQuotationItem | 2 | |
| RequirementTracking | RequirementTracking | 6 | |
| SchedAgrmtAgreedCumQty | SchedAgrmtAgreedCumQty | 1 | |
| SchedAgrmtCumQtyReconcileDate | SchedAgrmtCumQtyReconcileDate | 1 | |
| SchedAgrmtCumulativeQtyControl | SchedAgrmtCumulativeQtyControl | 1 | |
| SchedgAgrmtRelCreationProfile | SchedgAgrmtRelCreationProfile | 1 | |
| SchedLineSemiFirmOrderInDays | SchedLineSemiFirmOrderInDays | 1 | |
| ScheduleLineFirmOrderInDays | ScheduleLineFirmOrderInDays | 1 | |
| ServicePackage | ServicePackage | 1 | |
| ServicePerformer | ServicePerformer | 2 | |
| ShippingInstruction | ShippingInstruction | 3 | |
| ShippingType | ShippingType | 1 | |
| StockSegment | StockSegment | 1 | |
| StockType | StockType | 3 | |
| StorageLocation | StorageLocation | 3 | |
| Subcontractor | Subcontractor | 3 | |
| SupplierConfirmationControlKey | ConfirmationControl,SupplierConfirmationControlKey | 3 | |
| SupplierIsSubcontractor | SupplierIsSubcontractor | 1 | |
| SupplierMaterialNumber | SupplierMaterialNumber | 5 | |
| SupplierSubrange | SupplierSubrange | 1 | |
| TargetAmount | TargetAmount | 3 | |
| TargetQuantity | TargetQuantity | 3 | |
| TaxCode | TaxCode | 3 | |
| TaxCodeValidFromDate | TaxCodeValidFromDate | 1 | |
| TaxCountry | TaxCountry | 2 | |
| TaxDeterminationDate | TaxDeterminationDate | 2 | |
| UnderdelivTolrtdLmtRatioInPct | UnderdelivTolrtdLmtRatioInPct | 3 | |
| UnlimitedOverdeliveryIsAllowed | UnlimitedOverdeliveryIsAllowed | 3 | |
| VolumeUnit | VolumeUnit | 2 | |
| WeightUnit | WeightUnit | 1 |
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Purchasing Document Item'
@AccessControl.authorizationCheck:#PRIVILEGED_ONLY
@AccessControl.privilegedAssociations: [ '_ManualDeliveryAddress', '_ReferenceDeliveryAddress', '_ManualDeliveryAddress_2', '_ReferenceDeliveryAddress_2' ]
@AccessControl.personalData.blocking:#REQUIRED
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'RMMPURGDOCITEM'
@AbapCatalog.preserveKey: true
@ObjectModel.representativeKey: 'PurchasingDocumentItem'
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AbapCatalog.compiler.compareFilter: true
define view R_PurchasingDocumentItem
as select from ekpo
association [1..1] to R_PurchasingDocument as _PurchasingDocument on $projection.PurchasingDocument = _PurchasingDocument.PurchasingDocument
association [0..*] to I_PurgDocScheduleLine as _ScheduleLine on $projection.PurchasingDocument = _ScheduleLine.PurchasingDocument
and $projection.PurchasingDocumentItem = _ScheduleLine.PurchasingDocumentItem
association [0..1] to I_Purchaserequisition as _PurchaseRequisition on $projection.PurchaseRequisition = _PurchaseRequisition.PurchaseRequisition
association [0..1] to I_Purchaserequisitionitem as _PurchaseRequisitionItem on $projection.PurchaseRequisition = _PurchaseRequisitionItem.PurchaseRequisition
and $projection.PurchaseRequisitionItem = _PurchaseRequisitionItem.PurchaseRequisitionItem
association [0..1] to I_PurchaseContract as _PurchaseContract on $projection.PurchaseContract = _PurchaseContract.PurchaseContract
association [0..1] to I_PurchaseContractItem as _PurchaseContractItem on $projection.PurchaseContract = _PurchaseContractItem.PurchaseContract
and $projection.PurchaseContractItem = _PurchaseContractItem.PurchaseContractItem
association [0..1] to I_PurchasingInfoRecordApi01 as _PurchasingInfoRecord on $projection.PurchasingInfoRecord = _PurchasingInfoRecord.PurchasingInfoRecord
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [0..1] to I_StorageLocation as _StorageLocation on $projection.Plant = _StorageLocation.Plant
and $projection.StorageLocation = _StorageLocation.StorageLocation
association [0..1] to I_Material as _Material on $projection.Material = _Material.Material
association [0..1] to I_Product as _Product on $projection.Product = _Product.Product
association [0..1] to I_Material as _ManufacturerMaterial on $projection.ManufacturerMaterial = _ManufacturerMaterial.Material
association [0..1] to I_Material as _ConfigurableProduct on $projection.CrossPlantConfigurableProduct = _ConfigurableProduct.Material
association [0..1] to I_ProductGroup_2 as _ProductGroup on $projection.ProductGroup = _ProductGroup.ProductGroup
association [0..1] to I_MaterialGroup as _MaterialGroup on $projection.MaterialGroup = _MaterialGroup.MaterialGroup
association [0..1] to I_UnitOfMeasure as _BaseUnit on $projection.BaseUnit = _BaseUnit.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _OrderQuantityUnit on $projection.OrderQuantityUnit = _OrderQuantityUnit.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _VolumeUnit on $projection.VolumeUnit = _VolumeUnit.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _WeightUnit on $projection.WeightUnit = _WeightUnit.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _OrderPriceUnit on $projection.OrderPriceUnit = _OrderPriceUnit.UnitOfMeasure
association [0..1] to I_Address as _ManualDeliveryAddress on $projection.ManualDeliveryAddressID = _ManualDeliveryAddress.AddressID
association [0..1] to I_OrganizationAddress as _ManualDeliveryAddress_2 on $projection.ManualDeliveryAddressID = _ManualDeliveryAddress_2.AddressID
and _ManualDeliveryAddress_2.AddressPersonID = ' '
and _ManualDeliveryAddress_2.AddressRepresentationCode = ' '
association [0..1] to I_Address as _ReferenceDeliveryAddress on $projection.ReferenceDeliveryAddressID = _ReferenceDeliveryAddress.AddressID
association [0..1] to I_Address_2 as _ReferenceDeliveryAddress_2 on $projection.ReferenceDeliveryAddressID = _ReferenceDeliveryAddress_2.AddressID
and _ReferenceDeliveryAddress_2.AddressPersonID = ' '
and _ReferenceDeliveryAddress_2.AddressRepresentationCode = ' '
association [0..1] to I_PurchasingDocumentCategory as _PurgDocumentCategory on $projection.PurchasingDocumentCategory = _PurgDocumentCategory.PurchasingDocumentCategory
association [0..1] to I_PurgDocumentItemCategory as _PurgDocumentItemCategory on $projection.PurchasingDocumentItemCategory = _PurgDocumentItemCategory.PurchasingDocumentItemCategory
association [0..1] to I_Supplier as _Manufacturer on $projection.Manufacturer = _Manufacturer.Supplier
association [0..1] to I_Supplier as _Subcontractor on $projection.Subcontractor = _Subcontractor.Supplier
association [0..1] to I_Supplier as _PriorSupplier on $projection.PriorSupplier = _PriorSupplier.Supplier
association [0..1] to I_Customer as _Customer on $projection.Customer = _Customer.Customer
association [0..1] to I_IncotermsClassification as _IncotermsClassification on $projection.IncotermsClassification = _IncotermsClassification.IncotermsClassification
association [0..1] to I_BusinessPartner as _ServicePerformer on $projection.ServicePerformer = _ServicePerformer.BusinessPartner
association [0..1] to I_ProductTypeCode as _ProductType on $projection.ProductType = _ProductType.ProductTypeCode
association [0..1] to I_ProductCategory as _ProductCategory on $projection.ArticleCategory = _ProductCategory.ProductCategory
association [0..1] to I_AccountAssignmentCategory as _AccountAssignmentCategory on $projection.AccountAssignmentCategory = _AccountAssignmentCategory.AccountAssignmentCategory
association [0..1] to I_ConsumptionPosting as _ConsumptionPosting on $projection.ConsumptionPosting = _ConsumptionPosting.ConsumptionPosting
association [0..1] to I_AllocationTable as _AllocationTable on $projection.AllocationTable = _AllocationTable.AllocationTable
association [0..1] to I_AllocationTableItem as _AllocationTableItem on $projection.AllocationTableItem = _AllocationTableItem.AllocationTableItem
and $projection.AllocationTable = _AllocationTableItem.AllocationTable
association [0..1] to I_RetailPromotion as _RetailPromotion on $projection.RetailPromotion = _RetailPromotion.RetailPromotion
association [0..1] to E_PurchasingDocumentItem as _ItemExtension on $projection.PurchasingDocument = _ItemExtension.PurchasingDocument
and $projection.PurchasingDocumentItem = _ItemExtension.PurchasingDocumentItem
----Brazil Extension Associations
association [0..1] to I_BR_MaterialOrigin as _BR_MaterialOrigin on _BR_MaterialOrigin.BR_MaterialOrigin = $projection.BR_MaterialOrigin
association [0..1] to I_BR_MaterialUsage as _BR_MaterialUsage on _BR_MaterialUsage.BR_MaterialUsage = $projection.BR_MaterialUsage
association [0..1] to I_BR_CFOPCategory as _BR_CFOPCategory on _BR_CFOPCategory.BR_CFOPCategory = $projection.BR_CFOPCategory
association [0..1] to I_BR_NCM as _BR_NCM on _BR_NCM.CountryCode = 'BR'
and _BR_NCM.BR_NCM = $projection.BR_NCM
{
@ObjectModel.foreignKey.association: '_PurchasingDocument'
key ekpo.ebeln as PurchasingDocument,
key ekpo.ebelp as PurchasingDocumentItem,
ekpo.uniqueid as PurchasingDocumentItemUniqueID,
@ObjectModel.foreignKey.association: '_PurgDocumentCategory'
ekpo.bstyp as PurchasingDocumentCategory,
ekpo.loekz as PurchasingDocumentDeletionCode,
ekpo.statu as PurchasingDocumentItemOrigin,
ekpo.creationdate as PurchasingDocumentCreationDate,
ekpo.creationtime as PurchasingDocumentCreationTime,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'Product'
@ObjectModel.foreignKey.association: '_Material'
ekpo.matnr as Material,
@ObjectModel.foreignKey.association: '_Product'
cast (ekpo.matnr as productnumber preserving type ) as Product,
ekpo.idnlf as SupplierMaterialNumber,
@ObjectModel.foreignKey.association: '_ManufacturerMaterial'
ekpo.ematn as ManufacturerMaterial,
ekpo.mfrpn as ManufacturerPartNmbr,
@ObjectModel.foreignKey.association: '_Manufacturer'
ekpo.mfrnr as Manufacturer,
@Semantics.text: true
ekpo.txz01 as PurchasingDocumentItemText,
@ObjectModel.foreignKey.association: '_CompanyCode'
ekpo.bukrs as CompanyCode,
@ObjectModel.foreignKey.association: '_Plant'
ekpo.werks as Plant,
@ObjectModel.foreignKey.association: '_ManualDeliveryAddress'
ekpo.adrnr as ManualDeliveryAddressID,
@ObjectModel.foreignKey.association: '_ReferenceDeliveryAddress'
ekpo.adrn2 as ReferenceDeliveryAddressID,
@ObjectModel.foreignKey.association: '_Customer'
ekpo.kunnr as Customer,
@ObjectModel.foreignKey.association: '_Subcontractor'
ekpo.emlif as Subcontractor,
ekpo.lblkz as SupplierIsSubcontractor,
@ObjectModel.foreignKey.association: '_ConfigurableProduct'
ekpo.satnr as CrossPlantConfigurableProduct,
@ObjectModel.foreignKey.association: '_ProductCategory'
ekpo.attyp as ArticleCategory,
ekpo.kanba as PlndOrderReplnmtElmntType,
@Semantics.unitOfMeasure: true
ekpo.punei as ProductPurchasePointsQtyUnit,
@Semantics.quantity.unitOfMeasure: 'ProductPurchasePointsQtyUnit'
@DefaultAggregation: #NONE
ekpo.anzpu as ProductPurchasePointsQty,
//_Plant.AddressID as PlantAddressID,
@ObjectModel.foreignKey.association: '_StorageLocation'
cast (ekpo.lgort as vdm_storage_location preserving type) as StorageLocation,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'ProductGroup'
@ObjectModel.foreignKey.association: '_MaterialGroup'
ekpo.matkl as MaterialGroup,
@ObjectModel.foreignKey.association: '_ProductGroup'
cast (ekpo.matkl as productgroup preserving type ) as ProductGroup,
@Semantics.unitOfMeasure: true
ekpo.meins as OrderQuantityUnit,
ekpo.umrez as OrderItemQtyToBaseQtyNmrtr,
ekpo.umren as OrderItemQtyToBaseQtyDnmntr,
@Semantics.quantity.unitOfMeasure: 'OrderPriceUnit'
cast (ekpo.peinh as vdm_price_unit preserving type) as NetPriceQuantity,
ekpo.elikz as IsCompletelyDelivered,
ekpo.erekz as IsFinallyInvoiced,
ekpo.wepos as GoodsReceiptIsExpected,
ekpo.repos as InvoiceIsExpected,
ekpo.eglkz as OutwardDeliveryIsComplete,
ekpo.webre as InvoiceIsGoodsReceiptBased,
ekpo.weunb as GoodsReceiptIsNonValuated,
ekpo.weora as IsToBeAcceptedAtOrigin,
ekpo.price_change_in_ses_allowed as PriceChangeInSESIsAllowed,
ekpo.banfn as PurchaseRequisition,
// @ObjectModel.foreignKey.association: '_PurchaseRequisitionItem'
ekpo.bnfpo as PurchaseRequisitionItem,
ekpo.packno as ServicePackage,
@ObjectModel.foreignKey.association: '_ServicePerformer'
ekpo.serviceperformer as ServicePerformer,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'ProductTypeCode'
@ObjectModel.foreignKey.association: '_ProductType'
ekpo.producttype as ProductType,
ekpo.producttype as ProductTypeCode,
ekpo.mtart as MaterialType,
@ObjectModel.foreignKey.association: '_PurchaseContractItem'
ekpo.ktpnr as PurchaseContractItem,
@ObjectModel.foreignKey.association: '_PurchaseContract'
ekpo.konnr as PurchaseContract,
// @ObjectModel.foreignKey.association: '_RequestForQuotation'
ekpo.requestforquotation as RequestForQuotation,
// @ObjectModel.foreignKey.association: '_RequestForQuotationItem'
ekpo.requestforquotationitem as RequestForQuotationItem,
ekpo.xersy as EvaldRcptSettlmtIsAllowed,
ekpo.uebtk as UnlimitedOverdeliveryIsAllowed,
ekpo.uebto as OverdelivTolrtdLmtRatioInPct,
ekpo.untto as UnderdelivTolrtdLmtRatioInPct,
ekpo.afnam as RequisitionerName,
ekpo.berid as MRPArea,
@ObjectModel.foreignKey.association: '_IncotermsClassification'
ekpo.inco1 as IncotermsClassification,
ekpo.inco2 as IncotermsTransferLocation,
ekpo.inco2_l as IncotermsLocation1,
ekpo.inco3_l as IncotermsLocation2,
@ObjectModel.foreignKey.association: '_PriorSupplier'
ekpo.kolif as PriorSupplier,
ekpo.fplnr as InvoicingPlan,
ekpo.ean11 as InternationalArticleNumber,
ekpo.bstae as SupplierConfirmationControlKey,
ekpo.prsdr as PriceIsToBePrinted,
@Semantics.unitOfMeasure: true
ekpo.lmein as BaseUnit,
@ObjectModel.foreignKey.association: '_PurgDocumentItemCategory'
ekpo.pstyp as PurchasingDocumentItemCategory,
ekpo.ko_prctr as ProfitCenter,
@Semantics.unitOfMeasure: true
ekpo.bprme as OrderPriceUnit,
@Semantics.unitOfMeasure: true
ekpo.voleh as VolumeUnit,
@Semantics.unitOfMeasure: true
ekpo.gewei as WeightUnit,
ekpo.vrtkz as MultipleAcctAssgmtDistribution,
ekpo.twrkz as PartialInvoiceDistribution,
ekpo.meprf as PricingDateControl,
ekpo.stapo as IsStatisticalItem,
ekpo.uebpo as PurchasingParentItem,
ekpo.lewed as GoodsReceiptLatestCreationDate,
ekpo.retpo as IsReturnsItem,
ekpo.bsgru as PurchasingOrderReason,
ekpo.knttp as AccountAssignmentCategory,
@ObjectModel.foreignKey.association: '_PurchasingInfoRecord'
ekpo.infnr as PurchasingInfoRecord,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
ekpo.netwr as NetAmount,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
ekpo.brtwr as GrossAmount,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
ekpo.effwr as EffectiveAmount,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
ekpo.kzwi1 as Subtotal1Amount,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
ekpo.kzwi2 as Subtotal2Amount,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
ekpo.kzwi3 as Subtotal3Amount,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
ekpo.kzwi4 as Subtotal4Amount,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
ekpo.kzwi5 as Subtotal5Amount,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
ekpo.kzwi6 as Subtotal6Amount,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
@DefaultAggregation: #NONE
ekpo.ktmng as TargetQuantity,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
@DefaultAggregation: #NONE
ekpo.menge as OrderQuantity,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
ekpo.netpr as NetPriceAmount,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
ekpo.zwert as TargetAmount,
@Semantics.quantity.unitOfMeasure: 'VolumeUnit'
@DefaultAggregation: #NONE
ekpo.volum as ItemVolume,
@Semantics.quantity.unitOfMeasure: 'WeightUnit'
@DefaultAggregation: #NONE
ekpo.brgew as ItemGrossWeight,
@Semantics.quantity.unitOfMeasure: 'WeightUnit'
@DefaultAggregation: #NONE
ekpo.ntgew as ItemNetWeight,
ekpo.bpumz as OrderPriceUnitToOrderUnitNmrtr,
ekpo.bpumn as OrdPriceUnitToOrderUnitDnmntr,
ekpo.abdat as SchedAgrmtCumQtyReconcileDate,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
ekpo.abftz as SchedAgrmtAgreedCumQty,
ekpo.drdat as ItemLastTransmissionDate,
ekpo.etfz1 as ScheduleLineFirmOrderInDays,
ekpo.etfz2 as SchedLineSemiFirmOrderInDays,
ekpo.mahn1 as NoDaysReminder1,
ekpo.mahn2 as NoDaysReminder2,
ekpo.mahn3 as NoDaysReminder3,
ekpo.bednr as RequirementTracking,
ekpo.kzabs as IsOrderAcknRqd,
ekpo.insmk as StockType,
ekpo.mwskz as TaxCode,
ekpo.txjcd as TaxJurisdiction,
ekpo.evers as ShippingInstruction,
ekpo.vsart as ShippingType,
@Semantics.amount.currencyCode: 'DocumentCurrency'
@DefaultAggregation: #NONE
ekpo.navnw as NonDeductibleInputTaxAmount,
ekpo.bwtar as ValuationType,
ekpo.bwtty as ValuationCategory,
ekpo.abskz as ItemIsRejectedBySupplier,
ekpo.prdat as PurgDocPriceDate,
ekpo.spinf as PurchasingInfoRecordUpdateCode,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
ekpo.abmng as PurgDocReleaseOrderQuantity,
ekpo.labnr as PurgDocOrderAcknNumber,
ekpo.schpr as PurchasingPriceIsEstimated,
@Semantics.booleanIndicator: true
ekpo.borgr_miss as IsInfoAtRegistration,
ekpo.ltsnr as SupplierSubrange,
ekpo.kostl as CostCenter,
ekpo.sakto as GLAccount,
cast (ekpo.ps_psp_pnr as ps_s4_pspnr preserving type ) as WBSElementInternalID,
ekpo.geber as Fund,
ekpo.budget_pd as BudgetPeriod,
ekpo.fistl as FundsCenter,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'CommitmentItemShortID'
fipos as CommitmentItem,
cast( ekpo.fipos as fmis_ci_internalname) as CommitmentItemShortID,
ekpo.fkber as FunctionalArea,
ekpo.grant_nbr as GrantID,
ekpo.kblnr as EarmarkedFundsDocument,
ekpo.kblpos as EarmarkedFundsDocumentItem,
ekpo.ko_gsber as PartnerReportedBusinessArea,
ekpo.plifz as PlannedDeliveryDurationInDays,
ekpo.webaz as GoodsReceiptDurationInDays,
ekpo.kztlf as PartialDeliveryIsAllowed,
@ObjectModel.foreignKey.association: '_ConsumptionPosting'
ekpo.kzvbr as ConsumptionPosting,
ekpo.abueb as SchedgAgrmtRelCreationProfile,
ekpo.spe_cq_ctrltype as SchedAgrmtCumulativeQtyControl,
ekpo.spe_cq_nocq as CumulativeQuantityIsNotSent,
ekpo.mhdrz as MinRemainingShelfLife,
cast (ekpo.iprkz as vdm_dattp preserving type) as ShelfLifeExpirationDatePeriod, //Data element without conversion exit
ekpo.ssqss as QualityMgmtCtrlKey,
ekpo.sobkz as InventorySpecialStockType,
ekpo.fabkz as IsRelevantForJITDelivSchedule,
ekpo.nfabd as NextJITDelivSchedSendingDate,
ekpo.nlabd as NextFcstDelivSchedSendingDate,
ekpo.kzstu as FirmTradeOffZoneBindMRP,
ekpo.zgtyp as QualityCertificateType,
ekpo.anfnr as SupplierQuotation,
ekpo.anfps as SupplierQuotationItem,
ekpo.isvco as IntrastatServiceCode,
ekpo.stawn as CommodityCode,
ekpo.lfret as DeliveryDocumentType,
ekpo.mfrgr as MaterialFreightGroup,
ekpo.nrfhg as DiscountInKindEligibility,
ekpo.novet as PurgItemIsBlockedForDelivery,
ekpo.reslo as IssuingStorageLocation,
@ObjectModel.foreignKey.association: '_AllocationTable'
ekpo.abeln as AllocationTable,
@ObjectModel.foreignKey.association: '_AllocationTableItem'
ekpo.abelp as AllocationTableItem,
@ObjectModel.foreignKey.association: '_RetailPromotion'
ekpo.aktnr as RetailPromotion,
// Additional Fields for hierarchy implementation
ekpo.exlin as PurgConfigurableItemNumber,
ekpo.upvor as PurgDocAggrgdSubitemCategory,
ekpo.exsnr as PurgExternalSortNumber,
// ekpo.ehtyp as PurgExternalHierarchyCategory,
// Down Payment
ekpo.dptyp as DownPaymentType,
ekpo.dppct as DownPaymentPercentageOfTotAmt,
@Semantics.amount.currencyCode: 'DocumentCurrency'
ekpo.dpamt as DownPaymentAmount,
ekpo.dpdat as DownPaymentDueDate,
//add LoadingPoint field (present in EKPO table) in Scheduling Agreement App.
ekpo.loadingpoint as LoadingPointForDelivery,
// S/4 Limit
@Semantics.amount.currencyCode: 'DocumentCurrency'
ekpo.expected_value as ExpectedOverallLimitAmount,
@Semantics.amount.currencyCode: 'DocumentCurrency'
ekpo.limit_amount as OverallLimitAmount,
ekpo.contract_for_limit as PurContractForOverallLimit,
ekpo.contract_item_for_limit as PurContractItemForOverallLimit,
ekpo.sgt_rcat as RequirementSegment,
ekpo.itcons as SubcontrgCompIsRealTmeCnsmd,
// fields from product compliance
ekpo.status_dg as PurgProdCmplncDngrsGoodsStatus,
ekpo.status_pcs as PurgProdCmplncSupplierStatus,
ekpo.status_pma as PurgProductMarketabilityStatus,
ekpo.status_sds as PurgSafetyDataSheetStatus,
ekpo.blk_reason_id as PurgDocItmBlkRsnCode,
ekpo.renegotiation_status as PurgDocItemRenegotiationStatus,
//Brazil Extension
@ObjectModel.foreignKey.association: '_BR_MaterialOrigin'
ekpo.j_1bmatorg as BR_MaterialOrigin,
@ObjectModel.foreignKey.association: '_BR_MaterialUsage'
ekpo.j_1bmatuse as BR_MaterialUsage,
@ObjectModel.foreignKey.association: '_BR_CFOPCategory'
ekpo.j_1bindust as BR_CFOPCategory,
@ObjectModel.foreignKey.association: '_BR_NCM'
ekpo.j_1bnbm as BR_NCM,
cast(ekpo.j_1bnbm as j_1ig_hsn_sac preserving type) as ConsumptionTaxCtrlCode,
cast( ekpo.j_1bnbm as j_1ig_hsn_sac preserving type) as IN_GSTControlCode,
ekpo.j_1bownpro as BR_IsProducedInHouse,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'ProcmtHubExtReferencedMaterial'
ekpo.extmaterialforpurg as PurchasingCentralMaterial,
ekpo.extmaterialforpurg as ProcmtHubExtReferencedMaterial,
ekpo.procmt_hub_source_system as ProcmtHubRefcdConnectedSystem,
@Semantics.amount.currencyCode: 'DocumentCurrency'
ekpo.target_value as PurgDocItmTargetAmount,
ekpo.txdat_from as TaxCodeValidFromDate,
ekpo.tax_country as TaxCountry,
ekpo.txdat as TaxDeterminationDate,
ekpo.spe_crm_ref_so as ThirdPtyOrdProcgExtReference,
ekpo.spe_crm_ref_item as ThirdPtyOrdProcgExtRefItem,
cast ( ekpo.inco2_key as /scmtms/inc_loc_1_key_nc preserving type ) as IncotermsSupChnLoc1AddlUUID,
cast ( ekpo.inco3_key as /scmtms/inc_loc_2_key_nc preserving type ) as IncotermsSupChnLoc2AddlUUID,
cast ( ekpo.inco4_key as /scmtms/inc_dv_plce_dst_key_nc preserving type ) as IncotermsSupChnDvtgLocAddlUUID,
ekpo.goods_count_correction as IsGoodsCountCorrectionItem,
ekpo.lifex as GdsCtCrrtnDelivDocBySuplr,
ekpo.lifexpos as GdsCtCrrtnDelivDocItemBySuplr,
@Semantics.booleanIndicator: true
_PurchasingDocument.IsEndOfPurposeBlocked,
@Semantics.currencyCode: true
_PurchasingDocument.DocumentCurrency,
_PurchasingDocument.PurchasingOrganization,
_PurchasingDocument.PurchasingGroup,
_PurchasingDocument.PurchasingDocumentType,
//IsCatalogRelevant filed enhancement
ekpo.is_catalog_relevant as PurchasingIsCatalogRelevant,
// Additional Fields from Fashion Management
//X_RFM_I_PurchasingDocumentItem
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'PurgDocSubitemCategory'
uptyp as SubItemCategory,
uptyp as PurgDocSubitemCategory,
fsh_season_year as ProductSeasonYear,
fsh_season as ProductSeason,
fsh_collection as ProductCollection,
fsh_theme as ProductTheme,
rfm_scc_indicator as SeasonCompletenessStatus,
@Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
cnfm_qty as CommittedQuantity,
rfm_psst_rule as ShippingGroupRule,
rfm_psst_group as ShippingGroupNumber,
wrf_charstc1 as ProductCharacteristic1,
wrf_charstc2 as ProductCharacteristic2,
wrf_charstc3 as ProductCharacteristic3,
rfm_diversion as DiversionStatus,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'RefDocNmbrForTrcblyInPO'
rfm_ref_doc as ReferenceDocumentNumber,
rfm_ref_doc as RefDocNmbrForTrcblyInPO,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'RefDocItmNmbrForTrcblyInPO'
rfm_ref_item as ReferenceDocumentItem,
rfm_ref_item as RefDocItmNmbrForTrcblyInPO,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'RefActnForTrcblyInPO'
rfm_ref_action as PurchaseOrderReferenceType,
rfm_ref_action as RefActnForTrcblyInPO,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'RefDocSchdLnNmbrForTrcblyInPO'
rfm_ref_slitem as ReferenceDocumentScheduleLine,
rfm_ref_slitem as RefDocSchdLnNmbrForTrcblyInPO,
fsh_vas_rel as ItemHasValueAddedService,
fsh_vas_prnt_id as ValAddedSrvcParentItmNumber,
assignment_priority as ARunPriorityValue,
arun_group_prio as ARunDemandGroupPriority,
// //Foot Print Intigration
pfmtransdatafootprintuuid as PFMTransDataFootprintUUID,
// X_RFM_I_PurchasingDocItemSeg
sgt_scat as StockSegment,
_PurchasingDocument._DocumentCurrency,
_CompanyCode,
_Plant,
_StorageLocation,
_Material,
_Product,
_ManufacturerMaterial,
_ConfigurableProduct,
//_deletionTypeCode
_MaterialGroup,
_ProductGroup,
_BaseUnit,
_OrderQuantityUnit,
// _PurchasingDocumentItemCategory,
// _ProfitCenter,
_VolumeUnit,
_WeightUnit,
_OrderPriceUnit,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: '_ManualDeliveryAddress_2'
_ManualDeliveryAddress,
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: '_ReferenceDeliveryAddress_2'
_ReferenceDeliveryAddress,
_ManualDeliveryAddress_2,
_ReferenceDeliveryAddress_2,
// _DisplayDeliveryAddress,
_PurgDocumentCategory,
_PurgDocumentItemCategory,
_ProductCategory,
_IncotermsClassification,
_PurchasingDocument,
// _ServicePackage,
// _AccountAssignment,
_ScheduleLine,
// _PurchaseContractItem,
_PurchaseRequisitionItem,
_PurchasingInfoRecord,
_Manufacturer,
_Customer,
_Subcontractor,
_PriorSupplier,
_PurchaseRequisition,
_PurchaseContract,
_PurchaseContractItem,
_ServicePerformer,
_ProductType,
_AccountAssignmentCategory,
_ConsumptionPosting,
_AllocationTable,
_AllocationTableItem,
_RetailPromotion,
// Brazilian fields
_BR_MaterialOrigin,
_BR_MaterialUsage,
_BR_CFOPCategory,
_BR_NCM
}