R_BPCollsSegmentAssignmentTP

@AccessControl: { authorizationCheck: #CHECK,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED },
                  privilegedAssociations: [ '_SubstituteCard',
                                            '_CollectionsSpecialistCard',
                                            '_CollectionSpecialist' ] }
@EndUserText: { label: 'Business Partner: Collection Segments' }
@VDM: { viewType:  #TRANSACTIONAL,
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@ObjectModel: { usageType:         { serviceQuality: #X,
                                     sizeCategory:   #L,
                                     dataClass:      #TRANSACTIONAL },
                semanticKey:       [ 'CollectionSegment',
                                     'BusinessPartner' ],
                representativeKey: 'BusinessPartner' }

define view entity R_BPCollsSegmentAssignmentTP
  as select from I_BPCollectionsSegmentAssgmt
    inner join   I_BusinessPartnerCustomer on I_BPCollectionsSegmentAssgmt.BusinessPartner = I_BusinessPartnerCustomer.BusinessPartner

  // VDM Associations

  // Credit Management

  association [0..1] to R_CollsAcctCreditMgmtSummary        as _CollsAcctCreditMgmtSummary on  $projection.BusinessPartner   = _CollsAcctCreditMgmtSummary.BusinessPartner
                                                                                           and $projection.CollectionSegment = _CollsAcctCreditMgmtSummary.CollectionSegment

  // Main Contact Person

  association [0..1] to I_CollectionsMainContact            as _CollectionsMainContact     on  $projection.BusinessPartner   = _CollectionsMainContact.BusinessPartner
                                                                                           and $projection.CollectionSegment = _CollectionsMainContact.CollectionSegment

  // Payment Trend

  association [0..*] to I_CollectionsPaymentTrend           as _CollectionsPaymentTrend    on  $projection.Customer          = _CollectionsPaymentTrend.Customer
                                                                                           and $projection.CollectionSegment = _CollectionsPaymentTrend.CollectionSegment

  // Due Date Grid

  association [0..*] to I_CollectionsDueDateGrid            as _CollectionsDueDateGrid     on  $projection.BusinessPartner   = _CollectionsDueDateGrid.BusinessPartner
                                                                                           and $projection.CollectionSegment = _CollectionsDueDateGrid.CollectionSegment

  // Sticky Note

  association [0..1] to I_CollsAccountStickyNote            as _CollsAccountStickyNote     on  $projection.Customer          = _CollsAccountStickyNote.Customer
                                                                                           and $projection.CollectionSegment = _CollsAccountStickyNote.CollectionSegment

  // Collections Account Notes

  association [0..*] to I_CollectionsAccountNote            as _CollectionsAccountNote     on  $projection.Customer          = _CollectionsAccountNote.Customer
                                                                                           and $projection.CollectionSegment = _CollectionsAccountNote.CollectionSegment

  // Business Partner Quick View Facet

  association [0..1] to R_BPCollectionsSgmtQuickView        as _CollectionsBPQuickView     on  $projection.BusinessPartner   = _CollectionsBPQuickView.BusinessPartner
                                                                                           and $projection.CollectionSegment = _CollectionsBPQuickView.CollectionSegment

  // Collections Specialist Contact Card

  association [0..1] to R_RblsMgmtUserContactCard           as _CollectionsSpecialistCard  on  $projection.CollectionSpecialist = _CollectionsSpecialistCard.ContactCardID

  // Temporary Substitutes

  association [0..*] to R_CollsSpecialistSubstitute         as _CollsSpecialistSubstitute  on  $projection.CollectionGroup = _CollsSpecialistSubstitute.CollectionGroup

  // Current Substitute

  association [0..1] to R_BPCollsSgmtCurrentSubstitute      as _CurrentSubstitute          on  $projection.BusinessPartner             = _CurrentSubstitute.BusinessPartner
                                                                                           and $projection.CollectionSegment           = _CurrentSubstitute.CollectionSegment
                                                                                           and $projection.BPCollSgmtAssignmentValidTo = _CurrentSubstitute.BPCollSgmtAssignmentValidTo

  // Collections Specialist Contact Card

  association [0..1] to R_RblsMgmtUserContactCard           as _SubstituteCard             on  $projection.CollectionSpecialistSubstitute = _SubstituteCard.ContactCardID

  // BO Composition

  // Collections Master Data

  association        to parent R_CollsMgmtBusinessPartnerTP as _CollsMgmtBusinessPartnerTP on  $projection.BusinessPartner = _CollsMgmtBusinessPartnerTP.BusinessPartner

  // Temporary Segment Assignments

  composition [0..*] of R_BPCollsSegmentTmpAssgmtTP         as _BPCollsSegmentTmpAssgmtTP

{
      // VDM Fields

      @ObjectModel: { foreignKey: { association: '_CollectionsBPQuickView' } }
  key I_BPCollectionsSegmentAssgmt.BusinessPartner               as BusinessPartner,

  key I_BPCollectionsSegmentAssgmt.CollectionSegment             as CollectionSegment,

  key I_BPCollectionsSegmentAssgmt.BPCollSgmtAssignmentValidTo   as BPCollSgmtAssignmentValidTo,
      I_BPCollectionsSegmentAssgmt.BPCollSgmtAssignmentValidFrom as BPCollSgmtAssignmentValidFrom,
      I_BPCollectionsSegmentAssgmt.CollectionGroup               as CollectionGroup,

      @ObjectModel: { foreignKey: { association: '_CollectionsSpecialistCard' } }
      I_BPCollectionsSegmentAssgmt.CollectionSpecialist          as CollectionSpecialist,

      I_BPCollectionsSegmentAssgmt.CollectionBPMainContactPerson as CollectionBPMainContactPerson,
      I_BusinessPartnerCustomer.Customer                         as Customer,

      @ObjectModel: { foreignKey: { association: '_SubstituteCard' } }
      _CurrentSubstitute.CollectionSpecialistSubstitute          as CollectionSpecialistSubstitute,

      // Exposed Associations

      I_BPCollectionsSegmentAssgmt._BusinessPartner              as _BusinessPartner,
      I_BPCollectionsSegmentAssgmt._CollectionGroup              as _CollectionGroup,
      I_BPCollectionsSegmentAssgmt._CollectionSegment            as _CollectionSegment,
      I_BPCollectionsSegmentAssgmt._CollectionSpecialist         as _CollectionSpecialist,
      I_BPCollectionsSegmentAssgmt._MainContactPerson            as _MainContactPerson,
      _CollsAcctCreditMgmtSummary,
      _CollectionsMainContact,
      _CollectionsPaymentTrend,
      _CollectionsDueDateGrid,
      _CollsAccountStickyNote,
      _CollectionsAccountNote,
      _CollectionsBPQuickView,
      _CollectionsSpecialistCard,
      _CollsSpecialistSubstitute,
      _CurrentSubstitute,
      _SubstituteCard,

      // BO Compositions

      _CollsMgmtBusinessPartnerTP,
      _BPCollsSegmentTmpAssgmtTP

}

where
  I_BPCollectionsSegmentAssgmt.BPCollSgmtAssignmentValidTo = '99991231'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPCOLLECTIONSSEGMENTASSGMT",
"I_BUSINESSPARTNERCUSTOMER",
"R_BPCOLLSSGMTCURRENTSUBSTITUTE"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_COLLECTIONGROUP",
"I_COLLECTIONSACCOUNTNOTE",
"I_COLLECTIONSDUEDATEGRID",
"I_COLLECTIONSEGMENT",
"I_COLLECTIONSMAINCONTACT",
"I_COLLECTIONSPAYMENTTREND",
"I_COLLSACCOUNTSTICKYNOTE",
"I_USERCONTACTCARD",
"R_BPCOLLECTIONSSGMTQUICKVIEW",
"R_BPCOLLSSEGMENTTMPASSGMTTP",
"R_BPCOLLSSGMTCURRENTSUBSTITUTE",
"R_COLLSACCTCREDITMGMTSUMMARY",
"R_COLLSMGMTBUSINESSPARTNERTP",
"R_COLLSSPECIALISTSUBSTITUTE",
"R_RBLSMGMTUSERCONTACTCARD"
],
"BASE":
[
"I_BPCOLLECTIONSSEGMENTASSGMT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/