P_MfgOrderEvtBsdVariance1

@AbapCatalog.sqlViewName: 'PMFGORDEBVARC1'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@VDM.private: true
define view P_MfgOrderEvtBsdVariance1 
  with parameters
    P_Ledger               : fins_ledger,
    P_FromFiscalYearPeriod : fins_fyearperiod,
    P_ToFiscalYearPeriod   : fins_fyearperiod
  as select from I_JournalEntryItem 
{
  key Ledger,
  key CompanyCode,
  key case
        when OrderID <> '' then OrderID
        else OriginOrder // V-Price Variance (BSX transaction)

      end                                                              as OrderID,
  key OrderItem,
  key ChartOfAccounts,
  key cast(
        case
            when VarianceOriginGLAccount is not initial then VarianceOriginGLAccount
            else OffsettingAccount
        end
      as fis_racct)                                                    as GLAccount,
  key OriginProduct,
  key OriginCostCenter,
  key OriginCostCtrActivityType,
  key SubLedgerAcctLineItemType,

      sum(AmountInCompanyCodeCurrency)                                 as AmountInCompanyCodeCurrency,
      sum(AmountInGlobalCurrency)                                      as AmountInGlobalCurrency,
      sum(AmountInFreeDefinedCurrency1)                                as AmountInFreeDefinedCurrency1,
      sum(AmountInFreeDefinedCurrency2)                                as AmountInFreeDefinedCurrency2,
      sum(AmountInFreeDefinedCurrency3)                                as AmountInFreeDefinedCurrency3,
      sum(AmountInFreeDefinedCurrency4)                                as AmountInFreeDefinedCurrency4,
      sum(AmountInFreeDefinedCurrency5)                                as AmountInFreeDefinedCurrency5,
      sum(AmountInFreeDefinedCurrency6)                                as AmountInFreeDefinedCurrency6,
      sum(AmountInFreeDefinedCurrency7)                                as AmountInFreeDefinedCurrency7,
      sum(AmountInFreeDefinedCurrency8)                                as AmountInFreeDefinedCurrency8
}
where
       BusinessTransactionCategory  =  'EBVP'
  and  TransactionTypeDetermination <> 'GBB'
  and  FiscalYearPeriod             >= :P_FromFiscalYearPeriod
  and  FiscalYearPeriod             <= :P_ToFiscalYearPeriod
  and  Ledger                       =  :P_Ledger
group by
  Ledger,
  CompanyCode,
  OrderID,
  OriginOrder,
  OrderItem,
  ChartOfAccounts,
  VarianceOriginGLAccount,
  OffsettingAccount,
  OriginProduct,
  OriginCostCenter,
  OriginCostCtrActivityType,
  SubLedgerAcctLineItemType
  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_JOURNALENTRYITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/