I_IntOrderSettlementDistrRule

@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #TRANSACTIONAL
}

@EndUserText.label: 'Internal Order Distribution Rule'
define view entity I_IntOrderSettlementDistrRule
  as select from I_CtrlgObjSettlmtDistrRule
    inner join   I_InternalOrderSettlementRule on I_CtrlgObjSettlmtDistrRule.ControllingObject = I_InternalOrderSettlementRule.ControllingObject
  association [0..1] to I_InternalOrder                as _InternalOrder                on  $projection.ControllingObject = _InternalOrder.ControllingObject
  association [0..1] to I_NetworkActivityByInternalKey as _NetworkActivityByInternalKey on  $projection.ProjectNetworkInternalID  = _NetworkActivityByInternalKey.ProjectNetworkInternalID
                                                                                        and $projection.NetworkActivityInternalID = _NetworkActivityByInternalKey.NetworkActivityInternalID
  association [0..1] to I_ProjectNetworkBasicData      as _ProjectNetworkBasicData      on  $projection.ProjectNetwork = _ProjectNetworkBasicData.ProjectNetwork
  association [0..1] to I_AcctgSrvcDocumentItemBasic   as _AcctgSrvcDocumentItemBasic   on  $projection.ServiceDocumentType = _AcctgSrvcDocumentItemBasic.ServiceDocumentType
                                                                                        and $projection.ServiceDocument     = _AcctgSrvcDocumentItemBasic.ServiceDocument
                                                                                        and $projection.ServiceDocumentItem = _AcctgSrvcDocumentItemBasic.ServiceDocumentItem
  association [0..1] to I_AcctgServiceDocumentType     as _AcctgServiceDocumentType     on  $projection.ServiceDocumentType = _AcctgServiceDocumentType.ServiceDocumentType
{
  key I_CtrlgObjSettlmtDistrRule.ControllingObject,
  key I_CtrlgObjSettlmtDistrRule.Ledger,
  key I_CtrlgObjSettlmtDistrRule.LedgerGroup,
  key I_CtrlgObjSettlmtDistrRule.SettlementDistributionRuleGrp,
  key I_CtrlgObjSettlmtDistrRule.SettlmtDistrRuleSequence,
      I_CtrlgObjSettlmtDistrRule.SettlementType,
      I_CtrlgObjSettlmtDistrRule.AccountAssignmentType,
      I_CtrlgObjSettlmtDistrRule.SettlementReceiver,
      cast(I_CtrlgObjSettlmtDistrRule.SettlementPercentageRate as fco_sr_io_prozs preserving type ) as SettlementPercentageRate,
      I_CtrlgObjSettlmtDistrRule.SettlementEquivalenceFactor,
      I_CtrlgObjSettlmtDistrRule.SettlementAmount,
      I_CtrlgObjSettlmtDistrRule.SettlementAmountCurrency,
      I_CtrlgObjSettlmtDistrRule.SettlementTransaction,
      I_CtrlgObjSettlmtDistrRule.SettlementDefaultRule,
      @ObjectModel.text.association:null
      I_CtrlgObjSettlmtDistrRule.ControllingArea,
      I_CtrlgObjSettlmtDistrRule.CostCenter,
      @VDM.lifecycle: {
        status: #DEPRECATED,
        successor: 'ProfitabilitySegment_2' }
      I_CtrlgObjSettlmtDistrRule.ProfitabilitySegment,
      I_CtrlgObjSettlmtDistrRule.ProfitabilitySegment_2,
      I_CtrlgObjSettlmtDistrRule.WBSElementInternalID,
      I_CtrlgObjSettlmtDistrRule.WBSElementExternalID,
      I_CtrlgObjSettlmtDistrRule.ProjectNetwork,
      I_CtrlgObjSettlmtDistrRule.CostObject,
      I_CtrlgObjSettlmtDistrRule.BusinessProcess,
      I_CtrlgObjSettlmtDistrRule.SalesOrder,
      I_CtrlgObjSettlmtDistrRule.SalesOrderItem,
      I_CtrlgObjSettlmtDistrRule.OrderID,
      I_CtrlgObjSettlmtDistrRule.OrderItem,
      I_CtrlgObjSettlmtDistrRule.CompanyCode,
      I_CtrlgObjSettlmtDistrRule.ProfitCenter,
      I_CtrlgObjSettlmtDistrRule.MasterFixedAsset,
      I_CtrlgObjSettlmtDistrRule.FixedAsset,
      I_CtrlgObjSettlmtDistrRule.Plant,
      I_CtrlgObjSettlmtDistrRule.Material,
      I_CtrlgObjSettlmtDistrRule.GLAccount,
      I_CtrlgObjSettlmtDistrRule.ValidityStartFiscalPeriod,
      I_CtrlgObjSettlmtDistrRule.ValidityStartFiscalYear,
      I_CtrlgObjSettlmtDistrRule.ValidityEndFiscalPeriod,
      I_CtrlgObjSettlmtDistrRule.ValidityEndFiscalYear,
      I_CtrlgObjSettlmtDistrRule.SettlmtRule1stUsgeFiscalPeriod,
      I_CtrlgObjSettlmtDistrRule.SettlmtRule1stUsageFiscalYear,
      I_CtrlgObjSettlmtDistrRule.SettlmtRuleLastUsgeFsclPeriod,
      I_CtrlgObjSettlmtDistrRule.SettlmtRuleLastUsageFiscalYear,
      I_CtrlgObjSettlmtDistrRule.SettlmtDistributionRuleVersion,
      I_CtrlgObjSettlmtDistrRule.SettlmtTracingFctrDetnMethod,
      I_CtrlgObjSettlmtDistrRule.SettlementDistrAmountRuleType,
      I_CtrlgObjSettlmtDistrRule.SettlmtDistrRuleSrceAssignment,
      I_CtrlgObjSettlmtDistrRule.SettlmtDistributionRuleNumber,
      I_CtrlgObjSettlmtDistrRule.SettlmtDistrManipulationRule,
      I_CtrlgObjSettlmtDistrRule.SettlmtRuleAutomStrategyGnrtn,
      I_CtrlgObjSettlmtDistrRule.SettlementDistrRuleRmngAmount,
      I_CtrlgObjSettlmtDistrRule.SettlementDistrRuleInternalID                                      as NetworkActivityInternalID,
      I_CtrlgObjSettlmtDistrRule.OperationOrderRoutingNumber                                        as ProjectNetworkInternalID,
      I_CtrlgObjSettlmtDistrRule.SettlmtDistrRuleIsUsedInLedger,
      I_CtrlgObjSettlmtDistrRule.SettlementSourceStructure,
      I_CtrlgObjSettlmtDistrRule.BusinessArea,
      I_CtrlgObjSettlmtDistrRule.AssetTransactionType,
      I_CtrlgObjSettlmtDistrRule._ControllingArea.OperatingConcern,
      I_CtrlgObjSettlmtDistrRule.ServiceDocumentType,
      I_CtrlgObjSettlmtDistrRule.ServiceDocument,
      I_CtrlgObjSettlmtDistrRule.ServiceDocumentItem,
      I_CtrlgObjSettlmtDistrRule.SettlementDistributionRuleUUID,
      I_InternalOrderSettlementRule.SettlmtWithFreeDefinedCurrency,
      _InternalOrder.InternalOrder,
      @ObjectModel.text.association:null
      _InternalOrder.OrderType,
      _NetworkActivityByInternalKey.NetworkActivity,
      cast(I_InternalOrderSettlementRule.CompanyCode as fco_sr_io_bukrs preserving type )           as InternalOrderCompanyCode,
      /* Associations */
      I_CtrlgObjSettlmtDistrRule._AccountAssignmentTypeT,
      I_CtrlgObjSettlmtDistrRule._CompanyCode,
      I_CtrlgObjSettlmtDistrRule._ControllingArea,
      I_CtrlgObjSettlmtDistrRule._ControllingObject,
      I_CtrlgObjSettlmtDistrRule._ControllingObjectSettlmtRcvr,
      I_CtrlgObjSettlmtDistrRule._CostCenter,
      I_CtrlgObjSettlmtDistrRule._CtrlgObjectSettlementRule,
      I_CtrlgObjSettlmtDistrRule._SourceStructureAssignment,
      I_CtrlgObjSettlmtDistrRule._Currency,
      I_CtrlgObjSettlmtDistrRule._GLAccount,
      I_CtrlgObjSettlmtDistrRule._JntVntrMnpltnRuleRecoveryInd,
      I_CtrlgObjSettlmtDistrRule._Ledger,
      I_CtrlgObjSettlmtDistrRule._LedgerGroup,
      I_CtrlgObjSettlmtDistrRule._OrderID,
      I_CtrlgObjSettlmtDistrRule._ProjectNetwork,
      I_CtrlgObjSettlmtDistrRule._SettlementAutomGnrtnStrategy,
      I_CtrlgObjSettlmtDistrRule._SettlementType,
      I_CtrlgObjSettlmtDistrRule._SettlementTypeText,
      I_CtrlgObjSettlmtDistrRule._SettlmtDistrAmountRuleType,
      I_CtrlgObjSettlmtDistrRule._SettlmtTracingFctrDetnMethod,
      I_CtrlgObjSettlmtDistrRule._WBSElementBasicData,
      I_CtrlgObjSettlmtDistrRule._AssetTransactionType,
      I_CtrlgObjSettlmtDistrRule._SalesOrderItem,
      I_CtrlgObjSettlmtDistrRule._FixedAsset,
      I_CtrlgObjSettlmtDistrRule._MasterFixedAsset,
      I_CtrlgObjSettlmtDistrRule._BusinessProcess,
      I_CtrlgObjSettlmtDistrRule._ProfitCenter,
      I_CtrlgObjSettlmtDistrRule._AcctgServiceDocumentItem,
      I_CtrlgObjSettlmtDistrRule._ServiceDocumentItem,



      I_InternalOrderSettlementRule._SettlmtWithFreeDfndCurrency,
      _InternalOrder,
      _NetworkActivityByInternalKey,
      _ProjectNetworkBasicData,
      _AcctgSrvcDocumentItemBasic,
      _AcctgServiceDocumentType,
      I_InternalOrderSettlementRule._CompanyCode                                                    as _InternalOrderCompanyCode,
      I_CtrlgObjSettlmtDistrRule._SettlmtTypeLanguageDependent


}
// Only Actual settlement should be displayed (KOAP - Plan settlement, KOAW - Work in Progress and KOAV - Settlement of Variancies should be excluded)

