I_PlantMaintenancePartner

@AbapCatalog: { sqlViewName: 'IPLANTMAINTPARTN', preserveKey }
--@Analytics: { dataCategory: #DIMENSION }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Plant Maintenance Partner'
@ObjectModel.representativeKey: 'MaintObjectInternalID'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL
@VDM.viewType: #BASIC

define view I_PlantMaintenancePartner
  as select from ihpa
  association [0..1] to I_PartnerFunction        as _PartnerFunction        on  _PartnerFunction.PartnerFunction = $projection.PartnerFunction

  /* Associations - DPP */
  association [0..1] to I_ContactPerson          as _ContactPerson          on  _ContactPerson.ContactPerson = $projection.Partner
  association [0..1] to I_Customer               as _Customer               on  _Customer.Customer = $projection.Partner
  association [0..1] to I_WorkforcePerson        as _Employee               on  _Employee.PersonExternalID = $projection.Partner
  association [0..1] to I_OrganizationalUnitText as _OrganizationalUnitText on  _OrganizationalUnitText.OrganizationalUnit = $projection.Partner
                                                                            and _OrganizationalUnitText.Language           = $session.system_language
                                                                            and _OrganizationalUnitText.StartDate          <= $session.system_date
                                                                            and _OrganizationalUnitText.EndDate            >= $session.system_date
  association [0..1] to I_PMPositionText         as _PositionText           on  _PositionText.PositionID = $projection.Partner
                                                                            and _PositionText.Language   = $session.system_language
                                                                            and _PositionText.StartDate  <= $session.system_date
                                                                            and _PositionText.EndDate    >= $session.system_date
  association [0..1] to I_Supplier               as _Supplier               on  _Supplier.Supplier = $projection.Partner
  association [0..1] to I_User                   as _User                   on  _User.UserID = $projection.Partner
  association [0..1] to I_PMContactCardEmployee  as _PersonResponsible      on  $projection.Partner = _PersonResponsible.PersonnelNumber
  association [0..1] to I_PersonWorkAgreement_1  as _PersonWorkAgreement    on  $projection.Partner = _PersonWorkAgreement.PersonWorkAgreement  
{
      /* Fields */
  key objnr                                  as  MaintObjectInternalID,

      @ObjectModel.foreignKey.association: '_PartnerFunction'
  key parvw                                  as  PartnerFunction,
  
  key counter                                as  MaintenancePartnerObjectNumber,

      obtyp                                  as  MaintObjectCategory,
      @API.element.successor: 'MaintenancePartner'
      @API.element.releaseState: #DEPRECATED
      parnr                                  as  Partner,

      ernam                                  as  CreatedByUser,
      erdat                                  as  CreationDate,
      erzeit                                 as  CreationTime,
      aenam                                  as  LastChangedByUser,
      aezeit                                 as  LastChangeTime,
      aedat                                  as  LastChangeDate,
      
      parnr                                  as  MaintenancePartner,

      /* Associations */
      _PartnerFunction,

      /* Associations - DPP */
      _ContactPerson,
      _Customer,
      _Employee,
      _OrganizationalUnitText,
      _PositionText,
      _Supplier,
      _User,
      _PersonResponsible,
      _PersonWorkAgreement
}
where
  ihpa.kzloesch = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"IHPA"
],
"ASSOCIATED":
[
"I_CONTACTPERSON",
"I_CUSTOMER",
"I_ORGANIZATIONALUNITTEXT",
"I_PARTNERFUNCTION",
"I_PERSONWORKAGREEMENT_1",
"I_PMCONTACTCARDEMPLOYEE",
"I_PMPOSITIONTEXT",
"I_SUPPLIER",
"I_USER",
"I_WORKFORCEPERSON"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/