I_EngmntProjFcstCube

@AbapCatalog.sqlViewName: 'IEPFCSTCUBE'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #COMPOSITE
@Analytics: { dataCategory: #CUBE }
@AbapCatalog.preserveKey: true
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'I_ENGMNTPROJFCSTCUBE_2'
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Forecast Info for Engmnt Project - Cube'
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Metadata.allowExtensions:true
@Metadata.ignorePropagatedAnnotations: true
define view I_EngmntProjFcstCube
  as select from    I_EngagementProject           as EngagementProject

    inner join      I_EngagementProjFinancialPlan as EngagementProjFinancialPlan on EngagementProject.EngagementProjectUUID = EngagementProjFinancialPlan.EngagementProjectUUID

    left outer join I_WorkPackage                 as WorkPackage                 on  EngagementProjFinancialPlan.EngagementProjFinPlanUUID =  WorkPackage.EngagementProjFinPlanUUID
                                                                                 and WorkPackage.WorkPackageType                           <> 'U'

    inner join      I_WrkPckgPlnActlMappg         as EngmntProjWrkPckgPlanActual on  EngagementProject.EngagementProject = EngmntProjWrkPckgPlanActual.EngagementProject
                                                                                 and WorkPackage.WorkPackage             = EngmntProjWrkPckgPlanActual.WorkPackage

  association [0..1] to I_EngagementProject         as _EngagementProject             on  $projection.EngagementProject = _EngagementProject.EngagementProject

  association [0..1] to I_WorkPackage               as _WorkPackage                   on  $projection.WorkPackage = _WorkPackage.WorkPackage

  association [0..1] to I_SalesOrder                as _SalesOrder                    on  $projection.SalesOrder = _SalesOrder.SalesOrder

  association [0..1] to I_SalesOrderItem            as _SalesOrderItem                on  $projection.SalesOrderItem = _SalesOrderItem.SalesOrderItem
                                                                                      and $projection.SalesOrder     = _SalesOrderItem.SalesOrder

  association [0..1] to I_EngagementProjectResource as _EngagementProjectResource     on  $projection.EngagementProjectResource     = _EngagementProjectResource.EngagementProjectResource
                                                                                      and $projection.EngagementProjectResourceType = _EngagementProjectResource.EngagementProjectResourceType

  association [0..1] to I_WorkPackageWorkItem       as _WorkItem                      on  $projection.WorkItem    = _WorkItem.WorkItem
                                                                                      and $projection.WorkPackage = _WorkItem.WorkPackage

  association [0..1] to I_Currency                  as _Currency                      on  $projection.Currency = _Currency.Currency

  association [0..1] to I_UnitOfMeasure             as _UnitOfMeasure                 on  $projection.UnitOfMeasure = _UnitOfMeasure.UnitOfMeasure

  association [0..1] to I_EngagementProjectSrvcOrg  as _EngmntProjectDeliveryOrg      on  $projection.EngmntProjectDeliveryOrg = _EngmntProjectDeliveryOrg.EngagementProjectServiceOrg

  association [0..1] to I_EngagementProjectSrvcOrg  as _EngagementProjectSrvcOrg      on  $projection.EngagementProjectServiceOrg = _EngagementProjectSrvcOrg.EngagementProjectServiceOrg

  association [0..1] to I_EngmntProjResourceType    as _EngagementProjectResourceType on  $projection.EngagementProjectResourceType = _EngagementProjectResourceType.EngagementProjectResourceType
{
  @ObjectModel.foreignKey.association: '_EngagementProject'
  cast(EngagementProject.EngagementProject as /cpd/project )                    as EngagementProject,
  EngagementProject.EngagementProjectName                                       as EngagementProjectName,

  @ObjectModel.foreignKey.association: '_EngagementProjectSrvcOrg'
  EngagementProject.EngagementProjectServiceOrg,

  EngmntProjWrkPckgPlanActual.EngagementProjFinPlanUUID,

  @ObjectModel.foreignKey.association: '_WorkPackage'
  cast (WorkPackage.WorkPackage as /cpd/workpackage)                            as WorkPackage,

  WorkPackage.WorkPackageName                                                   as WorkPackageName,

  WorkPackage.WorkPackageStartDate                                              as WorkPackageStartDate,

  WorkPackage.WorkPackageEndDate                                                as WorkPackageEndDate,

  @ObjectModel.foreignKey.association: '_WorkItem'
  cast(EngmntProjWrkPckgPlanActual.WorkItem as  /cpd/workitem )                 as WorkItem,

  @ObjectModel.foreignKey.association: '_EngagementProjectResourceType'
  EngmntProjWrkPckgPlanActual.EngagementProjectResourceType                     as EngagementProjectResourceType,


  @ObjectModel.foreignKey.association: '_EngagementProjectResource'
  cast (EngmntProjWrkPckgPlanActual.EngagementProjectResource as /cpd/resource) as EngagementProjectResource,


  @EndUserText.label: 'Month'
  EngmntProjWrkPckgPlanActual.FiscalPeriod                                      as FiscalPeriod,
  @EndUserText.label: 'Year'
  EngmntProjWrkPckgPlanActual.FiscalYear                                        as FiscalYear,


  @EndUserText.label: 'Year/Month'
  EngmntProjWrkPckgPlanActual.FiscalYearPeriod                                  as FiscalYearPeriod,

  @ObjectModel.foreignKey.association: '_Currency'
  @Semantics.currencyCode: true
  EngmntProjWrkPckgPlanActual.Currency                                          as Currency,

  @DefaultAggregation: #SUM
  @Semantics.amount.currencyCode: 'Currency'
  cast(EngmntProjWrkPckgPlanActual.PlndCostAmt as /cpd/plan_cost)               as PlndCostAmt,

  @DefaultAggregation: #SUM
  @Semantics.amount.currencyCode: 'Currency'
  cast(EngmntProjWrkPckgPlanActual.ActlCostAmt as /cpd/actual_cost)             as ActlCostAmt,

  @DefaultAggregation: #SUM
  @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
  cast(EngmntProjWrkPckgPlanActual.SupplyEffortQty as /cpd/planned_effort)      as SupplyEffortQty,


  @ObjectModel.foreignKey.association: '_UnitOfMeasure'
  @Semantics.unitOfMeasure:true
  EngmntProjWrkPckgPlanActual.UnitOfMeasure                                     as UnitOfMeasure,

  @DefaultAggregation: #SUM
  @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
  cast(EngmntProjWrkPckgPlanActual.PlndEffortQty as /cpd/planned_effort)        as PlndEffortQty,

  @DefaultAggregation: #SUM
  @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
  cast(EngmntProjWrkPckgPlanActual.ActlEffortQty as /cpd/actual_effort)         as ActlEffortQty,

  @DefaultAggregation: #SUM
  @Semantics.amount.currencyCode: 'Currency'
  EngmntProjWrkPckgPlanActual.ActualPlanDeviationCost                           as ActualPlanDeviationCost,

  @DefaultAggregation: #SUM
  @Semantics.quantity.unitOfMeasure: 'UnitOfMeasure'
  EngmntProjWrkPckgPlanActual.ActualPlanDeviationEffort                         as ActualPlanDeviationEffort,

  @ObjectModel.foreignKey.association: '_EngmntProjectDeliveryOrg'
  EngmntProjWrkPckgPlanActual.EngagementProjectServiceOrg                       as EngmntProjectDeliveryOrg,

  @ObjectModel.foreignKey.association: '_SalesOrder'
  WorkPackage.SalesOrder                                                        as SalesOrder,

  @ObjectModel.foreignKey.association: '_SalesOrderItem'
  WorkPackage.SalesOrderItem                                                    as SalesOrderItem,
  _SalesOrderItem.SalesOrderItemText                                            as SalesOrderItemText,


  EngmntProjWrkPckgPlanActual.EngmntProjPlanLineType                            as EngmntProjPlanLineType,

  _EngagementProject,
  _WorkPackage,
  _WorkItem,
  _EngagementProjectResourceType,
  _EngagementProjectResource,
  _Currency,
  _UnitOfMeasure,
  _EngagementProjectSrvcOrg,
  _SalesOrder,
  _SalesOrderItem,
  _EngmntProjectDeliveryOrg

}
where
  EngmntProjWrkPckgPlanActual.EngmtProjFinPlanVersion = '1';
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ENGAGEMENTPROJECT",
"I_ENGAGEMENTPROJFINANCIALPLAN",
"I_SALESORDERITEM",
"I_WORKPACKAGE",
"I_WRKPCKGPLNACTLMAPPG"
],
"ASSOCIATED":
[
"I_CURRENCY",
"I_ENGAGEMENTPROJECT",
"I_ENGAGEMENTPROJECTRESOURCE",
"I_ENGAGEMENTPROJECTSRVCORG",
"I_ENGMNTPROJRESOURCETYPE",
"I_SALESORDER",
"I_SALESORDERITEM",
"I_UNITOFMEASURE",
"I_WORKPACKAGE",
"I_WORKPACKAGEWORKITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/