I_WorkPackage

@AbapCatalog: {
  sqlViewName: 'IWORKPCKG',
  preserveKey: true,
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  privilegedAssociations: [ '_EngagementProjFinancialPlan' ],
  personalData.blocking: #NOT_REQUIRED
}
@Analytics: {
  dataCategory: #DIMENSION,
  dataExtraction.enabled: true
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Work Package'
@Metadata: {
  allowExtensions: true,
  ignorePropagatedAnnotations: true
}
@ObjectModel: {
  usageType: {
    serviceQuality: #A,
    sizeCategory: #L,
    dataClass: #TRANSACTIONAL
  },
  modelingPattern: #ANALYTICAL_DIMENSION,
  supportedCapabilities: [ #ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE,
                           #EXTRACTION_DATA_SOURCE, #SQL_DATA_SOURCE ],
  representativeKey: 'WorkPackage'
}
@VDM: {
//  private: false,

  lifecycle.contract.type: #PUBLIC_LOCAL_API,
  viewType: #BASIC
}
define view I_WorkPackage
  as select from /cpd/d_pfp_ps as WorkPackage

  association [1]    to I_EngagementProjFinancialPlan  as _EngagementProjFinancialPlan on  $projection.EngagementProjFinPlanUUID = _EngagementProjFinancialPlan.EngagementProjFinPlanUUID
  association [0..1] to I_WBSElementBasicData          as _WBSElement                  on  $projection.WBSElementObject = _WBSElement.WBSElementObject
  association [0..1] to I_SalesOrder                   as _SalesOrder                  on  $projection.SalesOrder = _SalesOrder.SalesOrder
  association [0..1] to I_SalesOrderItem               as _SalesOrderItem              on  $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
                                                                                       and $projection.SalesOrder     = _SalesOrderItem.SalesOrder
  association [0..*] to I_EngagementProjectPlanData    as _EngagementProjectPlanData   on  $projection.EngagementProjFinPlanUUID = _EngagementProjectPlanData.EngagementProjFinPlanUUID
                                                                                       and $projection.WorkPackage               = _EngagementProjectPlanData.WorkPackage

  association [0..*] to I_WorkPackageWorkItem          as _WorkPackageWorkItem         on  $projection.WorkPackage               = _WorkPackageWorkItem.WorkPackage
                                                                                       and $projection.EngagementProjFinPlanUUID = _WorkPackageWorkItem.EngagementProjFinPlanUUID
  association [0..1] to E_Workpackage                  as _Extension                   on  WorkPackage.db_key = _Extension.WorkPackageUUID

  //This association is used to map WorPackageSet with PlanDataSet in SEGW

  association [0..*] to I_ExtSrvcWrkPckgPlnByPerd      as _ExtSrvcWrkPckgPlnByPerd     on  $projection.EngagementProjFinPlanUUID = _ExtSrvcWrkPckgPlnByPerd.EngagementProjFinPlanUUID
                                                                                       and $projection.WorkPackage               = _ExtSrvcWrkPckgPlnByPerd.WorkPackage

  //This association is used to map WorPackageSet with WorkPackageFunctionSet in SEGW

  association [1..*] to I_WorkPackageWithFunctionValue as _WorkPackageFunction         on  $projection.WorkPackage = _WorkPackageFunction.WorkPackage

{

      @ObjectModel.text.element: 'WorkPackageName'
  key WorkPackage.plan_item_id                                                as WorkPackage,
      cast( WorkPackage.db_key    as /cpd/wp_db_key preserving type )         as WorkPackageUUID,
      cast(WorkPackage.parent_key    as /cpd/eng_pfp_db_key preserving type ) as EngagementProjFinPlanUUID,
      @Semantics.text: true
      WorkPackage.plan_item_name                                              as WorkPackageName,
      WorkPackage.start_date                                                  as WorkPackageStartDate,
      WorkPackage.end_date                                                    as WorkPackageEndDate,
      WorkPackage.mapped_item_id                                              as WBSElementObject,
      WorkPackage.mapped_item_desc                                            as WBSDescription,
      //--[ GENERATED:012:GlBfhyJl7kY4nF6H}hes6m

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_SalesOrderStdVH',
                     element: 'SalesOrder' }
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_SalesOrder'
      WorkPackage.sales_order_hdr                                             as SalesOrder,
      //--[ GENERATED:012:GlBfhyJl7kY4nF6H}hes6m

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_SalesOrderItemStdVH',
                     element: 'SalesOrderItem' },
          additionalBinding: [{ localElement: 'SalesOrder',
                                element: 'SalesOrder' }]
        }]
      // ]--GENERATED

      @ObjectModel.foreignKey.association: '_SalesOrderItem'
      WorkPackage.so_item_id                                                  as SalesOrderItem,
      WorkPackage.changed_by                                                  as LastChangedByUser,
      @Semantics.dateTime:true
      @Semantics.systemDateTime.lastChangedAt:true
      cast(WorkPackage.changed_on as /cpd/cpm_changedon)                      as LastChangeDateTime,
      WorkPackage.created_by                                                  as CreatedByUser,
      @Semantics.dateTime:true
      @Semantics.systemDateTime.createdAt:true
      cast(WorkPackage.created_on as /cpd/cpm_createdon)                      as CreationDateTime,
      WorkPackage.plan_item_type                                              as WorkPackageType,



      /* Associations */
      _EngagementProjFinancialPlan,
      _EngagementProjectPlanData,
      _WBSElement,
      _SalesOrder,
      _SalesOrderItem,
      _WorkPackageWorkItem,
      _ExtSrvcWrkPckgPlnByPerd,
      _WorkPackageFunction

}

where
  WorkPackage.is_deleted = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"/CPD/D_PFP_PS"
],
"ASSOCIATED":
[
"E_WORKPACKAGE",
"I_ENGAGEMENTPROJECTPLANDATA",
"I_ENGAGEMENTPROJFINANCIALPLAN",
"I_EXTSRVCWRKPCKGPLNBYPERD",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_WBSELEMENTBASICDATA",
"I_WORKPACKAGEWITHFUNCTIONVALUE",
"I_WORKPACKAGEWORKITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/