I_PURCHASECONTRACTITEM

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'IPURCHASECTRITM'
@EndUserText.label: 'Purchase Contract Item'
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType : #COMPOSITE
@ObjectModel.representativeKey: 'PurchaseContractItem'

@ObjectModel.semanticKey:  [ 'PurchaseContract', 'PurchaseContractItem' ]

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AbapCatalog.preserveKey:true
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED

define view I_PurchaseContractItem
  as select from R_PurchaseContractItem

  association [1..1] to I_PurchaseContract            as _PurchaseContract            on  $projection.PurchaseContract = _PurchaseContract.PurchaseContract

  association [1..*] to I_PurchaseContractHistory     as _PurchaseContractHistory     on  $projection.PurchaseContract     = _PurchaseContractHistory.PurchaseContract
                                                                                      and $projection.PurchaseContractItem = _PurchaseContractHistory.PurchaseContractItem

  association [1..1] to I_StorageLocation             as _StorageLocation             on  $projection.Plant           = _StorageLocation.Plant
                                                                                      and $projection.StorageLocation = _StorageLocation.StorageLocation

  association [0..1] to I_Currency                    as _DocumentCurrency            on  $projection.DocumentCurrency = _DocumentCurrency.Currency

  association [0..1] to I_PurCtrAddress               as _PurCtrAddress
                                                                                      on  $projection.PurchaseContractItem = _PurCtrAddress.PurchaseContractItem
                                                                                      and $projection.PurchaseContract     = _PurCtrAddress.PurchaseContract

  association [0..*] to I_PurCtrAccount               as _PurCtrAccount               on  $projection.PurchaseContract     = _PurCtrAccount.PurchaseContract
                                                                                      and $projection.PurchaseContractItem = _PurCtrAccount.PurchaseContractItem

  association [0..*] to I_Purctritnotes               as _Purctritnotes               on  $projection.FormattedPurchaseContractItem = _Purctritnotes.ArchitecturalObjectNumber
                                                                                      and $projection.PurchaseContract              = _Purctritnotes.PurchaseContract
                                                                                      and $projection.PurchaseContractItem          = _Purctritnotes.PurchaseContractItem

  association [1..*] to I_PurCtrCndItem               as _PurCtrCndItem               on  $projection.PurchaseContract     = _PurCtrCndItem.PurchaseContract
                                                                                      and $projection.PurchaseContractItem = _PurCtrCndItem.PurchaseContractItem

  association [1..1] to I_PurchasingCategoryMatlGroup as _PurchasingCategoryMatlGroup on  $projection.MaterialGroup = _PurchasingCategoryMatlGroup.MaterialGroup

  ----Extension Association
  association [1..1] to E_PurchasingDocumentItem      as _PurchasingDocumentItem      on  $projection.PurchaseContract     = _PurchasingDocumentItem.PurchasingDocument
                                                                                      and $projection.PurchaseContractItem = _PurchasingDocumentItem.PurchasingDocumentItem
{

      @ObjectModel.foreignKey.association: '_PurchaseContract'
  key PurchaseContract,

  key PurchaseContractItem,

      PurchaseContractItemUniqueID,

      CompanyCode,

      Material,

      ManufacturerMaterial,

      @Semantics.text: true
      PurchaseContractItemText,

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      @DefaultAggregation: #NONE
      ContractNetPriceAmount,

      @Semantics.unitOfMeasure: true
      OrderPriceUnit,

      @Semantics.unitOfMeasure: true
      VolumeUnit,

      @Semantics.unitOfMeasure: true
      OrderQuantityUnit,

      MaterialGroup,

      Customer,
      Subcontractor,

      ReferenceDeliveryAddressID,
      ManualDeliveryAddressID,
      DeliveryAddressID,

      Plant,

      StorageLocation,

      AccountAssignmentCategory,

      GoodsReceiptIsExpected,
      
      IsToBeAcceptedAtOrigin,

      NetPriceQuantity,

      MultipleAcctAssgmtDistribution,

      TargetQuantity,
      OutlineAgreementTargetAmount,
      PurContrValidityEndDate,
      PurContrValidityStartDate,
      PurchaseContractCreatedByUser,
      PurchasingDocumentCategory                                    as PurchasingObjectCategory,
      //PurchaseContractTargetAmount,

      //ValidityEndDate,

      //ValidityStartDate,

      //CreatedByUser,

      //PurchasingDocumentCategory,

      //PurchasingDocumentDeletionCode,

      PurchaseContractType,
      PurchasingGroup,      

      @Semantics.amount.currencyCode: 'DocumentCurrency'
      @DefaultAggregation: #NONE
      TargetAmount,

      @Semantics.currencyCode: true
      DocumentCurrency,

      OrdPriceUnitToOrderUnitDnmntr, // price conversion from


      --cast needed to change the default description
      cast (OrderPriceUnitToOrderUnitNmrtr as mm_oa_conv_unit_nmrtr) as OrderPriceUnitToOrderUnitNmrtr, // price conversion to


      PurchasingDocumentItemCategory,

      SupplierMaterialNumber,

      EvaldRcptSettlmtIsAllowed,

      UnderdelivTolrtdLmtRatioInPct,

      PriceIsToBePrinted,

      SupplierConfirmationControlKey                                 as ConfirmationControl,

      SupplierConfirmationControlKey,

      OverdelivTolrtdLmtRatioInPct,

      UnlimitedOverdeliveryIsAllowed,

      IncotermsClassification,

      IncotermsLocation1,
      
      IncotermsLocation2,
      
      IncotermsSupChnLoc1AddlUUID,
      
      IncotermsSupChnLoc2AddlUUID,
      
      IncotermsSupChnDvtgLocAddlUUID,      

      InvoiceIsExpected,

      InvoiceIsGoodsReceiptBased,

      PurgDocPriceDate,

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'PurchasingInfoRecordUpdateCode'
      PurchasingInfoRecordUpdateCode                                 as IsInfoRecordUpdated,

      PurchasingInfoRecordUpdateCode,

      PurchasingInfoRecord,

      PurgDocReleaseOrderQuantity,

      PurgDocOrderAcknNumber,

      PurchasingPriceIsEstimated                                     as PurgDocEstimatedPrice,

      cast (IsInfoAtRegistration as mm_oa_infoatregn)                as IsInfoAtRegistration,
      
      SupplierSubrange,

      NoDaysReminder1,

      NoDaysReminder2,

      NoDaysReminder3,

      PlannedDeliveryDurationInDays,

      StockType,

      TaxCode,

      TaxCountry,

      TaxDeterminationDate,

      RequirementTracking,

      IsOrderAcknRqd,

      ShippingInstruction,
      
      ShippingType,

      GoodsReceiptIsNonValuated,

      ServicePerformer,

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'ProductTypeCode'
      ProductTypeCode                                                as ProductType,

      ProductTypeCode,

      MaterialType,

      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'PurchaseContractItemFormatted'
      cast(PurchaseContractItemUniqueID as char15 )                 as FormattedPurchaseContractItem,

      cast(PurchaseContractItemUniqueID as char15 )                 as PurchaseContractItemFormatted,

      PurchasingContractDeletionCode,

      PurchaseRequisition,

      PurchaseRequisitionItem,

      PartialInvoiceDistribution,

      ManufacturerPartNmbr                                           as ManufacturerPartNmbr,

      Manufacturer                                                   as Manufacturer,

      PlndOrderReplnmtElmntType                                      as PurContractItmReplnmtElmntType,

      //Added for Item hierarchy

      PurchasingParentItem,
      IsStatisticalItem,
      PurgConfigurableItemNumber,
      PurgDocAggrgdSubitemCategory,
      PurgExternalSortNumber,

      // fields from product compliance

      PurgProdCmplncSupplierStatus,
      PurgProductMarketabilityStatus,
      PurgSafetyDataSheetStatus,
      PurgProdCmplncDngrsGoodsStatus,
      
      PurchasingIsCatalogRelevant,
      
      @ObjectModel.text.element: ['PurgCatName']
      @Consumption.labelElement: 'PurgCatName'
      _PurchasingCategoryMatlGroup._PurchasingCategory.PurchasingCategory,
      @Semantics.text: true
      _PurchasingCategoryMatlGroup._PurchasingCategory.PurgCatName,

      //_PurchaseContract.PurchaseContractType                 as PurchaseContractType,


      _PurchaseContract.PurchasingOrganization               as PurchasingOrganization,

      //_PurchaseContract.PurchasingGroup                      as PurchasingGroup,


      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT , #TO_COMPOSITION_ROOT ]
      _PurchaseContract,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD]
      _PurCtrAccount,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD]
      _PurCtrAddress,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD]
      _Purctritnotes,

      @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD]
      _PurCtrCndItem,

      _PurchaseContractHistory,

      _MaterialGroup,

      _Plant,

      _StorageLocation,

      _Material,

      _OrderQuantityUnit,

      _VolumeUnit,

      _OrderPriceUnit,

      _DocumentCurrency

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_PURCHASECONTRACT",
"I_PURCHASINGCATEGORY",
"I_PURCHASINGCATEGORYMATLGROUP",
"R_PURCHASECONTRACTITEM"
],
"ASSOCIATED":
[
"E_PURCHASINGDOCUMENTITEM",
"I_CURRENCY",
"I_MATERIAL",
"I_MATERIALGROUP",
"I_PLANT",
"I_PURCHASECONTRACT",
"I_PURCHASECONTRACTHISTORY",
"I_PURCHASINGCATEGORYMATLGROUP",
"I_PURCTRACCOUNT",
"I_PURCTRADDRESS",
"I_PURCTRCNDITEM",
"I_PURCTRITNOTES",
"I_STORAGELOCATION",
"I_UNITOFMEASURE"
],
"BASE":
[
"R_PURCHASECONTRACTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/