I_JournalEntryOneTimeAccount

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Journal Entry One Time Account'
@VDM.viewType: #BASIC
@ObjectModel.usageType.serviceQuality:#A
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@Metadata.ignorePropagatedAnnotations: true

define view entity I_JournalEntryOneTimeAccount
  as select from bsec
  association [1..1] to I_CompanyCode                as _CompanyCode             on  $projection.CompanyCode = _CompanyCode.CompanyCode

  association [0..1] to I_JournalEntry               as _AccountingDocument      on  $projection.CompanyCode        = _AccountingDocument.CompanyCode
                                                                                 and $projection.AccountingDocument = _AccountingDocument.AccountingDocument
                                                                                 and $projection.FiscalYear         = _AccountingDocument.FiscalYear
  association [0..1] to I_OperationalAcctgDocItem    as _OperationalAcctgDocItem on  $projection.CompanyCode            = _OperationalAcctgDocItem.CompanyCode
                                                                                 and $projection.AccountingDocument     = _OperationalAcctgDocItem.AccountingDocument
                                                                                 and $projection.FiscalYear             = _OperationalAcctgDocItem.FiscalYear
                                                                                 and $projection.AccountingDocumentItem = _OperationalAcctgDocItem.AccountingDocumentItem

  association [0..1] to I_FiscalYearForCompanyCode   as _FiscalYear              on  $projection.FiscalYear  = _FiscalYear.FiscalYear
                                                                                 and $projection.CompanyCode = _FiscalYear.CompanyCode
  association [0..1] to I_Iban                       as _IBAN                    on  $projection.BankInternalID = _IBAN.Bank
                                                                                 and $projection.BankAccount    = _IBAN.BankAccount
                                                                                 and $projection.BankCountry    = _IBAN.BankCountry
                                                                                 and $projection.BankControlKey = _IBAN.BankControlKey
  association [0..1] to I_Bank_2                     as _Bank                    on  $projection.BankCountry    = _Bank.BankCountry
                                                                                 and $projection.BankInternalID = _Bank.BankInternalID
  association [0..*] to I_CountryText                as _BankCountryText         on  $projection.BankCountry = _BankCountryText.Country
  association [0..1] to I_Address                    as _Address                 on  $projection.AddressID = _Address.AddressID
  association [0..*] to I_CountryText                as _CountryText             on  $projection.Country = _CountryText.Country
  association [0..*] to I_LanguageText               as _LanguageText            on  $projection.Language = _LanguageText.LanguageCode
  association [0..*] to I_OneTimeAcctDataMdmExchText as _DMEIndicatorText        on  $projection.DataMediumExchangeIndicator = _DMEIndicatorText.DataMediumExchangeIndicator
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key bsec.bukrs                                               as CompanyCode,
      @ObjectModel.foreignKey.association: '_AccountingDocument'
  key bsec.belnr                                               as AccountingDocument,
      @ObjectModel.foreignKey.association: '_FiscalYear'
  key bsec.gjahr                                               as FiscalYear,
  key bsec.buzei                                               as AccountingDocumentItem,
      bsec.anred                                               as OneTimeAccountBPSalutationText,
      @ObjectModel.text.association: '_LanguageText'
      bsec.spras                                               as Language,
      cast(bsec.name1 as ad_name1)                             as BusinessPartnerName1,
      cast(bsec.name2 as ad_name2)                             as BusinessPartnerName2,
      cast(bsec.name3 as ad_name3)                             as BusinessPartnerName3,
      cast(bsec.name4 as ad_name4)                             as BusinessPartnerName4,
      bsec.stras                                               as StreetName,
      bsec.pfach                                               as POBox,
      bsec.po_box_num                                          as POBoxIsWithoutNumber,
      cast(bsec.pstl2 as fis_ad_pstcd2 preserving type)        as POBoxPostalCode,
      bsec.pskto                                               as PostOfficeBankAccount,
      bsec.ort01                                               as CityName,
      bsec.pstlz                                               as PostalCode,
      @ObjectModel.text.association: '_CountryText'
      bsec.land1                                               as Country,
      bsec.regio                                               as Region,
      cast(bsec.intad as ad_smtpadr)                           as EmailAddress,
      bsec.adrnr                                               as AddressID,

      bsec.bankl                                               as BankInternalID,
      @ObjectModel.text.association: '_BankCountryText'
      bsec.banks                                               as BankCountry,
      bsec.bankn                                               as BankAccount,
      bsec.bkont                                               as BankControlKey,
      cast(bsec.bkref as refbk)                                as BankReference,
      bsec.empfg                                               as PaymentRecipient,
      cast(bsec.payment_system as payment_system_id)           as PaymentSystem,
      cast(bsec.alias_type as alias_type_id)                   as AliasType,
      cast(bsec.bank_alias as bu_bank_alias)                   as BPBankAccountAliasName,

      cast(bsec.dtaws as farp_dtaws preserving type )          as DataExchangeInstructionKey,
      bsec.dtams                                               as DataMediumExchangeIndicator,
      bsec.stcd1                                               as TaxID1,
      bsec.stcd2                                               as TaxID2,
      bsec.stcd3                                               as TaxID3,
      bsec.stcd4                                               as TaxID4,
      bsec.stcd5                                               as TaxID5,
      bsec.fityp                                               as AccountTaxType,
      bsec.stcdt                                               as TaxNumberType,
      @Semantics.booleanIndicator
      bsec.stkzn                                               as IsNaturalPerson,
      @Semantics.booleanIndicator
      bsec.stkza                                               as OneTmeAcctIsEqualizationTxSubj,
      bsec.j_1kftbus                                           as BusinessType,
      bsec.j_1kftind                                           as IndustryType,
      bsec.stkzu                                               as IsVATLiable,
      bsec.j_1kfrepre                                          as RepresentativeName,

      bsec.glo_re1_ot                                          as OneTimeAcctCntrySpecificRef1,
      bsec.xcpdk                                               as IsOneTimeAccount,
      @Semantics.booleanIndicator
      bsec.xrguh                                               as OneTimeAcctBankDetIsFromPayt,
      cast(bsec.begru as fota_begru preserving type )          as OneTimeAccountAuthznGroup,
      cast(bsec._dataaging as fota_data_temp preserving type ) as OneTimeAccountDataAgingDate,

      _CompanyCode,
      _AccountingDocument,
      _OperationalAcctgDocItem,
      _FiscalYear,
      _IBAN,
      _Bank,
      _BankCountryText,
      _Address,
      _CountryText,
      _LanguageText,
      _DMEIndicatorText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"BSEC"
],
"ASSOCIATED":
[
"I_ADDRESS",
"I_BANK_2",
"I_COMPANYCODE",
"I_COUNTRYTEXT",
"I_FISCALYEARFORCOMPANYCODE",
"I_IBAN",
"I_JOURNALENTRY",
"I_LANGUAGETEXT",
"I_ONETIMEACCTDATAMDMEXCHTEXT",
"I_OPERATIONALACCTGDOCITEM"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/