I_Bank_2

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Bank'
@VDM.viewType: #BASIC
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #B,
  sizeCategory: #L,
  dataClass: #MASTER
}
@Metadata.allowExtensions:true
@Search.searchable: true
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE]
@ObjectModel.representativeKey: 'BankInternalID'
//@ObjectModel.sapObjectNodeType.name: 'Bank'

@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}


define view entity I_Bank_2
  as select from    bnka   as bk
    left outer join bnkain as ad on  bk.banks = ad.banks
                                 and bk.bankl = ad.bankl
  association [0..1] to I_Address             as _Address     on  $projection.AddressID = _Address.AddressID
  association [0..*] to I_OrganizationAddress as _BankAddress on  $projection.AddressID = _BankAddress.AddressID
  association [0..1] to I_Region              as _Region      on  $projection.Region      = _Region.Region
                                                              and $projection.BankCountry = _Region.Country
  association [0..1] to I_Country             as _Country     on  $projection.BankCountry = _Country.Country

{
      @ObjectModel.foreignKey.association: '_Country'
  key bk.banks as BankCountry,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key bk.bankl as BankInternalID,
      bk.erdat as CreationDate,
      bk.ernam as CreatedByUser,
      @Semantics.text: true
      bk.banka as BankName,
      bk.provz as Region,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'ShortStreetName'
      bk.stras as StreetName,
      bk.stras as ShortStreetName, //successor for StreetName

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'ShortCityName'
      bk.ort01 as CityName,
      bk.ort01 as ShortCityName, //successor for CityName

      bk.swift as SWIFTCode,
      bk.bgrup as BankNetworkGrouping,
      bk.xpgro as IsPostBankAccount,
      bk.loevm as IsMarkedForDeletion,
      bk.bnklz as Bank,
      bk.pskto as PostOfficeBankAccount,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'BankBranch'
      bk.brnch as Branch,
      bk.brnch as BankBranch, //successor for Branch

      bk.chkme as CheckDigitCalculationMethod,
      bk.vers  as BankDataFileFormat,
      bk.adrnr as AddressID,
      @ObjectModel.sapObjectNodeTypeReference: 'BankCategory'
      ad.bintk as BankCategory,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_BankAddress'
      _Address,
      _BankAddress,
      _Region,
      _Country
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"BNKA",
"BNKAIN"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_COUNTRY",
"I_ORGANIZATIONADDRESS",
"I_REGION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/