R_BankDepTP

@VDM.viewType: #TRANSACTIONAL
@ObjectModel.usageType:{
     serviceQuality: #C,
     sizeCategory: #L,
     dataClass: #TRANSACTIONAL 
}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@Search.searchable: false

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_BankAddress' ]
@EndUserText.label: 'Transactional Bank'
define root view entity R_BankDepTP
  as select from I_Bank_2 as Bank
  composition [0..*] of R_BankAddressDepTP  as _BankAddress
  association [0..1] to R_BankAddressDepTP  as _BankMainAddress on  _BankMainAddress.BankCountry               = $projection.BankCountry
                                                             and _BankMainAddress.BankInternalID            = $projection.BankInternalID
                                                             and _BankMainAddress.AddressRepresentationCode = ''
  association [1..1] to C_BankCategoryVH as _BankCategory    on  $projection.BankCategory = _BankCategory.BankCategory

{
      @ObjectModel.foreignKey.association: '_Country'
  key BankCountry                                 as BankCountry,
  key BankInternalID                              as BankInternalID,
      @Semantics.systemDate.createdAt: true
      CreationDate                                as CreationDate,
      @Semantics.user.createdBy: true
      CreatedByUser                               as CreatedByUser,
      @Semantics.text: true
      BankName                                    as BankName,
      Region                                      as Region,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'ShortStreetName'
      StreetName                                  as StreetName,
      ShortStreetName                             as ShortStreetName, //successor for StreetName

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'ShortCityName'
      CityName                                    as CityName,
      ShortCityName                               as ShortCityName, //successor for CityName

      SWIFTCode                                   as SWIFTCode,
      BankNetworkGrouping                         as BankNetworkGrouping,
      IsPostBankAccount                           as IsPostBankAccount,
      IsMarkedForDeletion                         as IsMarkedForDeletion,
      Bank                                        as Bank,
      PostOfficeBankAccount                       as PostOfficeBankAccount,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'BankBranch'
      Branch                                      as Branch,
      BankBranch                                  as BankBranch, //successor for Branch

      CheckDigitCalculationMethod                 as CheckDigitCalculationMethod,
      BankDataFileFormat                          as BankDataFileFormat,
      AddressID                                   as AddressID,
      BankCategory,
/*

      case
        when BankCategory is not initial then cast( BankCategory as bf_bank_category preserving type )
        else cast( ' ' as bf_bank_category preserving type)
      end                                         as BankCategory,



      //local ETag field --> OData ETag

      cast( dats_tims_to_tstmp( CreationDate , cast('120000' as uzeit),       
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client,
                         'NULL' ) as timestampl ) as LocalLastChangedAt,

      cast( dats_tims_to_tstmp( CreationDate , cast('120000' as uzeit),
                          abap_system_timezone( $session.client,'NULL' ),
                          $session.client,
                         'NULL' ) as timestampl ) as LastChangedAt,
*/
      case
        when _BankMainAddress.BankNameInLocalScript is null then BankName
        else _BankMainAddress.BankNameInLocalScript
      end                                         as AddressBankName,

      case
        when _BankMainAddress.BankBranchInLocalScript is null then BankBranch
        else _BankMainAddress.BankBranchInLocalScript
      end                                         as AddressBankBranch,

      case
        when _BankMainAddress.CityName is null then CityName
        else _BankMainAddress.CityName
      end                                         as AddressCity,

      case
        when _BankMainAddress.Region is null then Region
        else _BankMainAddress.Region
      end                                         as AddressRegion,
      
      case
        when _BankMainAddress.StreetName is null then StreetName
        else _BankMainAddress.StreetName
      end                           as      AddressStreet,      
      

      cast(
        case
          when _BankMainAddress.AddressID is null then ' '
          else 'X'
        end as xfeld preserving type )             as hasAddress,

      _BankAddress,
      _Region,
      _BankCategory, 
      _Country

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BANK_2",
"R_BANKADDRESSDEPTP"
],
"ASSOCIATED":
[
"C_BANKCATEGORYVH",
"I_COUNTRY",
"I_REGION",
"R_BANKADDRESSDEPTP"
],
"BASE":
[
"I_BANK_2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/