I_PMContactCardEmployee

@AbapCatalog.sqlViewName: 'IPMCONTCARDEMP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Employee'
@ObjectModel.representativeKey : 'PersonnelNumber'

@Search.searchable: true

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L

@AccessControl.personalData.blocking: #REQUIRED

define view I_PMContactCardEmployee
  as select from           I_PersonWorkAgreement_1 as I_PersonWorkAgreement
    left outer to one join I_BusinessPartner on  I_PersonWorkAgreement.Person              = I_BusinessPartner.BusinessPartner
                                             and I_BusinessPartner.BusinessPartnerCategory = '1'
  association [0..1] to I_WorkforcePersonImageURL as _WorkforcePersonImageURL on _WorkforcePersonImageURL.Person = I_PersonWorkAgreement.Person
  association [0..1] to I_WorkplaceAddress        as _WorkplaceAddress        on I_BusinessPartner.BusinessPartnerUUID = _WorkplaceAddress.BusinessPartnerUUID
  association [0..1] to I_BusinessUser            as _BusinessUser            on I_PersonWorkAgreement.Person = _BusinessUser.BusinessPartner
{
      @ObjectModel.text.element:  [ 'EmployeeFullName' ]
  key cast( I_PersonWorkAgreement.PersonWorkAgreement as co_pernr )                             as PersonnelNumber,
      @Semantics.text: true
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      @Semantics.name.fullName: true
      I_BusinessPartner.PersonFullName                                                          as EmployeeFullName,
      @Semantics.name.givenName: true
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      I_BusinessPartner.FirstName,
      @Semantics.name.familyName: true
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      I_BusinessPartner.LastName                                                                as FamilyName,
      I_BusinessPartner.FormOfAddress,

      _PersonWrkAgrmtForKeyDate( P_KeyDate: $session.system_date ).Job,
      @Semantics.name.jobTitle: true
      _PersonWrkAgrmtForKeyDate( P_KeyDate: $session.system_date )._PersonWorkAgrmtJobText[ 1: Language = $session.system_language ].JobName,

      @ObjectModel.text.element:  [ 'CompanyCodeName' ]
      _PersonWrkAgrmtForKeyDate( P_KeyDate: $session.system_date ).CompanyCode,
      _PersonWrkAgrmtForKeyDate( P_KeyDate: $session.system_date )._CompanyCode[ 1: Language = $session.system_language ].CompanyCodeName,

      _PersonWrkAgrmtForKeyDate( P_KeyDate: $session.system_date ).OrganizationalUnit,
      @Semantics.organization.name: true
      _PersonWrkAgrmtForKeyDate( P_KeyDate: $session.system_date )._OrganizationalUnitName[ 1: Language = $session.system_language ].OrganizationalUnitName,
      @Semantics.telephone.type:  [ #WORK  ]
      _WorkplaceAddress.PhoneNumber,
      _WorkplaceAddress.NormalizedPhoneNumber,
      @Semantics.telephone.type:  [ #CELL  ]
      @EndUserText.label: 'Mobile Phone Number'
      _WorkplaceAddress.MobilePhoneNumber,
      @EndUserText.label: 'Complete Mobile Phone Number'
      _WorkplaceAddress.MblNormalizedPhoneNumber,

      @Semantics: {
        eMail.address: true,
        eMail.type:  [ #WORK ]
      }
      _WorkplaceAddress.DefaultEmailAddress,

      _WorkplaceAddress.Building,
      _WorkplaceAddress.RoomNumber,

      @UI.hidden:  true
      @Semantics.imageUrl: true
      @Semantics.contact: {
        photo: true
      }
      _WorkforcePersonImageURL.WorkforcePersonImageURL                                          as EmployeeImageURL,
      @Consumption.hidden:  true
      I_BusinessPartner.AuthorizationGroup,
      @Consumption.hidden: true
      I_BusinessPartner.IsBusinessPurposeCompleted,
      @Consumption.hidden: true
      I_BusinessPartner.BusinessPartnerUUID,
      @Consumption.hidden: true
      I_BusinessPartner._CurrentDefaultAddress.AddressID,

      @UI.hidden: true
      _BusinessUser.UserID,

      /////// Start of Datacontroller 10+1 fields -  Not to be consumed by any other views//////////


      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataControllerSet,
      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController1,
      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController2,
      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController3,
      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController4,
      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController5,
      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController6,
      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController7,
      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController8,
      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController9,
      @Consumption.hidden:true
      @UI.hidden:true
      I_BusinessPartner.DataController10,

 ////////////// End of Datacontroller 10+1 fields//////////


      -- used by CL_EAM_NTF_CREATE_DPC_EXT
      @UI.hidden: true
      _WorkplaceAddress,
      @UI.hidden: true
      I_BusinessPartner._CurrentDefaultAddress._Address as _WorkplacePhysicalAddress
}
--where
--  I_Employment.IsMainEmployment = 'X'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BPCURRENTDEFAULTADDRESS",
"I_BUSINESSPARTNER",
"I_BUSINESSUSER",
"I_COMPANYCODE",
"I_ORGANIZATIONALUNITTEXT",
"I_PERSONWORKAGREEMENT_1",
"I_PERSONWORKAGRMTFORKEYDATE",
"I_PERSONWORKAGRMTJOBTEXT",
"I_WORKFORCEPERSONIMAGEURL",
"I_WORKPLACEADDRESS"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_BUSINESSUSER",
"I_WORKFORCEPERSONIMAGEURL",
"I_WORKPLACEADDRESS"
],
"BASE":
[
"I_BPCURRENTDEFAULTADDRESS"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/