P_JournalEntryOneTimeAcctReuse

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'One Time Account Reuse'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.private:true
@VDM.viewType: #COMPOSITE

define view entity P_JournalEntryOneTimeAcctReuse 
  as select from I_JournalEntryOneTimeAccount
  association [1..1] to I_Customer                as _Customer                on  $projection.Customer = _Customer.Customer
  association [1..1] to I_Supplier                as _Supplier                on  $projection.Supplier = _Supplier.Supplier
                                                                         
  association [0..1] to I_FinancialAccountType    as _FinancialAccountType    on  $projection.FinancialAccountType   = _FinancialAccountType.FinancialAccountType

  association [0..*] to I_GlAccountTextInCompanycode  as _GLAccountText       on  $projection.CompanyCode = _GLAccountText.CompanyCode
                                                                              and $projection.GLAccount   = _GLAccountText.GLAccount
  association [0..*] to I_AccountType             as _AccountTaxTypeText      on  $projection.FinancialAccountType = _AccountTaxTypeText.AccountType
                                                                              and $projection.AccountTaxType       = _AccountTaxTypeText.AccountTaxType
  association [0..*] to I_AR_TaxNumberTypeText    as _TaxNumberTypeText       on  $projection.TaxNumberType   = _TaxNumberTypeText.TaxNumberType   
{
      //Key Fields

  key cast('' as fota_sourcedoctype)                       as OneTimeAccountSourceDocType,  //For creation

  key cast('' as fota_sourcedocid)                         as OneTimeAccountSourceDocument, //For creation

  key cast('0000000000' as posnr_acc)                      as OneTimeAccountSourceDocItem,  //For creation

      @ObjectModel.foreignKey.association: '_CompanyCode'
  key CompanyCode,           
      @ObjectModel.foreignKey.association: '_AccountingDocument'                                                                 //For Change & Display

  key AccountingDocument,                                                                   //For Change & Display

      @ObjectModel.foreignKey.association: '_FiscalYear'
  key FiscalYear,                                                                           //For Change & Display

  key AccountingDocumentItem,                                                               //For Change & Display

  key cast ('' as fota_image_type)                         as OneTimeAccountImageType,      //For Draft Data Status Record Use

      //Key Fields for edit

      @ObjectModel.editableFieldFor: 'CompanyCode'
      CompanyCode                                          as CompanyCodeForEdit,
      @ObjectModel.editableFieldFor: 'AccountingDocument'
      AccountingDocument                                   as AccountingDocumentForEdit,
      @ObjectModel.editableFieldFor: 'FiscalYear'
      FiscalYear                                           as FiscalYearForEdit,
      @ObjectModel.editableFieldFor: 'AccountingDocumentItem'
      AccountingDocumentItem                               as AccountingDocumentItemForEdit,

      //Address Fields

      OneTimeAccountBPSalutationText,      
      @Consumption.valueHelpDefinition: [{ entity: {element: 'Language' , name: 'I_OneTimeAccountLanguageVH' }}]
      Language,
      BusinessPartnerName1,
      BusinessPartnerName2,
      BusinessPartnerName3,
      BusinessPartnerName4,
      StreetName,
      POBox,
      POBoxIsWithoutNumber,
      POBoxPostalCode,
      PostOfficeBankAccount,
      CityName,
      PostalCode,
      @Consumption.valueHelpDefinition: [{ entity: {element: 'Country', name: 'C_CountryVHTemp' }} ]
      Country,
      @Consumption.valueHelpDefinition: [{ entity: {element: 'Region', name: 'C_RegionVHTemp' },
                                           additionalBinding: [{ element: 'Country',
                                                                 localElement: 'Country' }]}]
      Region,
      EmailAddress,
      AddressID,

      //Bank fields

      @Consumption.valueHelpDefinition: [{ entity: {element: 'BankInternalID' , name: 'I_Bank_Acct_VH' },
                                           additionalBinding: [{ element: 'BankCountry',
                                                                 localElement: 'BankCountry' }]} ]
      BankInternalID,
      @Consumption.valueHelpDefinition: [{ entity: {element: 'Country' , name: 'C_CountryVHTemp' }} ]
      BankCountry,
      BankAccount,
      BankControlKey,
      BankReference,
      _Bank.SWIFTCode                                      as SWIFTCode,
      _Bank.Bank                                           as Bank,
      _IBAN.IBAN                                           as IBAN,
      cast('' as qriban )                                  as QuickResponseIBAN,
      _IBAN.IBANValidityStartDate                          as IBANValidityStartDate,     
      PaymentRecipient,
      PaymentSystem,
      AliasType,
      BPBankAccountAliasName,
      
      //Tax Fields

      cast(_OperationalAcctgDocItem.VATRegistration as farp_stceg preserving type) as VATRegistration,      
      @Consumption.valueHelpDefinition: [{ entity: {element: 'DataExchangeInstructionKey' , name: 'C_PaytRequestInstructionKeyVH' }} ]
      DataExchangeInstructionKey,      
      @Consumption.valueHelpDefinition: [{ entity: {element: 'DataMediumExchangeIndicator' , name: 'C_DataMediumExchangeVHTemp' }} ]
      DataMediumExchangeIndicator,
      TaxID1,
      TaxID2,
      TaxID3,
      TaxID4,
      TaxID5,      
      @Consumption.valueHelpDefinition: [{ entity: {element: 'AccountTaxType' , name: 'C_AccountTaxTypeValHelpTmp' }} ]
      AccountTaxType,     
      @Consumption.valueHelpDefinition: [{ entity: {element: 'TaxNumberType' , name: 'I_AR_TaxNumberType' }} ]
      TaxNumberType,
      @Semantics.booleanIndicator
      IsNaturalPerson,
      @Semantics.booleanIndicator
      OneTmeAcctIsEqualizationTxSubj,
      BusinessType,
      IndustryType,
      IsVATLiable,
      RepresentativeName,

      //GLO Country Specific Fields

      OneTimeAcctCntrySpecificRef1,
      cast('' as scrtext_m)                                as OneTimeAcctCntrySpcfcRef1Text,
      
      //Internal Technical Fields

      cast('' as fota_transactiontype)                     as OneTimeAccountTransactionType,      
      _AccountingDocument.FiscalPeriod                     as FiscalPeriod,
      _AccountingDocument.TransactionCurrency              as TransactionCurrency,
      _AccountingDocument.IsReversal                       as IsReversal,
      _AccountingDocument.IsReversed                       as IsReversed,
      _OperationalAcctgDocItem.AddressAndBankIsSetManually as AddressAndBankIsSetManually,
      @ObjectModel.foreignKey.association: '_FinancialAccountType'
      _OperationalAcctgDocItem.FinancialAccountType        as FinancialAccountType,
      _OperationalAcctgDocItem.Customer                    as Customer,
      _OperationalAcctgDocItem.Supplier                    as Supplier,
      _OperationalAcctgDocItem.InvoiceReference            as InvoiceReference,
      _OperationalAcctgDocItem.InvoiceReferenceFiscalYear  as InvoiceReferenceFiscalYear,
      _OperationalAcctgDocItem.PostingKey                  as PostingKey,
      _OperationalAcctgDocItem.SpecialGLCode               as SpecialGLCode,
      @Semantics.booleanIndicator
      _OperationalAcctgDocItem.IsSalesRelated              as IsSalesRelated,
      _OperationalAcctgDocItem.DocumentDate                as DocumentDate,
      _OperationalAcctgDocItem.GLAccount                   as GLAccount,
      _OperationalAcctgDocItem.SpecialGLTransactionType    as SpecialGLTransactionType,
      _OperationalAcctgDocItem.ClearingAccountingDocument  as ClearingAccountingDocument,
      _OperationalAcctgDocItem.HasPaymentOrder             as HasPaymentOrder,
      _OperationalAcctgDocItem.DebitCreditCode             as DebitCreditCode,
      _OperationalAcctgDocItem.FollowOnDocumentType        as FollowOnDocumentType,
      _OperationalAcctgDocItem.BPBankAccountInternalID     as BPBankAccountInternalID,
      _OperationalAcctgDocItem.PaytSlipWthRefSubscriber    as PaytSlipWthRefSubscriber,
      _OperationalAcctgDocItem.PaytSlipWthRefReference     as PaytSlipWthRefReference,
      _OperationalAcctgDocItem.AlternativePayeePayer       as AlternativePayeePayer,
      IsOneTimeAccount,
      @Semantics.booleanIndicator
      OneTimeAcctBankDetIsFromPayt,      
      _AccountingDocument.LastChangeDate                   as LastChangeDate,
      cast(OneTimeAccountAuthznGroup as begru)             as OneTimeAccountAuthznGroup,
      cast(OneTimeAccountDataAgingDate as data_temperature) as OneTimeAccountDataAgingDate,
      
      cast('' as char70 )                                  as OneTimeAccountFieldStatusValue,
      cast(' ' as xfeld )                                  as OneTimeAcctDetnIsNotRequired,
      cast(' ' as xfeld )                                  as AcctgDocHasQuickRspBillgSupp,
      cast(' ' as xfeld )                                  as IBANIsQuickResponse,
      cast(' ' as xfeld )                                  as OneTimeAcctChgIsNotAllowed,
      cast(' ' as fota_ref_account_for_iban )              as ReferenceAccountForIBAN,
      cast(' ' as xfeld )                                  as QuickRepIBANIsUsdInOneTmeAcct,
      cast(' ' as xfeld )                                  as SEPAMandtIsUsdInOneTimeAcct,
      cast(' ' as xfeld )                                  as OneTimeAccountIsCreatedFromAPI,
      cast(' ' as xfeld )                                  as QuickRepRefEditIsSupported,
      
      //Association

      _CompanyCode,
      _Customer,
      _Supplier,
      _AccountingDocument,
      _OperationalAcctgDocItem,
      _FiscalYear,
      _Address,
      _IBAN,
      _Bank,
      _FinancialAccountType,
      _CountryText,
      _BankCountryText,
      _LanguageText,
      _GLAccountText,
      _DMEIndicatorText,
      _AccountTaxTypeText,
      _TaxNumberTypeText
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BANK_2",
"I_IBAN",
"I_JOURNALENTRY",
"I_JOURNALENTRYONETIMEACCOUNT",
"I_OPERATIONALACCTGDOCITEM"
],
"ASSOCIATED":
[
"I_ACCOUNTTYPE",
"I_ADDRESS",
"I_AR_TAXNUMBERTYPETEXT",
"I_BANK_2",
"I_COMPANYCODE",
"I_COUNTRYTEXT",
"I_CUSTOMER",
"I_FINANCIALACCOUNTTYPE",
"I_FISCALYEARFORCOMPANYCODE",
"I_GLACCOUNTTEXTINCOMPANYCODE",
"I_IBAN",
"I_JOURNALENTRY",
"I_LANGUAGETEXT",
"I_ONETIMEACCTDATAMDMEXCHTEXT",
"I_OPERATIONALACCTGDOCITEM",
"I_SUPPLIER"
],
"BASE":
[
"I_JOURNALENTRYONETIMEACCOUNT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/