I_BPCOLLECTIONSSEGMENTASSGMT

CDS View

Collection Segment Assignment

I_BPCOLLECTIONSSEGMENTASSGMT is a CDS View in S/4HANA. Collection Segment Assignment. It contains 12 fields. 15 CDS views read from this table.

Used by 15 CDS view(s) 12 fields

CDS Views using this table (15)

ViewTypeJoinVDMDescription
I_CollectionContact view from COMPOSITE Collection Contact
I_CollectionsMainContact view from COMPOSITE Main Contact Person
P_CollectionsAccount view inner COMPOSITE
P_CollectionsAccountNote view inner COMPOSITE
P_CollMgmtRblsItmForKeyDte view right_outer COMPOSITE
P_CollMgmtRblsItmForKeyDte1 view from COMPOSITE
P_CollsAccountCollsSegment view inner COMPOSITE
P_CollsAccountCompanyCode view inner COMPOSITE
P_CollsLastWLItemBP view from COMPOSITE
P_CollsLatestWLItem view from COMPOSITE
P_CrdtMNrOfBrokenPromisesToPay view inner COMPOSITE
R_BPCollsSegmentAssignmentTP view_entity from TRANSACTIONAL Business Partner: Collection Segments
R_BPCollsSgmtCurrentSubstitute view from COMPOSITE Current Substitute
R_CollectionsCustomerQuickView view inner COMPOSITE Customer Quick View
R_CollsAcctCreditMgmtSummary view from COMPOSITE Collectoins Account Credit Summary

Fields (12)

KeyField CDS FieldsUsed in Views
KEY BPCollSgmtAssignmentValidTo BPCollSgmtAssignmentValidTo 1
KEY BusinessPartner BusinessPartner 3
KEY CollectionSegment CollectionSegment 6
_BusinessPartner _BusinessPartner 1
_CollectionGroup _CollectionGroup 1
_CollectionSegment _CollectionSegment 1
_CollectionSpecialist _CollectionSpecialist 1
_MainContactPerson _MainContactPerson 1
BPCollSgmtAssignmentValidFrom BPCollSgmtAssignmentValidFrom 1
CollectionBPMainContactPerson CollectionBPMainContactPerson 1
CollectionGroup CollectionGroup 2
CollectionSpecialist CollectionSpecialist 2 
@AbapCatalog: { sqlViewName: 'IBPCOLLSSGASSGNT',
                compiler: { compareFilter: true } }
@AccessControl: { authorizationCheck:     #MANDATORY,
                  personalData:           { blocking: #BLOCKED_DATA_EXCLUDED },
                  privilegedAssociations: [ '_CollectionSpecialist' ] }
@EndUserText: { label: 'Collection Segment Assignment' }
@VDM: { viewType: #BASIC,
        lifecycle: { contract: { type: #PUBLIC_LOCAL_API } } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel: { usageType: { serviceQuality: #A,
                             sizeCategory: #L,
                             dataClass: #TRANSACTIONAL },
                semanticKey: [ 'BusinessPartner', 'CollectionSegment' ],
                representativeKey: 'BusinessPartner' }
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE,
                                     #CDS_MODELING_DATA_SOURCE,
                                     #CDS_MODELING_ASSOCIATION_TARGET,
                                     #ANALYTICAL_DIMENSION ]

define view I_BPCollectionsSegmentAssgmt
  as select from udmbpsegments

  // VDM Associatons

  // Business Partner

  association [0..1] to I_BusinessPartner   as _BusinessPartner      on $projection.BusinessPartner = _BusinessPartner.BusinessPartner

  // Collection Segment

  association [0..1] to I_CollectionSegment as _CollectionSegment    on $projection.CollectionSegment = _CollectionSegment.CollectionSegment

  // Collection Group

  association [0..1] to I_CollectionGroup   as _CollectionGroup      on $projection.CollectionGroup = _CollectionGroup.CollectionGroup

  // Collection Specialist

  association [0..1] to I_UserContactCard   as _CollectionSpecialist on $projection.CollectionSpecialist = _CollectionSpecialist.ContactCardID

  // Last Contact Person

  association [0..1] to I_BusinessPartner   as _MainContactPerson    on $projection.CollectionBPMainContactPerson = _MainContactPerson.BusinessPartner

{

      // VDM Fields

      @ObjectModel: { foreignKey: { association: '_BusinessPartner' } }
  key partner         as BusinessPartner,

      @ObjectModel: { foreignKey: { association: '_CollectionSegment' } }
  key coll_segment    as CollectionSegment,

      @Semantics: { businessDate: { to: true } }
  key valid_until     as BPCollSgmtAssignmentValidTo,

      @Semantics: { businessDate: { from: true } }
      valid_from      as BPCollSgmtAssignmentValidFrom,

      @ObjectModel: { foreignKey: { association: '_CollectionGroup' } }
      coll_group      as CollectionGroup,

      @ObjectModel: { foreignKey: { association: '_CollectionSpecialist' } }
      coll_specialist as CollectionSpecialist,

      @ObjectModel: { foreignKey: { association: '_MainContactPerson' } }
      last_contact    as CollectionBPMainContactPerson,

      // Exposed Associations

      _BusinessPartner,
      _CollectionSegment,
      _CollectionGroup,
      _CollectionSpecialist,
      _MainContactPerson

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"UDMBPSEGMENTS"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_COLLECTIONGROUP",
"I_COLLECTIONSEGMENT",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More