P_CollectionsAccountNote

DDL: P_COLLECTIONSACCOUNTNOTE Type: view COMPOSITE

P_CollectionsAccountNote is a Composite CDS View in SAP S/4HANA. It reads from 2 data sources (I_BPCollectionsSegmentAssgmt, I_BusinessPartnerCustomer) and exposes 6 fields with key fields Customer, CollectionSegment. It has 2 associations to related views.

2 data source(s) 6 fields

Data Sources (2)

SourceAliasJoin Type
I_BPCollectionsSegmentAssgmt I_BPCollectionsSegmentAssgmt inner
I_BusinessPartnerCustomer I_BusinessPartnerCustomer inner

Associations (2)

CardinalityTargetAliasCondition
[0..*] Sgbt_Nte_Cds_Cont _NoteContent $projection.ObjectKey = _NoteContent.objectid and _NoteContent.objectnodetype = 'CollectionsManagementAccount' and _NoteContent.notetype = 'COLL_PR_ACCOUNT'
[0..1] I_Customer _Customer $projection.Customer = _Customer.Customer

Annotations (12)

NameValueLevelField
AbapCatalog.sqlViewName PCLLSACCNTE view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #NOT_REQUIRED view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
VDM.viewType #COMPOSITE view
VDM.private true view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.representativeKey Customer view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY Customer I_Customer Customer
KEY CollectionSegment CollectionSegment
ObjectKey
_NoteContent _NoteContent
_Customer _Customer
_CollectionSegment _CollectionSegment 
@AbapCatalog: { sqlViewName: 'PCLLSACCNTE',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #NOT_REQUIRED,
                  personalData:       { blocking: #BLOCKED_DATA_EXCLUDED } }
@VDM: { viewType: #COMPOSITE,
        private: true }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #C,
                             sizeCategory: #L,
                             dataClass: #TRANSACTIONAL },
                representativeKey: 'Customer' }
define view P_CollectionsAccountNote
  as select distinct from I_Customer
    inner join            I_BusinessPartnerCustomer    on I_Customer.Customer = I_BusinessPartnerCustomer.Customer
    inner join            I_BPCollectionsSegmentAssgmt on  I_BusinessPartnerCustomer.BusinessPartner                  = I_BPCollectionsSegmentAssgmt.BusinessPartner
                                                       and I_BPCollectionsSegmentAssgmt.BPCollSgmtAssignmentValidFrom <= $session.system_date
                                                       and I_BPCollectionsSegmentAssgmt.BPCollSgmtAssignmentValidTo   >= $session.system_date

  // VDM Association

  association [0..*] to Sgbt_Nte_Cds_Cont as _NoteContent on  $projection.ObjectKey       = _NoteContent.objectid
                                                          and _NoteContent.objectnodetype = 'CollectionsManagementAccount'
                                                          and _NoteContent.notetype       = 'COLL_PR_ACCOUNT'

  association [0..1] to I_Customer        as _Customer    on  $projection.Customer = _Customer.Customer

{

      // VDM Fields

  key I_Customer.Customer                            as Customer,
  key CollectionSegment,
      concat(I_Customer.Customer, CollectionSegment) as ObjectKey,

      // Exposed Associations

      _NoteContent,
      _Customer,
      _CollectionSegment

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPCOLLECTIONSSEGMENTASSGMT",
"I_BUSINESSPARTNERCUSTOMER",
"I_CUSTOMER"
],
"ASSOCIATED":
[
"I_COLLECTIONSEGMENT",
"I_CUSTOMER",
"SGBT_NTE_CDS_CONT"
],
"BASE":
[
"I_BPCOLLECTIONSSEGMENTASSGMT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More