A_EquipmentPartner

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Equipment Partner Functions'

@VDM.viewType: #COMPOSITE
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@AccessControl.personalData.blocking:#NOT_REQUIRED
define view entity A_EquipmentPartner as select from I_EquipmentData
                                  left outer join I_PlantMaintenancePartner on I_PlantMaintenancePartner.MaintObjectInternalID = I_EquipmentData.MaintObjectInternalID

association to parent A_Equipment as _Equipment on $projection.Equipment = _Equipment.Equipment
                                                and $projection.ValidityEndDate = _Equipment.ValidityEndDate
                                                                                            
 {
            
      key I_EquipmentData.Equipment,
      key cast(I_PlantMaintenancePartner.PartnerFunction as parvw_unv preserving type ) as PartnerFunction,
      key I_PlantMaintenancePartner.MaintenancePartnerObjectNumber as EquipmentPartnerObjectNmbr,
      I_PlantMaintenancePartner.Partner,
      I_PlantMaintenancePartner.CreatedByUser,
      I_PlantMaintenancePartner.CreationDate, 
      @Consumption.hidden: true
      I_PlantMaintenancePartner.CreationTime,
      @Consumption.hidden: true
      I_PlantMaintenancePartner.LastChangedByUser,
      @Consumption.hidden: true
      I_PlantMaintenancePartner.LastChangeTime,
      @Consumption.hidden: true
      I_PlantMaintenancePartner.LastChangeDate,
        @Consumption.hidden: true
      I_EquipmentData.ValidityEndDate,  
        @Consumption.hidden: true          
      I_PlantMaintenancePartner.MaintObjectInternalID,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._PartnerFunction.SDDocumentPartnerType as PartnerFunctionType,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._ContactPerson.IsBusinessPurposeCompleted as CntctPersnIsBusPrpsCompleted,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._ContactPerson._Customer.CustomerAccountGroup as CntctPersnCustomerAccountGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._ContactPerson._Customer.AuthorizationGroup as CntctPersnCustomerAuthznGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._ContactPerson._Supplier.SupplierAccountGroup as CntctPersnSupplierAccountGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._ContactPerson._Supplier.AuthorizationGroup as CntctPersnSupplierAuthznGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Customer.IsBusinessPurposeCompleted as CustomerIsBusPrpsCmpltd,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Customer.CustomerAccountGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Customer.AuthorizationGroup as CustomerAuthznGrp,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Employee.IsBusinessPurposeCompleted as EmployeeIsBusPrpsCmpltd,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Employee.AuthorizationGroup as EmployeeAuthznGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Supplier.IsBusinessPurposeCompleted as SupplierIsBusPrpsCmpltd,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Supplier.SupplierAccountGroup,
      @Consumption.hidden: true
      I_PlantMaintenancePartner._Supplier.AuthorizationGroup as SupplierAuthznGrp, 
      _Equipment
      
}where I_EquipmentData.ValidityEndDate = '99991231' and I_PlantMaintenancePartner.PartnerFunction is not null
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CONTACTPERSON",
"I_CUSTOMER",
"I_EQUIPMENTDATA",
"I_PARTNERFUNCTION",
"I_PLANTMAINTENANCEPARTNER",
"I_SUPPLIER",
"I_WORKFORCEPERSON"
],
"ASSOCIATED":
[
"A_EQUIPMENT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/