I_NotificationActivity

@AbapCatalog.sqlViewName: 'INOTIFACT'
@AbapCatalog.compiler.compareFilter: true

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.privilegedAssociations: ['_CreatedByUserContactCard', '_LastChangedByUserContactCard']

@VDM.viewType: #BASIC

@EndUserText.label: 'Notification Activity'
@ClientHandling.algorithm: #SESSION_VARIABLE


@ObjectModel: {
    representativeKey: 'NotificationActivity',
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #L,
        serviceQuality: #A }
} 

define view I_NotificationActivity as select from qmma 

    association[1..1] to I_Notification as _Notification on $projection.Notification = _Notification.Notification
    
    association[0..1] to I_UserContactCard  as _CreatedByUserContactCard        on $projection.CreatedByUser = _CreatedByUserContactCard.ContactCardID
    association[0..1] to I_UserContactCard  as _LastChangedByUserContactCard    on $projection.LastChangedByUser = _LastChangedByUserContactCard.ContactCardID
    association[0..1] to I_Language     as _Language                        on $projection.MasterLanguage = _Language.Language
    
    association[0..1] to I_NotifActivityCatalog     as _NotifActivityCatalog    on  $projection.NotifActivityCatalog = _NotifActivityCatalog.NotifActivityCatalog
    association[0..1] to I_NotifActivityCodeGroup   as _NotifActivityCodeGroup  on  $projection.NotifActivityCatalog = _NotifActivityCodeGroup.NotifActivityCatalog and
                                                                                    $projection.NotifActivityCodeGroup = _NotifActivityCodeGroup.NotifActivityCodeGroup
    association[0..1] to I_NotifActivityCode        as _NotifActivityCode       on  $projection.NotifActivityCatalog = _NotifActivityCode.NotifActivityCatalog and
                                                                                    $projection.NotifActivityCodeGroup = _NotifActivityCode.NotifActivityCodeGroup and
                                                                                    $projection.NotifActivityCode = _NotifActivityCode.NotifActivityCode
                                                                                                                                                                    
{

//=== Key Fields

    @ObjectModel.foreignKey.association: '_Notification'
    key qmnum   as Notification,
    key manum   as NotificationActivity,
    fenum       as NotificationItem,
    qmanum      as NotificationActivitySortNumber,
//=== Common Fields

    kzloesch    as IsDeleted,
    kzmla       as MasterLanguage,    
    @ObjectModel.foreignKey.association: '_NotifActivityCatalog'
    mnkat       as NotifActivityCatalog,
    @ObjectModel.foreignKey.association: '_NotifActivityCodeGroup'
    mngrp       as NotifActivityCodeGroup,
    @ObjectModel.foreignKey.association: '_NotifActivityCode'
    mncod       as NotifActivityCode,
    
    matxt       as NotifActivityText,
    pster       as NotifActivityStartDate,
    pstur       as NotifActivityStartTime,
    peter       as NotifActivityEndDate,
    petur       as NotifActivityEndTime,

//=== Administrative Data

    case changeddatetime
        when 0 then cast( '19000101010101' as tzntstmps )
        else changeddatetime                            
    end         as ChangedDateTime,
    @ObjectModel.foreignKey.association: '_CreatedByUserContactCard'
    ernam       as CreatedByUser,
    @Semantics.systemDate.createdAt: true
    erdat       as CreationDate,
    erzeit      as CreationTime,
    @ObjectModel.foreignKey.association: '_LastChangedByUserContactCard'
    aenam       as LastChangedByUser,
    @Semantics.systemDate.lastChangedAt: true
    aedat       as LastChangeDate,
    aezeit      as LastChangeTime,
    _Notification.IsBusinessPurposeCompleted,
    
    /* Associations */ 
    _Notification,
    _CreatedByUserContactCard,
    _LastChangedByUserContactCard,
    _Language,
    _NotifActivityCatalog,
    _NotifActivityCodeGroup,
    _NotifActivityCode
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_NOTIFICATION",
"QMMA"
],
"ASSOCIATED":
[
"I_LANGUAGE",
"I_NOTIFACTIVITYCATALOG",
"I_NOTIFACTIVITYCODE",
"I_NOTIFACTIVITYCODEGROUP",
"I_NOTIFICATION",
"I_USERCONTACTCARD"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/