@AbapCatalog.sqlViewName: 'IWLFSMTMGTDOCITM'
@AbapCatalog.preserveKey: true
@ObjectModel.representativeKey: 'SettlmtMgmtDocItem'
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XXL
@ClientHandling.type: #INHERITED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Settlement Management Document Item'
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: false }
@Analytics.internalName: #LOCAL
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: [ '_ProductText', '_SuplrSettlmtBusinessAreaText', '_CustSettlmtBusinessAreaText', '_CreatedByUser' ]
@AbapCatalog.compiler.compareFilter: true
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions:true
/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
define view I_SettlmtMgmtDocItem
as select from wbrp
inner join wbrk on wbrp.wbeln = wbrk.wbeln
inner join P_SettlDocItemAddInfo1 on wbrp.wbeln = P_SettlDocItemAddInfo1.wbeln
and wbrp.posnr = P_SettlDocItemAddInfo1.posnr
association [1..1] to I_SettlmtMgmtDoc as _SettlmtMgmtDoc on $projection.SettlmtMgmtDoc = _SettlmtMgmtDoc.SettlmtMgmtDoc
association [0..*] to I_SettlmtMgmtDocItemPartner as _Partner on $projection.SettlmtMgmtDoc = _Partner.SettlmtMgmtDoc
and $projection.SettlmtMgmtDocItem = _Partner.SettlmtMgmtDocItem
association [0..*] to R_SetlMgmtDocItmPlainLongText as _SetlMgmtDocItmPlainLongText on $projection.SettlmtMgmtDoc = _SetlMgmtDocItmPlainLongText.SettlmtMgmtDoc
and $projection.SettlmtMgmtDocItem = _SetlMgmtDocItmPlainLongText.SettlmtMgmtDocItem
association [0..1] to I_Currency as _SettlmtDocCurrency on $projection.SettlmtDocCurrency = _SettlmtDocCurrency.Currency
association [0..1] to I_Currency as _BusinessVolumeCurrency on $projection.BusinessVolumeCurrency = _BusinessVolumeCurrency.Currency
association [0..1] to I_SettlmtMgmtDocCat as _SettlmtMgmtDocCat on $projection.SettlmtMgmtDocCat = _SettlmtMgmtDocCat.SettlmtMgmtDocCat
association [0..*] to I_SetlMgmtDocItmSuplrPrcgElmnt as _SupplierPricingElement on $projection.SettlmtMgmtDoc = _SupplierPricingElement.SettlmtMgmtDoc
and $projection.SettlmtMgmtDocItem = _SupplierPricingElement.SettlmtMgmtDocItem
association [0..*] to I_SetlMgmtDocItmCustPrcgElmnt as _CustomerPricingElement on $projection.SettlmtMgmtDoc = _CustomerPricingElement.SettlmtMgmtDoc
and $projection.SettlmtMgmtDocItem = _CustomerPricingElement.SettlmtMgmtDocItem
association [0..1] to I_SettlmtPartnerCat as _SettlmtPartnerCat on $projection.SettlmtPartnerCat = _SettlmtPartnerCat.SettlmtPartnerCat
association [0..1] to I_SettlmtBusProcCat as _SettlmtBusProcCat on $projection.SettlmtBusProcCat = _SettlmtBusProcCat.SettlmtBusProcCat
// association [0..*] to I_PricingElement as _SupplierPricingElement on $projection.SupplierPricingDocument = _SupplierPricingElement.PricingDocument
// and $projection.SettlmtMgmtDocItem = _SupplierPricingElement.PricingDocumentItem
// association [0..*] to I_PricingElement as _CustomerPricingElement on $projection.CustomerPricingDocument = _CustomerPricingElement.PricingDocument
// and $projection.SettlmtMgmtDocItem = _CustomerPricingElement.PricingDocumentItem
association [0..1] to I_Product as _Product on $projection.Product = _Product.Product
// association [0..1] to I_ProductGroup as _ProductGroup on $projection.ProductGroup = _ProductGroup.MaterialGroup
association [0..1] to I_Plant as _Plant on $projection.Plant = _Plant.Plant
association [0..1] to I_Country as _TaxCountry on $projection.TaxCountry = _TaxCountry.Country
association [0..1] to I_Country as _IntercompanyTaxCountry on $projection.IntercompanyTaxCountry = _IntercompanyTaxCountry.Country
association [0..1] to I_UnitOfMeasure as _SettlmtQuantityUnit on $projection.SettlmtQuantityUnit = _SettlmtQuantityUnit.UnitOfMeasure
// views not needed anymore in the basis view:
// association [0..1] to I_TaxCode as _SupplierTaxCode on $projection.SupplierTaxCalculationProced = _SupplierTaxCode.TaxCalculationProcedure
// and $projection.SupplierTaxCode = _SupplierTaxCode.TaxCode
// association [0..1] to I_TaxCode as _CustomerTaxCode on $projection.CustomerTaxCalculationProced = _CustomerTaxCode.TaxCalculationProcedure
// and $projection.CustomerTaxCode = _CustomerTaxCode.TaxCode
association [0..1] to I_UnitOfMeasure as _NetPriceQuantityUnit on $projection.NetPriceQuantityUnit = _NetPriceQuantityUnit.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _BaseUnit on $projection.BaseUnit = _BaseUnit.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _ItemWeightUnit on $projection.ItemWeightUnit = _ItemWeightUnit.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _ItemVolumeUnit on $projection.ItemVolumeUnit = _ItemVolumeUnit.UnitOfMeasure
association [0..1] to I_SettlmtItmStatisticalPrpty as _SettlmtItmStatisticalPrpty on $projection.SettlmtItmStatisticalPrpty = _SettlmtItmStatisticalPrpty.SettlmtItmStatisticalPrpty
association [0..1] to I_SettlmtSourceDocCat as _SettlmtSourceDocCat on $projection.SettlmtSourceDocCat = _SettlmtSourceDocCat.SettlmtSourceDocCat
association [0..1] to I_SettlmtActivityReasonCode as _SettlmtItemActivityReason on $projection.SettlmtItemActivityReason = _SettlmtItemActivityReason.SettlmtActivityReason
association [0..1] to I_UnitOfMeasure as _ProductPurchasePointsQtyUnit on $projection.ProductPurchasePointsQtyUnit = _ProductPurchasePointsQtyUnit.UnitOfMeasure
association [0..1] to I_Supplier as _PriorSupplier on $projection.PriorSupplier = _PriorSupplier.Supplier
association [0..1] to I_InventoryValuationType as _InventoryValuationType on $projection.InventoryValuationType = _InventoryValuationType.InventoryValuationType
association [0..1] to I_BusinessArea as _SuplrSettlmtBusinessArea on $projection.SuplrSettlmtBusinessArea = _SuplrSettlmtBusinessArea.BusinessArea
association [0..1] to I_BusinessArea as _CustSettlmtBusinessArea on $projection.CustSettlmtBusinessArea = _CustSettlmtBusinessArea.BusinessArea
association [0..1] to I_ControllingArea as _SuplrSettlmtControllingArea on $projection.SuplrSettlmtControllingArea = _SuplrSettlmtControllingArea.ControllingArea
association [0..1] to I_CostCenter as _SuplrSettlmtCostCenter on $projection.SuplrSettlmtCostCenter = _SuplrSettlmtCostCenter.CostCenter
and $projection.SuplrSettlmtControllingArea = _SuplrSettlmtCostCenter.ControllingArea
and _SuplrSettlmtCostCenter.ValidityEndDate >= $projection.CreationDate
and _SuplrSettlmtCostCenter.ValidityStartDate <= $projection.CreationDate
association [0..1] to I_ProfitCenter as _SuplrSettlmtProfitCenter on $projection.SuplrSettlmtProfitCenter = _SuplrSettlmtProfitCenter.ProfitCenter
and $projection.SuplrSettlmtControllingArea = _SuplrSettlmtProfitCenter.ControllingArea
and _SuplrSettlmtProfitCenter.ValidityEndDate >= $projection.CreationDate
and _SuplrSettlmtProfitCenter.ValidityStartDate <= $projection.CreationDate
association [0..1] to I_IncotermsClassification as _IncotermsClassification on $projection.IncotermsClassification = _IncotermsClassification.IncotermsClassification
association [0..1] to I_IncotermsVersion as _IncotermsVersion on $projection.IncotermsVersion = _IncotermsVersion.IncotermsVersion
association [0..1] to I_ControllingArea as _CustSettlmtControllingArea on $projection.CustSettlmtControllingArea = _CustSettlmtControllingArea.ControllingArea
association [0..1] to I_CostCenter as _CustSettlmtCostCenter on $projection.CustSettlmtCostCenter = _CustSettlmtCostCenter.CostCenter
and $projection.CustSettlmtControllingArea = _CustSettlmtCostCenter.ControllingArea
and _CustSettlmtCostCenter.ValidityEndDate >= $projection.CreationDate
and _CustSettlmtCostCenter.ValidityStartDate <= $projection.CreationDate
association [0..1] to I_ProfitCenter as _CustSettlmtProfitCenter on $projection.CustSettlmtProfitCenter = _CustSettlmtProfitCenter.ProfitCenter
and $projection.CustSettlmtControllingArea = _CustSettlmtProfitCenter.ControllingArea
and _CustSettlmtProfitCenter.ValidityEndDate >= $projection.CreationDate
and _CustSettlmtProfitCenter.ValidityStartDate <= $projection.CreationDate
association [0..1] to I_SettlmtPrecdgDocCat as _SettlmtPrecdgDocCat on $projection.SettlmtPrecdgDocCat = _SettlmtPrecdgDocCat.SettlmtPrecdgDocCat
association [0..1] to I_SettlmtMgmtDocItemCat as _SettlmtMgmtDocItemCat on $projection.SettlmtMgmtDocItemCat = _SettlmtMgmtDocItemCat.SettlmtMgmtDocItemCat
association [0..1] to I_PurchasingDocument as _SettlmtItemReltdPurgDoc on $projection.SettlmtItemReltdPurgDoc = _SettlmtItemReltdPurgDoc.PurchasingDocument
association [0..1] to I_BillingDocument as _SettlmtItemReltdBillgDoc on $projection.SettlmtItemReltdBillgDoc = _SettlmtItemReltdBillgDoc.BillingDocument
association [0..1] to I_SettlmtMgmtDocItemStatus as _SettlmtMgmtDocItemStatus on $projection.SettlmtMgmtDocItemStatus = _SettlmtMgmtDocItemStatus.SettlmtMgmtDocItemStatus
association [0..1] to I_SettlmtMgmtDocItemCancld as _SettlmtMgmtDocItemCancld on $projection.SettlmtMgmtDocItemCancld = _SettlmtMgmtDocItemCancld.SettlmtMgmtDocItemCancld
//association [0..1] to I_Order as _SupplierSettlementOrder on $projection.SupplierSettlementOrder = _SupplierSettlementOrder.OrderID
association [0..1] to I_InternalOrder as _SupplierSettlementOrder on $projection.SupplierSettlementOrder = _SupplierSettlementOrder.InternalOrder
association [0..1] to I_SupplierItemSettlmtStatus as _SupplierItemSettlmtStatus on $projection.SupplierItemSettlmtStatus = _SupplierItemSettlmtStatus.SupplierItemSettlmtStatus
association [0..1] to I_CustomerItemSettlmtStatus as _CustomerItemSettlmtStatus on $projection.CustomerItemSettlmtStatus = _CustomerItemSettlmtStatus.CustomerItemSettlmtStatus
association [0..1] to I_SettlmtBlockingReasonCode as _SupplierItemSettlmtBlkgReason on $projection.SupplierItemSettlmtBlkgReason = _SupplierItemSettlmtBlkgReason.SettlmtBlockingReason
association [0..1] to I_SettlmtBlockingReasonCode as _CustomerItemSettlmtBlkgReason on $projection.CustomerItemSettlmtBlkgReason = _CustomerItemSettlmtBlkgReason.SettlmtBlockingReason
association [0..1] to I_ItemSettlmtRelevance as _ItemSettlmtRelevance on $projection.ItemSettlmtRelevance = _ItemSettlmtRelevance.ItemSettlmtRelevance
association [0..1] to I_CompanyCode as _SuplrSettlmtCompanyCode on $projection.SuplrSettlmtCompanyCode = _SuplrSettlmtCompanyCode.CompanyCode
association [0..1] to I_GLAccountInCompanyCode as _GLAccountInCompanyCode on $projection.GLAccount = _GLAccountInCompanyCode.GLAccount
and $projection.SuplrSettlmtCompanyCode = _GLAccountInCompanyCode.CompanyCode
association [0..1] to I_SettlmtMgmtDocItem as _HigherLevelItem on $projection.SettlmtMgmtDoc = _HigherLevelItem.SettlmtMgmtDoc
and $projection.HigherLevelItem = _HigherLevelItem.SettlmtMgmtDocItem
association [0..1] to I_ItemDistributionStatus as _ItemDistributionStatus on $projection.ItemDistributionStatus = _ItemDistributionStatus.ItemDistributionStatus
association [0..1] to I_LogicalSystem as _SettlmtRefDocLogicalSyst on $projection.SettlmtRefDocLogicalSyst = _SettlmtRefDocLogicalSyst.LogicalSystem
association [0..1] to I_SettlmtRefDocCat as _SettlmtRefDocCat on $projection.SettlmtRefDocCat = _SettlmtRefDocCat.SettlmtRefDocCat
association [0..1] to I_ItemIntrastatRelevance as _ItemIntrastatRelevance on $projection.ItemIntrastatRelevance = _ItemIntrastatRelevance.ItemIntrastatRelevance
association [0..1] to I_CompanyCode as _SettlmtRefDocCompanyCode on $projection.SettlmtRefDocCompanyCode = _SettlmtRefDocCompanyCode.CompanyCode
//association [0..1] to I_Order as _CustomerSettlementOrder on $projection.CustomerSettlementOrder = _CustomerSettlementOrder.OrderID
association [0..1] to I_InternalOrder as _CustomerSettlementOrder on $projection.CustomerSettlementOrder = _CustomerSettlementOrder.InternalOrder
association [0..1] to I_WBSElementBasicData as _SuplrSettlmtWBSElmntBasicData on $projection.SuplrSettlmtWBSElmntInternalID = _SuplrSettlmtWBSElmntBasicData.WBSElementInternalID
association [0..1] to I_WBSElementBasicData as _CustSettlmtWBSElmntBasicData on $projection.CustSettlmtWBSElmntInternalID = _CustSettlmtWBSElmntBasicData.WBSElementInternalID
association [0..1] to I_SettlmtMgmtDocItemCollSts as _SettlmtMgmtDocItemCollSts on $projection.SettlmtMgmtDocItemCollSts = _SettlmtMgmtDocItemCollSts.SettlmtMgmtDocItemCollSts
association [0..1] to I_SettlmtBlockingReasonCode as _CollSettlmtItemBlkgReason on $projection.CollSettlmtItemBlkgReason = _CollSettlmtItemBlkgReason.SettlmtBlockingReason
association [0..1] to I_ItmSettlmtDocCollRelevance as _ItmSettlmtDocCollRelevance on $projection.ItmSettlmtDocCollRelevance = _ItmSettlmtDocCollRelevance.ItmSettlmtDocCollRelevance
association [0..1] to I_LogicalSystem as _SettlmtAddlRefDocLogicalSyst on $projection.SettlmtAddlRefDocLogicalSyst = _SettlmtAddlRefDocLogicalSyst.LogicalSystem
association [0..1] to I_SettlmtAddlRefDocCat as _SettlmtAddlRefDocCat on $projection.SettlmtAddlRefDocCat = _SettlmtAddlRefDocCat.SettlmtAddlRefDocCat
association [0..1] to I_Customer as _CustomerSettlmtRecipient on $projection.CustomerSettlmtRecipient = _CustomerSettlmtRecipient.Customer
// association [0..1] to I_SupplierSubrange as _SupplierSubrange on $projection.SupplierSubrange = _SupplierSubrange.SupplierSubrange
// and $projection.PriorSupplier = _SupplierSubrange.Supplier
// association [0..1] to I_ProductHierarchy as _ProductHierarchy on $projection.ProductHierarchy = _ProductHierarchy.ProductHierarchy
association [0..1] to I_SalesSpcfcProductGroup1 as _SalesSpcfcProductGroup1 on $projection.SalesSpcfcProductGroup1 = _SalesSpcfcProductGroup1.SalesSpcfcProductGroup1
association [0..1] to I_SalesSpcfcProductGroup2 as _SalesSpcfcProductGroup2 on $projection.SalesSpcfcProductGroup2 = _SalesSpcfcProductGroup2.SalesSpcfcProductGroup2
association [0..1] to I_SalesSpcfcProductGroup3 as _SalesSpcfcProductGroup3 on $projection.SalesSpcfcProductGroup3 = _SalesSpcfcProductGroup3.SalesSpcfcProductGroup3
association [0..1] to I_SalesSpcfcProductGroup4 as _SalesSpcfcProductGroup4 on $projection.SalesSpcfcProductGroup4 = _SalesSpcfcProductGroup4.SalesSpcfcProductGroup4
association [0..1] to I_SalesSpcfcProductGroup5 as _SalesSpcfcProductGroup5 on $projection.SalesSpcfcProductGroup5 = _SalesSpcfcProductGroup5.SalesSpcfcProductGroup5
association [0..1] to I_ConditionContract as _SettlmtItemReltdCndnContr on $projection.SettlmtItemReltdCndnContr = _SettlmtItemReltdCndnContr.ConditionContract
association [0..*] to I_BusinessAreaText as _SuplrSettlmtBusinessAreaText on $projection.SuplrSettlmtBusinessArea = _SuplrSettlmtBusinessAreaText.BusinessArea
association [0..*] to I_BusinessAreaText as _CustSettlmtBusinessAreaText on $projection.CustSettlmtBusinessArea = _CustSettlmtBusinessAreaText.BusinessArea
association [0..*] to I_ProductText as _ProductText on $projection.Product = _ProductText.Product
association [0..1] to I_SalesOrganization as _SettlmtItemSalesOrganization on $projection.SettlmtItemSalesOrganization = _SettlmtItemSalesOrganization.SalesOrganization
association [0..1] to I_DistributionChannel as _SettlmtItmDistributionChannel on $projection.SettlmtItemDistributionChannel = _SettlmtItmDistributionChannel.DistributionChannel
association [0..1] to I_Division as _SettlmtItemDivision on $projection.SettlmtItemDivision = _SettlmtItemDivision.Division
association [0..1] to I_User as _CreatedByUser on $projection.CreatedByUser = _CreatedByUser.UserID
association [0..1] to I_SettlmtDateCat as _SettlmtDateCat on $projection.SettlmtDateCat = _SettlmtDateCat.SettlmtDateCat
association [0..1] to I_CndnContrType as _CndnContrType on $projection.CndnContrType = _CndnContrType.CndnContrType
association [0..1] to I_CndnContrProcVar as _CndnContrProcVar on $projection.CndnContrProcVar = _CndnContrProcVar.CndnContrProcVar
//Extension Association
association [1..1] to E_SettlmtMgmtDocItem as _Extension on $projection.SettlmtMgmtDoc = _Extension.SettlmtMgmtDoc
and $projection.SettlmtMgmtDocItem = _Extension.SettlmtMgmtDocItem
{
//key:
@ObjectModel.foreignKey.association: '_SettlmtMgmtDoc'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_SettlmtMgmtDocStdVH', element: 'SettlmtMgmtDoc' } }]
}
key wbrp.wbeln as SettlmtMgmtDoc,
key wbrp.posnr as SettlmtMgmtDocItem,
@Semantics.currencyCode: true
@ObjectModel.foreignKey.association: '_SettlmtDocCurrency'
cast( wbrk.waerl as waerl preserving type ) as SettlmtDocCurrency,
@ObjectModel.foreignKey.association: '_SettlmtMgmtDocCat'
wbrk.wdtyp as SettlmtMgmtDocCat,
cast( wbrk.knumv as wlf_knumv_k preserving type ) as SupplierPricingDocument,
cast( wbrk.knumvd as wlf_knumv_d preserving type ) as CustomerPricingDocument,
@ObjectModel.foreignKey.association: '_SettlmtPartnerCat'
wbrk.settl_party as SettlmtPartnerCat,
@ObjectModel.foreignKey.association: '_SettlmtBusProcCat'
wbrk.use_case as SettlmtBusProcCat,
@ObjectModel.foreignKey.association: '_Product'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_ProductVH', element: 'Product' } }]
}
cast( wbrp.matnr as productnumber preserving type ) as Product,
// @ObjectModel.foreignKey.association: '_ProductGroup'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_ProductGroupVH', element: 'ProductGroup' } }]
}
cast( wbrp.matkl as productgroup preserving type ) as ProductGroup,
@ObjectModel.foreignKey.association: '_Plant'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_PlantStdVH', element: 'Plant' } }]
}
wbrp.werks as Plant,
// fields were only needed to define a foreign key association which is not provided in the basis view anymore:
// cast( P_SettlDocAddInfo2.tax_kalsm as wlf_suplr_kalsm_d ) as SupplierTaxCalculationProced,
// cast( P_SettlDocAddInfo2.tax_kalsm_deb as wlf_cust_kalsm_d ) as CustomerTaxCalculationProced,
// @ObjectModel.foreignKey.association: '_SupplierTaxCode'
cast( wbrp.mwskz as wlf_mwskz_k preserving type ) as SupplierTaxCode,
// @ObjectModel.foreignKey.association: '_CustomerTaxCode'
cast( wbrp.mwsk2 as wlf_mwskz_d preserving type ) as CustomerTaxCode,
@ObjectModel.foreignKey.association: '_TaxCountry'
wbrp.tax_country as TaxCountry,
@ObjectModel.foreignKey.association: '_IntercompanyTaxCountry'
wbrp.tax_country_ic as IntercompanyTaxCountry,
wbrp.txdat_from_k as SuplrSettlmtTxRateValdFrmDate,
wbrp.txdat_from_d as CustSettlmtTxRateValdFrmDate,
wbrp.prsdt as PricingDate,
// @DefaultAggregation: #NONE
@Semantics.quantity.unitOfMeasure: 'SettlmtQuantityUnit'
wbrp.menge as SettlmtQuantity,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_SettlmtQuantityUnit'
wbrp.wfkme as SettlmtQuantityUnit,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
wbrp.netpr as NetPriceAmount,
// @DefaultAggregation: #NONE
@Semantics.quantity.unitOfMeasure: 'NetPriceQuantityUnit'
wbrp.peinh as NetPriceQuantity,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_NetPriceQuantityUnit'
wbrp.fprme as NetPriceQuantityUnit,
cast( wbrp.umrez as wlf_umwfz preserving type ) as SettlmtToBaseQuantityNmrtr,
cast( wbrp.umren as wlf_umwfn preserving type ) as SettlmtToBaseQuantityDnmntr,
cast( wbrp.fpumz as wlf_wpumz preserving type ) as SettlmtToNetPriceQtyNmrtr,
cast( wbrp.fpumn as wlf_wpumn preserving type ) as SettlmtToNetPriceQtyDnmntr,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_BaseUnit'
wbrp.meins as BaseUnit,
// @DefaultAggregation: #NONE
@Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
wbrp.ntgew as ItemNetWeight,
// @DefaultAggregation: #NONE
@Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
wbrp.brgew as ItemGrossWeight,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_ItemWeightUnit'
wbrp.gewei as ItemWeightUnit,
// @DefaultAggregation: #NONE
@Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
wbrp.volum as ItemVolume,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_ItemVolumeUnit'
wbrp.voleh as ItemVolumeUnit,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.brtwr as wlf_brtwr_lfp preserving type ) as SupplierItemGrossAmount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.netwr as wlf_netwr_lfp preserving type ) as SupplierItemNetAmount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.kzwi1 as wlf_suplr_kzwi1 preserving type ) as SupplierSubtotal1Amount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.kzwi2 as wlf_suplr_kzwi2 preserving type ) as SupplierSubtotal2Amount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.kzwi3 as wlf_suplr_kzwi3 preserving type ) as SupplierSubtotal3Amount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.kzwi4 as wlf_suplr_kzwi4 preserving type ) as SupplierSubtotal4Amount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.kzwi5 as wlf_suplr_kzwi5 preserving type ) as SupplierSubtotal5Amount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.kzwi6 as wlf_suplr_kzwi6 preserving type ) as SupplierSubtotal6Amount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.bonba as wlf_suplr_bonba preserving type ) as SupplierRebateBasisAmount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
wbrp.effwr as SupplierEffectiveItemAmount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
wbrp.skfbp as SuplrItmEligibleAmtForCshDisc,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.mwsbp as wlf_suplr_mwsbp preserving type ) as SupplierItemTaxAmount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.brtwrd as wlf_brtwrd_lfp preserving type ) as CustomerItemGrossAmount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.netwrd as wlf_netwrd_lfp preserving type ) as CustomerItemNetAmount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.kzwi1d as wlf_cust_kzwi1 preserving type ) as CustomerSubtotal1Amount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.kzwi2d as wlf_cust_kzwi2 preserving type ) as CustomerSubtotal2Amount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.kzwi3d as wlf_cust_kzwi3 preserving type ) as CustomerSubtotal3Amount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.kzwi4d as wlf_cust_kzwi4 preserving type ) as CustomerSubtotal4Amount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.kzwi5d as wlf_cust_kzwi5 preserving type ) as CustomerSubtotal5Amount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.kzwi6d as wlf_cust_kzwi6 preserving type ) as CustomerSubtotal6Amount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.bonbad as wlf_cust_bonba preserving type ) as CustomerRebateBasisAmount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
wbrp.effwrd as CustomerEffectiveItemAmount,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
wbrp.skfbpd as CustItmEligibleAmtForCshDisc,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
cast( wbrp.mwsbpd as wlf_cust_mwsbp preserving type ) as CustomerItemTaxAmount,
@ObjectModel.foreignKey.association: '_SettlmtItmStatisticalPrpty'
wbrp.kowrr as SettlmtItmStatisticalPrpty,
wbrp.sktof as CashDiscountIsDeductible,
@Semantics.user.createdBy: true
cast( wbrp.ernam as wlf_created_by preserving type ) as CreatedByUser,
@Semantics.systemDate.createdAt: true
cast( wbrp.erdat as wlf_created_on preserving type ) as CreationDate,
cast( wbrp.erzet as wlf_created_at preserving type ) as CreationTime,
wbrp.wbelnv as SettlmtSourceDoc,
wbrp.posnrv as SettlmtSourceDocItem,
@ObjectModel.foreignKey.association: '_SettlmtSourceDocCat'
wbrp.lftypv as SettlmtSourceDocCat,
cast( P_SettlDocItemAddInfo1.gjahrv as wlf_source_fiscal_year preserving type ) as SettlmtSourceDocFiscalYear,
@ObjectModel.foreignKey.association: '_SettlmtItemActivityReason'
wbrp.lfgru as SettlmtItemActivityReason,
wbrp.arktx as SettlmtMgmtDocItemText,
wbrp.idnlf as SupplierProductID,
cast( wbrp.txjcd as fis_txjcd preserving type ) as TaxJurisdiction,
wbrp.txjcd_ic as IntercompanyTaxJurisdiction,
wbrp.bupla as BusinessPlace,
wbrp.bupla_ic as IntercompanyBusinessPlace,
@Semantics.unitOfMeasure: true
@ObjectModel.foreignKey.association: '_ProductPurchasePointsQtyUnit'
wbrp.punei as ProductPurchasePointsQtyUnit,
// @DefaultAggregation: #NONE
@Semantics.quantity.unitOfMeasure: 'ProductPurchasePointsQtyUnit'
wbrp.anzpu as ProductPurchasePointsQty,
@ObjectModel.foreignKey.association: '_PriorSupplier'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_Supplier_VH', element: 'Supplier' } }]
}
wbrp.kolif as PriorSupplier,
// @DefaultAggregation: #NONE
@Semantics.amount.currencyCode: 'SettlmtDocCurrency'
wbrp.navnw as NonDeductibleInputTaxAmount,
@ObjectModel.foreignKey.association: '_InventoryValuationType'
wbrp.bwtar as InventoryValuationType,
@ObjectModel.foreignKey.association: '_SuplrSettlmtBusinessArea'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_BusinessAreaStdVH', element: 'BusinessArea' } }]
}
cast( wbrp.gsber as fis_rbusa preserving type ) as SuplrSettlmtBusinessArea,
@ObjectModel.foreignKey.association: '_CustSettlmtBusinessArea'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_BusinessAreaStdVH', element: 'BusinessArea' } }]
}
wbrp.gsberd as CustSettlmtBusinessArea,
@ObjectModel.foreignKey.association: '_SuplrSettlmtControllingArea'
cast( wbrp.kokrs as fis_kokrs preserving type ) as SuplrSettlmtControllingArea,
cast( wbrp.kostl as fis_kostl preserving type ) as SuplrSettlmtCostCenter,
cast( wbrp.prctr as fis_prctr preserving type ) as SuplrSettlmtProfitCenter,
@ObjectModel.foreignKey.association: '_IncotermsVersion'
wbrp.incov_p as IncotermsVersion,
@ObjectModel.foreignKey.association: '_IncotermsClassification'
wbrp.inco1_p as IncotermsClassification,
wbrp.inco2_p as IncotermsTransferLocation,
wbrp.inco2_l_p as IncotermsLocation1,
wbrp.inco3_l_p as IncotermsLocation2,
@ObjectModel.foreignKey.association: '_CustSettlmtControllingArea'
wbrp.kokrsd as CustSettlmtControllingArea,
wbrp.kostld as CustSettlmtCostCenter,
wbrp.prctrd as CustSettlmtProfitCenter,
wbrp.charg as Batch,
cast( wbrp.wuvprs as wlf_suplr_wuvprs preserving type ) as SupplierPrcDetnIsIncmplt,
cast( wbrp.wuvprs as wlf_cust_wuvprs preserving type ) as CustomerPrcDetnIsIncmplt,
wbrp.wbeln_v as SettlmtPrecdgDoc,
wbrp.posnr_v as SettlmtPrecdgDocItem,
@ObjectModel.foreignKey.association: '_SettlmtPrecdgDocCat'
wbrp.ftypv_v as SettlmtPrecdgDocCat,
cast( P_SettlDocItemAddInfo1.gjahr_v as wlf_precdg_fiscal_year preserving type ) as SettlmtPrecdgDocFiscalYear,
@ObjectModel.foreignKey.association: '_SettlmtMgmtDocItemCat'
wbrp.itemcat as SettlmtMgmtDocItemCat,
@ObjectModel.foreignKey.association: '_SettlmtItemReltdCndnContr'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_ConditionContractStdVH', element: 'ConditionContract' } }]
}
cast( P_SettlDocItemAddInfo1.related_coco_num as wlf_item_related_coco_num preserving type ) as SettlmtItemReltdCndnContr,
//define foreign key association for SettlmtItemReltdTrdgContr as soon as an appropriate CDS-View is available:
cast( P_SettlDocItemAddInfo1.related_tkonn as wlf_item_related_tkonn preserving type ) as SettlmtItemReltdTrdgContr,
cast( P_SettlDocItemAddInfo1.related_tposn as wlf_related_tposn preserving type ) as SettlmtItemReltdTrdgContrItem,
// foreign key association not allowed because target view is not a #DIMENSION
// @ObjectModel.foreignKey.association: '_SettlmtItemReltdPurgDoc'
cast( P_SettlDocItemAddInfo1.related_ebeln as wlf_item_related_ebeln preserving type ) as SettlmtItemReltdPurgDoc,
cast( P_SettlDocItemAddInfo1.related_ebelp as wlf_related_ebelp preserving type ) as SettlmtItemReltdPurgDocItem,
@ObjectModel.foreignKey.association: '_SettlmtItemReltdBillgDoc'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_BillingDocumentStdVH', element: 'BillingDocument' } }]
}
cast( P_SettlDocItemAddInfo1.related_vbeln as wlf_item_related_vbeln preserving type ) as SettlmtItemReltdBillgDoc,
cast( P_SettlDocItemAddInfo1.related_posnr as wlf_related_posnr preserving type ) as SettlmtItemReltdBillgDocItem,
@ObjectModel.foreignKey.association: '_SettlmtMgmtDocItemStatus'
wbrp.item_status as SettlmtMgmtDocItemStatus,
@ObjectModel.foreignKey.association: '_SettlmtMgmtDocItemCancld'
wbrp.item_canceled as SettlmtMgmtDocItemCancld,
@ObjectModel.foreignKey.association: '_SupplierSettlementOrder'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_InternalOrderStdVH', element: 'InternalOrder' } }]
}
cast( wbrp.aufnr as wlf_suplr_aufnr preserving type ) as SupplierSettlementOrder,
@ObjectModel.foreignKey.association: '_SupplierItemSettlmtStatus'
wbrp.settl_status_i_v as SupplierItemSettlmtStatus,
@ObjectModel.foreignKey.association: '_CustomerItemSettlmtStatus'
wbrp.settl_status_i_c as CustomerItemSettlmtStatus,
@ObjectModel.foreignKey.association: '_SupplierItemSettlmtBlkgReason'
wbrp.settl_block_i_v as SupplierItemSettlmtBlkgReason,
@ObjectModel.foreignKey.association: '_CustomerItemSettlmtBlkgReason'
wbrp.settl_block_i_c as CustomerItemSettlmtBlkgReason,
@ObjectModel.foreignKey.association: '_ItemSettlmtRelevance'
wbrp.settl_item_rel as ItemSettlmtRelevance,
wbrp.fbuda as ServicesRenderedDate,
@ObjectModel.foreignKey.association: '_SuplrSettlmtCompanyCode'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } }]
}
cast( wbrk.bukrs as wlf_suplr_bukrs preserving type ) as SuplrSettlmtCompanyCode,
@ObjectModel.foreignKey.association: '_GLAccountInCompanyCode'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_GLAccountInCompanyCodeStdVH', element: 'GLAccount' } }]
}
cast( wbrp.sakto as fis_racct preserving type ) as GLAccount,
wbrp.gjahr as SettlementFiscalYear,
@ObjectModel.foreignKey.association: '_HigherLevelItem'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_SettlmtMgmtDocItemStdVH', element: 'SettlmtMgmtDocItem' } }]
}
cast( wbrp.posnr_main as uepos preserving type ) as HigherLevelItem,
wbrp.posnr_sub_exist as LowerLevelItemExists,
@ObjectModel.foreignKey.association: '_ItemDistributionStatus'
wbrp.distrib_status as ItemDistributionStatus,
wbrp.ref_doc_type_1 as SettlmtRefDocType,
wbrp.ref_doc_nr_1 as SettlmtRefDoc,
wbrp.ref_doc_year_1 as SettlmtRefDocFiscalYear,
@ObjectModel.foreignKey.association: '_SettlmtRefDocLogicalSyst'
wbrp.ref_log_sys_1 as SettlmtRefDocLogicalSyst,
@ObjectModel.foreignKey.association: '_SettlmtRefDocCompanyCode'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } }]
}
wbrp.ref_company_code_1 as SettlmtRefDocCompanyCode,
wbrp.ref_item_number as SettlmtRefDocItem,
@ObjectModel.foreignKey.association: '_SettlmtRefDocCat'
wbrp.ref_type as SettlmtRefDocCat,
@ObjectModel.foreignKey.association: '_CndnContrType'
wbrp.contr_type_i as CndnContrType,
@ObjectModel.foreignKey.association: '_CndnContrProcVar'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_CndnContrProcVarStdVH', element: 'CndnContrProcVar' } }]
}
wbrp.process_variant_i as CndnContrProcVar,
@ObjectModel.foreignKey.association: '_SettlmtDateCat'
wbrp.settl_date_type_i as SettlmtDateCat,
wbrp.settl_date_i as SettlmtDate,
wbrp.settl_date_seq_id_i as SettlmtDateSequentialID,
wbrp.act_settl_date_i as ActualSettlmtDate,
wbrp.settl_start_date_i as SettlmtPeriodStartDate,
cast( wbrp.act_settl_date_i as wb2_settlement_end_date preserving type ) as SettlmtPeriodEndDate,
wbrp.ref_settl_date_i as RefSettlmtDate,
@ObjectModel.foreignKey.association: '_ItemIntrastatRelevance'
wbrp.item_intra_rel as ItemIntrastatRelevance,
@ObjectModel.foreignKey.association: '_CustomerSettlementOrder'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_InternalOrderStdVH', element: 'InternalOrder' } }]
}
wbrp.aufnrd as CustomerSettlementOrder,
@ObjectModel.foreignKey.association: '_SuplrSettlmtWBSElmntBasicData'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_WBSElementBasicDataStdVH', element: 'WBSElementInternalID' } }]
}
cast( wbrp.ps_psp_pnr as wlf_psp_pnr_no_cnext preserving type ) as SuplrSettlmtWBSElmntInternalID,
@ObjectModel.foreignKey.association: '_CustSettlmtWBSElmntBasicData'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_WBSElementBasicDataStdVH', element: 'WBSElementInternalID' } }]
}
cast( wbrp.ps_psp_pnrd as wlf_ps_psp_pnr_cust_no_cnext preserving type ) as CustSettlmtWBSElmntInternalID,
@ObjectModel.foreignKey.association: '_SettlmtMgmtDocItemCollSts'
wbrp.coll_status_i as SettlmtMgmtDocItemCollSts,
@ObjectModel.foreignKey.association: '_CollSettlmtItemBlkgReason'
wbrp.coll_block_i as CollSettlmtItemBlkgReason,
@ObjectModel.foreignKey.association: '_ItmSettlmtDocCollRelevance'
wbrp.coll_rel as ItmSettlmtDocCollRelevance,
wbrp.ref_doc_type_2 as SettlmtAddlRefDocType,
wbrp.ref_doc_nr_2 as SettlmtAddlRefDoc,
wbrp.ref_doc_year_2 as SettlmtAddlRefDocFiscalYear,
@ObjectModel.foreignKey.association: '_SettlmtAddlRefDocLogicalSyst'
wbrp.ref_log_sys_2 as SettlmtAddlRefDocLogicalSyst,
wbrp.ref_item_num_2 as SettlmtAddlRefDocItem,
@ObjectModel.foreignKey.association: '_SettlmtAddlRefDocCat'
wbrp.ref_type_2 as SettlmtAddlRefDocCat,
@ObjectModel.foreignKey.association: '_CustomerSettlmtRecipient'
@Consumption: {
valueHelpDefinition: [{ entity: { name: 'I_Customer_VH', element: 'Customer' } }]
}
cast( wbrp.customer as wlf_cust_settlmt_recpnt preserving type ) as CustomerSettlmtRecipient,
//@ObjectModel.foreignKey.association: '_SupplierSubrange'
wbrp.ltsnr as SupplierSubrange,
// @ObjectModel.foreignKey.association: '_ProductHierarchy'
wbrp.prodh as ProductHierarchy,
@ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup1'
cast( wbrp.mvgr1 as wlf_salesspcfcproductgroup1 preserving type ) as SalesSpcfcProductGroup1,
@ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup2'
cast( wbrp.mvgr2 as wlf_salesspcfcproductgroup2 preserving type ) as SalesSpcfcProductGroup2,
@ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup3'
cast( wbrp.mvgr3 as wlf_salesspcfcproductgroup3 preserving type ) as SalesSpcfcProductGroup3,
@ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup4'
cast( wbrp.mvgr4 as wlf_salesspcfcproductgroup4 preserving type ) as SalesSpcfcProductGroup4,
@ObjectModel.foreignKey.association: '_SalesSpcfcProductGroup5'
cast( wbrp.mvgr5 as wlf_salesspcfcproductgroup5 preserving type ) as SalesSpcfcProductGroup5,
@ObjectModel.foreignKey.association: '_SettlmtItemSalesOrganization'
wbrp.vkorg_i as SettlmtItemSalesOrganization,
@ObjectModel.foreignKey.association: '_SettlmtItmDistributionChannel'
wbrp.vtweg_i as SettlmtItemDistributionChannel,
@ObjectModel.foreignKey.association: '_SettlmtItemDivision'
wbrp.spart_i as SettlmtItemDivision,
wbrp.provg as ProductCommissionGroup,
cast( wbrp.kondm as pricespecificationproductgroup preserving type ) as PriceSpecificationProductGroup,
wbrp.rebate_grp as SalesVolumeRebateGroup,
wbrp.reference_id as BusTransDocReferenceID,
wbrp.ref_item_id as BusTransDocReferenceItemID,
P_SettlDocItemAddInfo1.SettlmtMgmtDocItemTextKey as SettlmtMgmtDocItemTextKey,
wbrp.no_text_i as SettlmtMgmtDocItemHasNoTexts,
wbrp.mwskz_bv as BusinessVolumeTaxCode,
@ObjectModel.foreignKey.association: '_BusinessVolumeCurrency'
wbrp.waers_bv as BusinessVolumeCurrency,
wbrp.txdat_from_bv as BusVolTxRateValdFrmDate,
wbrp.kschl_settlement as SettlementConditionType,
wbrp.dispute_case as DisputeCaseUUID,
/* Entity Tag */
cast( wbrp.entity_tag_item as wlf_change_state_item ) as SettlmtMgmtDocItemChangeState,
/* Associations */
@ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
_SettlmtMgmtDoc,
_Partner,
_SetlMgmtDocItmPlainLongText,
_SettlmtDocCurrency,
_BusinessVolumeCurrency,
_SettlmtMgmtDocCat,
_SupplierPricingElement,
_CustomerPricingElement,
_SettlmtPartnerCat,
_SettlmtBusProcCat,
_Product,
// _ProductGroup,
_Plant,
_TaxCountry,
_IntercompanyTaxCountry,
_SettlmtQuantityUnit,
// _SupplierTaxCode,
// _CustomerTaxCode,
_NetPriceQuantityUnit,
_BaseUnit,
_ItemWeightUnit,
_ItemVolumeUnit,
_SettlmtItmStatisticalPrpty,
_SettlmtSourceDocCat,
_SettlmtItemActivityReason,
_ProductPurchasePointsQtyUnit,
_PriorSupplier,
_InventoryValuationType,
_SuplrSettlmtBusinessArea,
_CustSettlmtBusinessArea,
_SuplrSettlmtControllingArea,
_SuplrSettlmtCostCenter,
_SuplrSettlmtProfitCenter,
_IncotermsVersion,
_IncotermsClassification,
_CustSettlmtControllingArea,
_CustSettlmtCostCenter,
_CustSettlmtProfitCenter,
_SettlmtPrecdgDocCat,
_SettlmtMgmtDocItemCat,
_SettlmtItemReltdPurgDoc,
_SettlmtItemReltdBillgDoc,
_SettlmtMgmtDocItemStatus,
_SettlmtMgmtDocItemCancld,
_SupplierSettlementOrder,
_SupplierItemSettlmtStatus,
_CustomerItemSettlmtStatus,
_SupplierItemSettlmtBlkgReason,
_CustomerItemSettlmtBlkgReason,
_ItemSettlmtRelevance,
_SuplrSettlmtCompanyCode,
_GLAccountInCompanyCode,
_HigherLevelItem,
_ItemDistributionStatus,
_SettlmtRefDocLogicalSyst,
_SettlmtRefDocCompanyCode,
_SettlmtRefDocCat,
_CndnContrType,
_CndnContrProcVar,
_SettlmtDateCat,
_ItemIntrastatRelevance,
_CustomerSettlementOrder,
_SuplrSettlmtWBSElmntBasicData,
_CustSettlmtWBSElmntBasicData,
_SettlmtMgmtDocItemCollSts,
_CollSettlmtItemBlkgReason,
_ItmSettlmtDocCollRelevance,
_SettlmtAddlRefDocLogicalSyst,
_SettlmtAddlRefDocCat,
_CustomerSettlmtRecipient,
// _SupplierSubrange
// _ProductHierarchy,
_SalesSpcfcProductGroup1,
_SalesSpcfcProductGroup2,
_SalesSpcfcProductGroup3,
_SalesSpcfcProductGroup4,
_SalesSpcfcProductGroup5,
_SettlmtItemReltdCndnContr,
@Consumption.hidden: true
_ProductText,
@Consumption.hidden: true
_SuplrSettlmtBusinessAreaText,
@Consumption.hidden: true
_CustSettlmtBusinessAreaText,
_SettlmtItemSalesOrganization,
_SettlmtItmDistributionChannel,
_SettlmtItemDivision,
_CreatedByUser
}