I_MfgBillOfOperationsOperation

@AbapCatalog.sqlViewName: 'IMFGBOOOPERATION'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE]
@ObjectModel.representativeKey: 'BOOOperationInternalID'
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #MASTER}
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@EndUserText.label: 'Manufacturing Bill of Operations Operation'

define view I_MfgBillOfOperationsOperation
  as select from I_BillOfOperationsOperation as plas

  -- to root
  association [1..1] to I_MfgBillOfOperations          as _BillOfOperations          on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                     and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                     and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  -- to parent
  association [1..1] to I_MfgBillOfOperationsSequence  as _BillOfOperationsSequence  on  $projection.BillOfOperationsType     = _BillOfOperationsSequence.BillOfOperationsType
                                                                                     and $projection.BillOfOperationsGroup    = _BillOfOperationsSequence.BillOfOperationsGroup
                                                                                     and $projection.BillOfOperationsVariant  = _BillOfOperationsSequence.BillOfOperationsVariant
                                                                                     and $projection.BillOfOperationsSequence = _BillOfOperationsSequence.BillOfOperationsSequence
  -- to child
  association [1..*] to I_MfgBOOOperationChangeState   as _BOOOperationChangeState   on  $projection.BillOfOperationsType     = _BOOOperationChangeState.BillOfOperationsType
                                                                                     and $projection.BillOfOperationsGroup    = _BOOOperationChangeState.BillOfOperationsGroup
                                                                                     and $projection.BillOfOperationsVariant  = _BOOOperationChangeState.BillOfOperationsVariant
                                                                                     and $projection.BillOfOperationsSequence = _BOOOperationChangeState.BillOfOperationsSequence
                                                                                     and $projection.BOOOperationInternalID   = _BOOOperationChangeState.BOOOperationInternalID
{
      // Key

      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plas.BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plas.BillOfOperationsGroup,
      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key plas.BillOfOperationsVariant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsSequence'
  key plas.BillOfOperationsSequence,
      // representative key BillOfOperationsOperationInternal

  key plas.BOOOperationInternalID,

      // Associations

      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _BillOfOperations,
      _BillOfOperationsSequence,
      _BOOOperationChangeState
--    _BOOOpBOMItemChangeState,
--    _BOOOpMaterialPRTChangeState,
--    _BOOOpEquipmentPRTChangeState,
--    _BOOOpMiscPRTChangeState,
--    _BOOOpDocumentPRTChangeState
}
where plas.BillOfOperationsType = '2'  // Recipe

   or plas.BillOfOperationsType = 'N'  // Standard routing

   or plas.BillOfOperationsType = 'S'; // Reference operation set

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONSOPERATION"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_MFGBILLOFOPERATIONS",
"I_MFGBILLOFOPERATIONSSEQUENCE",
"I_MFGBOOOPERATIONCHANGESTATE"
],
"BASE":
[
"I_BILLOFOPERATIONSOPERATION"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/