P_EBOC_OrderPlanCost1

@AbapCatalog.sqlViewName: 'PEBOCPLNCST1'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #COMPOSITE
@VDM.private: true

define view P_EBOC_OrderPlanCost1
  with parameters
    P_OrderID              : fis_order_number,
    P_FromFiscalYearPeriod : fis_jahrper,
    P_ToFiscalYearPeriod   : fis_jahrper,
    P_Ledger               : fins_ledger
  as select from I_FinancialPlanningEntryItem
{
  key CompanyCode,
  key Plant,
  key ControllingArea,
  key PlanningCategory,
  key cast(GLAccount as fis_saknr)      as CostElement,
  key BusinessTransactionCategory,
  key ControllingDebitCreditCode,
  key case
         when BusinessTransactionCategory = 'KPPP' then 'P'
         else 'S'
       end                              as CtrlgOriginClassification,
  key OrderID,
  key cast(
        case AccountAssignmentType
          when 'OR' then '0000'
          else OrderItem
        end
      as co_posnr)                      as OrderItem,
  key AccountAssignmentType,
  key PartnerAccountAssignmentType,
  key PartnerCostCenter,
  key PartnerCostCtrActivityType,
  key PartnerOrder_2                    as PartnerOrder,
  key CostSourceUnit                    as UnitOfMeasure,
  key Material,
  key IsLotSizeIndependent,
  key CostOriginGroup,
  key OriginCostCenter,
  key OriginCostCtrActivityType,

      sum(AmountInCompanyCodeCurrency)  as AmountInCompanyCodeCurrency,
      sum(AmountInGlobalCurrency)       as AmountInGlobalCurrency,
      sum(FixedAmountInGlobalCrcy)      as FixedAmountInGlobalCrcy,

      sum(AmountInFreeDefinedCurrency1) as AmountInFreeDefinedCurrency1,
      sum(AmountInFreeDefinedCurrency2) as AmountInFreeDefinedCurrency2,
      sum(AmountInFreeDefinedCurrency3) as AmountInFreeDefinedCurrency3,
      sum(AmountInFreeDefinedCurrency4) as AmountInFreeDefinedCurrency4,
      sum(AmountInFreeDefinedCurrency5) as AmountInFreeDefinedCurrency5,
      sum(AmountInFreeDefinedCurrency6) as AmountInFreeDefinedCurrency6,
      sum(AmountInFreeDefinedCurrency7) as AmountInFreeDefinedCurrency7,
      sum(AmountInFreeDefinedCurrency8) as AmountInFreeDefinedCurrency8,

      sum(ValuationQuantity)            as Quantity
}
where
  (
       AccountAssignmentType =  'OR'
    or AccountAssignmentType =  'OP'
  )
  and  OrderID               =  :P_OrderID
  and  Ledger                =  :P_Ledger
  and  FiscalYearPeriod      >= :P_FromFiscalYearPeriod
  and  FiscalYearPeriod      <= :P_ToFiscalYearPeriod

group by
  CompanyCode,
  Plant,
  ControllingArea,
  PlanningCategory,
  GLAccount,
  BusinessTransactionCategory,
  ControllingDebitCreditCode,
  OrderID,
  AccountAssignmentType,
  OrderItem,
  PartnerAccountAssignmentType,
  PartnerCostCenter,
  PartnerCostCtrActivityType,
  PartnerOrder_2,
  CostSourceUnit,
  Material,
  IsLotSizeIndependent,
  CostOriginGroup,
  OriginCostCenter,
  OriginCostCtrActivityType
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FINANCIALPLANNINGENTRYITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/