R_CentralReqForQuotationItemTP

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@EndUserText.label: 'Central Request for Quotation Item'

@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API


@ObjectModel.semanticKey:  [ 'CentralRequestForQuotation', 'CentralRequestForQuotationItem' ]
@ObjectModel.representativeKey: 'CentralRequestForQuotationItem'
@ObjectModel: {
    usageType: {
      sizeCategory: #L,
      serviceQuality: #C,
      dataClass: #MIXED
    }
  }

@Metadata.ignorePropagatedAnnotations: true

define view entity R_CentralReqForQuotationItemTP
  as select from R_CentralReqForQuotationItem

  association to parent R_CentralRequestForQuotationTP as _CentralRequestForQuotation on $projection.CentralRequestForQuotation = _CentralRequestForQuotation.CentralRequestForQuotation

  composition [0..*] of R_CentralRFQItemDistributionTP as _CentralRFQItemDistribution

  ---- Extension Association
  association [0..1] to E_PurchasingDocumentItem     as _ItemExtension             on  $projection.CentralRequestForQuotation     = _ItemExtension.PurchasingDocument
                                                                                   and $projection.CentralRequestForQuotationItem = _ItemExtension.PurchasingDocumentItem

{

      @ObjectModel.foreignKey.association: '_CentralRequestForQuotation'
  key CentralRequestForQuotation,
  key CentralRequestForQuotationItem,

      @ObjectModel: { foreignKey.association: '_PurchasingDocumentCategory' }
      PurchasingDocumentCategory,
      PurchasingDocumentItemText,
      
      ProductTypeCode,
      ManufacturerMaterial,
      ManufacturerPartNmbr,
      Manufacturer,
      MaterialGroup,

      @ObjectModel: { foreignKey.association: '_Plant' }
      Plant,
      ManualDeliveryAddressID,
      ReferenceDeliveryAddressID,
      AddressID,
      ItemDeliveryAddressID,

      @ObjectModel: { foreignKey.association: '_IncotermsClassification' }
      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsLocation1,
      IncotermsLocation2,

      @Semantics.quantity.unitOfMeasure: 'OrderQuantityUnit'
      _CntrlReqForQtanScheduleLine.ScheduleLineOrderQuantity,
      _CntrlReqForQtanScheduleLine.ScheduleLineDeliveryDate,
      _CntrlReqForQtanScheduleLine.PerformancePeriodStartDate,
      _CntrlReqForQtanScheduleLine.PerformancePeriodEndDate,

      @ObjectModel: { foreignKey.association: '_OrderQuantityUnit' }
      OrderQuantityUnit,
      OrderItemQtyToBaseQtyNmrtr,
      OrderItemQtyToBaseQtyDnmntr,
      OrderPriceUnitToOrderUnitNmrtr,
      OrdPriceUnitToOrderUnitDnmntr,

      BaseUnit,
      PurchaseRequisition,
      PurchaseRequisitionItem,
      RequirementTracking,
      PurchasingCentralMaterial,
      PurchasingDocumentItemCategory,

      DocumentCurrency,
      @Semantics.systemDateTime.lastChangedAt: true
      _CentralRequestForQuotation.LastChangeDateTime as LastChangeDateTime,
      
      /* Associations */
      _CentralRequestForQuotation,
      _CentralRFQItemDistribution,
      _IncotermsClassification,
      _OrderQuantityUnit,
      _Plant,
      _PurchasingDocumentCategory,
      _CntrlReqForQtanScheduleLine,
      _MaterialGroup,
      _ManufacturerMaterial,
      _PurgDocumentItemCategory,
      _BaseUnit,
      _Manufacturer

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"R_CENTRALREQFORQUOTATIONITEM",
"R_CENTRALREQUESTFORQUOTATIONTP",
"R_CNTRLREQFORQTANSCHEDULELINE"
],
"ASSOCIATED":
[
"I_INCOTERMSCLASSIFICATION",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_PLANT",
"I_PURCHASINGDOCUMENTCATEGORY",
"I_PURGDOCUMENTITEMCATEGORY",
"I_SUPPLIER",
"I_UNITOFMEASURE",
"R_CENTRALREQUESTFORQUOTATIONTP",
"R_CENTRALRFQITEMDISTRIBUTIONTP",
"R_CNTRLREQFORQTANSCHEDULELINE"
],
"BASE":
[
"R_CENTRALREQFORQUOTATIONITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/