I_BANK_2

CDS View

Bank

I_BANK_2 is a CDS View in S/4HANA. Bank. It contains 13 fields. 18 CDS views read from this table.

Used by 18 CDS view(s) 13 fields

CDS Views using this table (18)

ViewTypeJoinVDMDescription
C_Bank view from CONSUMPTION Bank Factsheet
C_BankInternalIDVH view_entity from CONSUMPTION Bank Key
C_BankNameVH view_entity from CONSUMPTION Bank Name
C_BankNumberVH_2 view_entity from Bank Number
C_BankSwiftCodeVH_2 view_entity from Bank SWIFT/BIC Code
C_BkReltdRiskBusinessPartnerVH view_entity from CONSUMPTION Bank Related Risk Business Partner
I_BankHierBankGroupMapping view left_outer BASIC Bank Hierarchy Bank Group Name Mapping
I_BankNumberVH view from COMPOSITE Bank Number
I_BankStdVH view from COMPOSITE Bank
I_CashBankCompany view inner COMPOSITE Cash Bank for Company
I_MDI_BANK view from View on I_BANK2
I_NumberOfCashBankUsage view from COMPOSITE Number of Bank Usage
R_BankAddressDepTP view_entity from TRANSACTIONAL Bank Address
R_BankAddressTP view_entity from TRANSACTIONAL Bank Address
R_BankDepTP view_entity from TRANSACTIONAL Transactional Bank
R_BankScriptedAddressTP view_entity from TRANSACTIONAL Bank Scripted Address
R_BankTP view_entity from TRANSACTIONAL Transactional Bank
R_CashBankTP view_entity from TRANSACTIONAL Cash Transactional Bank TP

Fields (13)

KeyField CDS FieldsUsed in Views
KEY BankCountry BankCountry 6
KEY BankInternalID Bank,BankInternalID 6
Bank BankNumber 2
BankBranch BankBranch 2
BankCategory BankCategory 1
BankName BankName 3
BankNetworkGrouping BankNetworkGrouping 1
IsPostBankAccount IsPostBankAccount 1
PostOfficeBankAccount PostOfficeBankAccount 1
Region Region 2
ShortCityName ShortCityName 2
ShortStreetName ShortStreetName 2
SWIFTCode SWIFTCode 1 
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Bank'
@VDM.viewType: #BASIC
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #B,
  sizeCategory: #L,
  dataClass: #MASTER
}
@Metadata.allowExtensions:true
@Search.searchable: true
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE]
@ObjectModel.representativeKey: 'BankInternalID'
//@ObjectModel.sapObjectNodeType.name: 'Bank'

@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}


define view entity I_Bank_2
  as select from    bnka   as bk
    left outer join bnkain as ad on  bk.banks = ad.banks
                                 and bk.bankl = ad.bankl
  association [0..1] to I_Address             as _Address     on  $projection.AddressID = _Address.AddressID
  association [0..*] to I_OrganizationAddress as _BankAddress on  $projection.AddressID = _BankAddress.AddressID
  association [0..1] to I_Region              as _Region      on  $projection.Region      = _Region.Region
                                                              and $projection.BankCountry = _Region.Country
  association [0..1] to I_Country             as _Country     on  $projection.BankCountry = _Country.Country

{
      @ObjectModel.foreignKey.association: '_Country'
  key bk.banks as BankCountry,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key bk.bankl as BankInternalID,
      bk.erdat as CreationDate,
      bk.ernam as CreatedByUser,
      @Semantics.text: true
      bk.banka as BankName,
      bk.provz as Region,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'ShortStreetName'
      bk.stras as StreetName,
      bk.stras as ShortStreetName, //successor for StreetName

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'ShortCityName'
      bk.ort01 as CityName,
      bk.ort01 as ShortCityName, //successor for CityName

      bk.swift as SWIFTCode,
      bk.bgrup as BankNetworkGrouping,
      bk.xpgro as IsPostBankAccount,
      bk.loevm as IsMarkedForDeletion,
      bk.bnklz as Bank,
      bk.pskto as PostOfficeBankAccount,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'BankBranch'
      bk.brnch as Branch,
      bk.brnch as BankBranch, //successor for Branch

      bk.chkme as CheckDigitCalculationMethod,
      bk.vers  as BankDataFileFormat,
      bk.adrnr as AddressID,
      @ObjectModel.sapObjectNodeTypeReference: 'BankCategory'
      ad.bintk as BankCategory,

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_BankAddress'
      _Address,
      _BankAddress,
      _Region,
      _Country
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"BNKA",
"BNKAIN"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_COUNTRY",
"I_ORGANIZATIONADDRESS",
"I_REGION"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More