P_ReleaseDocumentationValues5

@AbapCatalog.sqlViewName: 'PMMRELDOCVAL5'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType : #CONSUMPTION
@VDM.private: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Release Documentation Values 5'
define view P_ReleaseDocumentationValues5
  with parameters
    P_StartDate       : bedat,
    P_EndDate         : bedat

  as select from I_PurchaseContractHistory as PurchaseContractHistory

    inner join   I_PurchaseContractItem    as PurchaseContractItem on  PurchaseContractItem.PurchaseContract     = PurchaseContractHistory.PurchaseContract
                                                                   and PurchaseContractItem.PurchaseContractItem = PurchaseContractHistory.PurchaseContractItem

    inner join   I_PurchaseContract        as PurchaseContract     on PurchaseContractItem.PurchaseContract = PurchaseContract.ActivePurchasingDocument


{
  key PurchaseContractHistory.PurchaseContract,

  key PurchaseContractHistory.PurchaseContractItem,

  key PurchaseContractHistory.ReleaseOrder,

  key PurchaseContractHistory.ReleaseOrderItem,

      PurchaseContractHistory.ReleaseOrderCurrency,

      PurchaseContractHistory.ReleaseOrderDate,

      cast( PurchaseContractHistory.ReleaseOrderItemNetAmount as mm_a_release_ord_net_amt_21_2 ) as ReleaseOrderItemNetAmount,

      cast( unit_conversion
      (
         quantity    => ReleaseOrderItemOrderQuantity,
         source_unit => ReleaseOrderItemQuantityUnit,
         target_unit => PurchaseContractItem.OrderQuantityUnit,
         error_handling => 'KEEP_UNCONVERTED'
       ) as abap.quan( 13, 0 )  )                                                                as ReleaseOrderItemOrderQuantity

}
where
        PurchaseContractHistory.ReleaseOrderCurrency != ''
  and   PurchaseContractHistory.ReleaseOrderCurrency        is not null
  and   PurchaseContractItem.PurchasingContractDeletionCode = ''
  and   ValidityEndDate                                     >= $parameters.P_StartDate
  and   ValidityStartDate                                   <= $parameters.P_EndDate
  and   not(
      Material                                              = ''
      and IsStatisticalItem                                 = 'X'
    )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASECONTRACT",
"I_PURCHASECONTRACTHISTORY",
"I_PURCHASECONTRACTITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/