where
     I_CtrlgObjSettlmtDistrRule.SettlementTransaction = 'KOAO'
  or I_CtrlgObjSettlmtDistrRule.SettlementTransaction = ' '
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CONTROLLINGAREA",
"I_CTRLGOBJSETTLMTDISTRRULE",
"I_INTERNALORDER",
"I_INTERNALORDERSETTLEMENTRULE",
"I_NETWORKACTIVITYBYINTERNALKEY"
],
"ASSOCIATED":
[
"I_ACCOUNTASSIGNMENTTYPET",
"I_ACCTGSERVICEDOCUMENTITEM",
"I_ACCTGSERVICEDOCUMENTTYPE",
"I_ACCTGSRVCDOCUMENTITEMBASIC",
"I_ASSETTRANSACTIONTYPE",
"I_BUSINESSPROCESS",
"I_COMPANYCODE",
"I_CONTROLLINGAREA",
"I_CONTROLLINGOBJECT",
"I_COSTCENTER",
"I_CTRLGOBJECTSETTLEMENTRULE",
"I_CTRLGSTRUCTUREASSIGNMENT",
"I_CURRENCY",
"I_FIXEDASSET",
"I_GLACCOUNT",
"I_INTERNALORDER",
"I_JNTVNTRMNPLTNRULERECOVERYIND",
"I_LEDGER",
"I_LEDGERGROUP",
"I_MASTERFIXEDASSET",
"I_NETWORKACTIVITYBYINTERNALKEY",
"I_ORDERBASIC",
"I_PROFITCENTER",
"I_PROJECTNETWORKBASICDATA",
"I_SALESORDERITEM",
"I_SERVICEDOCUMENTITEM",
"I_SETTLEMENTAUTOMGNRTNSTRATEGY",
"I_SETTLEMENTTYPE",
"I_SETTLEMENTTYPETEXT",
"I_SETTLMTDISTRAMOUNTRULETYPE",
"I_SETTLMTTRACINGFCTRDETNMETHOD",
"I_SETTLMTTYPELANGUAGEDEPENDENT",
"I_SETTLMTWITHFREEDFNDCURRENCY",
"I_WBSELEMENTBASICDATA"
],
"BASE":
[
"I_CTRLGOBJSETTLMTDISTRRULE",
"I_INTERNALORDERSETTLEMENTRULE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/