C_WorkpackageDetails

@AbapCatalog.sqlViewName: 'CWORKPKGDETAIL'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@EndUserText.label: 'Work Package Details'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.authorizationCheck:#CHECK
@AccessControl.personalData.blocking:#REQUIRED
@VDM.viewType: #CONSUMPTION
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'C_WorkPackage'
/* As of 2302 release, this view is deprecated. Please do not use this view and refer to it's successor. */
define view C_WorkpackageDetails
  as select from           I_WorkPackage              as WorkPackage

    left outer to one join C_EngagementProjectDetails as EngagementProject   on EngagementProject.EngagementProjFinPlanUUID = WorkPackage.EngagementProjFinPlanUUID

    left outer to one join C_WorkPackagePlanData      as WorkPackagePlanData on  WorkPackagePlanData.WorkPackage     = WorkPackage.WorkPackage
                                                                             and EngagementProject.EngagementProject = WorkPackagePlanData.EngagementProject

    left outer to one join P_WorkPackageWorkItemCount as WorkItemCount       on WorkItemCount.WorkPackage = WorkPackage.WorkPackage

  association [0..*] to C_WorkpackageMember            as _WorkpackageMember   on  $projection.WorkPackage = _WorkpackageMember.WorkPackage

  association [0..1] to C_EngagementProjectDetails     as _EngagementProject   on  $projection.EngagementProjFinPlanUUID = _EngagementProject.EngagementProjFinPlanUUID

  association [0..1] to E_Workpackage                  as _Extension           on  $projection.WorkPackageUUID = _Extension.WorkPackageUUID

  association [0..*] to C_WorkpackageWorkItem          as _WorkPackageWorkItem on  $projection.WorkPackage               = _WorkPackageWorkItem.WorkPackage
                                                                               and $projection.EngagementProjFinPlanUUID = _WorkPackageWorkItem.EngagementProjFinPlanUUID

  association [0..*] to I_EngmntProjectUnitDataVersion as _UnitPlanData        on  $projection.WorkPackage = _UnitPlanData.WorkPackage

  association [0..1] to I_UnitOfMeasure                as _UnitOfMeasure       on  $projection.WorkPackageUnitUoM = _UnitOfMeasure.UnitOfMeasure

  association [0..1] to I_EngagementProjectResource    as _WorkPackageUnit     on  $projection.WorkPackageUnit                    = _WorkPackageUnit.EngagementProjectResource
                                                                               and _WorkPackageUnit.EngagementProjectResourceType = '0SRV'


{
  WorkPackage.WorkPackage                as WorkPackage,
  WorkPackage.WorkPackageUUID            as WorkPackageUUID,
  WorkPackage.EngagementProjFinPlanUUID  as EngagementProjFinPlanUUID,
  WorkPackage.WorkPackageName            as WorkPackageName,
  WorkPackage.WorkPackageStartDate       as WorkPackageStartDate,
  WorkPackage.WorkPackageEndDate         as WorkPackageEndDate,
  WorkPackage.WBSElementObject           as WBSElementObject,
  WorkPackage.WBSDescription             as WBSDescription,
  //--[ GENERATED:012:GlBfhyJl7jY4oBIOE}WCZW

  @Consumption.valueHelpDefinition: [
    { entity:  { name:    'I_SalesOrderStdVH',
                 element: 'SalesOrder' }
    }]
  // ]--GENERATED

  WorkPackage.SalesOrder                 as SalesOrder,
  //--[ GENERATED:012:GlBfhyJl7jY4oBIOE}WCZW

  @Consumption.valueHelpDefinition: [
    { entity:  { name:    'I_SalesOrderItemStdVH',
                 element: 'SalesOrderItem' },
      additionalBinding: [{ localElement: 'SalesOrder',
                            element: 'SalesOrder' }]
    }]
  // ]--GENERATED

  WorkPackage.SalesOrderItem             as SalesOrderItem,
  WorkPackage.LastChangedByUser          as LastChangedByUser,
  @Semantics.dateTime:true
  @Semantics.systemDateTime.lastChangedAt:true
  WorkPackage.LastChangeDateTime         as LastChangeDateTime,
  WorkPackage.WorkPackageType            as WorkPackageType,

  @Semantics.currencyCode: true
  WorkPackagePlanData.Currency           as Currency,

  @Semantics.amount.currencyCode: 'Currency'
  WorkPackagePlanData.PlndCostAmt        as PlndCostAmt,
  WorkPackagePlanData.PlndEffortQty      as PlndEffortQty,

  @Semantics.amount.currencyCode: 'Currency'
  WorkPackagePlanData.PlndRevnAmt        as PlndRevnAmt,

  @Semantics.amount.currencyCode: 'Currency'
  WorkPackagePlanData.PlannedUnitRevenue as PlannedUnitRevenue,

  WorkPackagePlanData.WorkPackageUnit    as WorkPackageUnit,
  @Semantics.quantity.unitOfMeasure:'WorkPackageUnitUoM'
  WorkPackagePlanData.PlanUnitQuantity   as WorkPackageUnitQuantity,
  @Semantics.unitOfMeasure: true
  WorkPackagePlanData.WorkPackageUnitUoM as WorkPackageUnitUoM,
  @Semantics.dateTime:true
  @Semantics.systemDateTime.createdAt:true
  WorkPackage.CreationDateTime           as CreationDateTime,
  WorkPackage.CreatedByUser              as CreatedByUser,
  WorkItemCount.NumberOfWorkItems        as NumberOfWorkItems,
  EngagementProject.EngagementProject    as EngagementProject,

  /* Associations */
  WorkPackage._EngagementProjFinancialPlan,
  WorkPackage._SalesOrder,
  WorkPackage._SalesOrderItem,
  WorkPackage._WBSElement,
  WorkPackage._EngagementProjectPlanData,
  _WorkpackageMember,
  _WorkPackageWorkItem,
  _EngagementProject,
  _UnitPlanData,
  _WorkPackageUnit,
  _UnitOfMeasure
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"C_ENGAGEMENTPROJECTDETAILS",
"C_WORKPACKAGEPLANDATA",
"I_WORKPACKAGE",
"P_WORKPACKAGEWORKITEMCOUNT"
],
"ASSOCIATED":
[
"C_ENGAGEMENTPROJECTDETAILS",
"C_WORKPACKAGEMEMBER",
"C_WORKPACKAGEWORKITEM",
"E_WORKPACKAGE",
"I_ENGAGEMENTPROJECTPLANDATA",
"I_ENGAGEMENTPROJECTRESOURCE",
"I_ENGAGEMENTPROJFINANCIALPLAN",
"I_ENGMNTPROJECTUNITDATAVERSION",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_UNITOFMEASURE",
"I_WBSELEMENTBASICDATA"
],
"BASE":
[
"I_WORKPACKAGE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/