I_InspCharacteristicTP

@AbapCatalog.sqlViewName: 'IINSPCHARCTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #REQUIRED
}
@EndUserText.label: 'Characteristic in Inspection Lot'
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API  // Shall be set for #TRANSACTIONAL views

}

@ObjectModel: {
//    representativeKey: 'InspectionCharacteristic',

    semanticKey: ['InspectionLot','InspPlanOperationInternalID','InspectionCharacteristic'],
    compositionRoot: true,
    sapObjectNodeType.name: 'InspectionLot',
    createEnabled: false,
    updateEnabled: false,
    deleteEnabled: false,                    // Assume: Inspection Results shall never be deleted!?

    transactionalProcessingEnabled: true, 
//    draftEnabled: true,                     // No draft, only 'active persistence'

//    writeDraftPersistence: 'QINSPRSLT_D',          // Not necessary so far

    writeActivePersistence: 'VQAMV_ACTIV', 
    entityChangeStateId: 'ChangedDateTime',
    lifecycle.enqueue: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT15M'                   // Default 'PT15M'

      //  notificationBeforeExpiryInterval: 'PT1M'   // Default 'PT5M'

    },
    lifecycle.processing: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT30M'                        // Default 'PT30M'

      //  notificationBeforeExpiryInterval: 'PT3M'       // Default 'PT10M'

    },
   
    usageType: { dataClass: #TRANSACTIONAL, sizeCategory: #L, serviceQuality: #D }
}

define view I_InspCharacteristicTP as select from I_InspectionCharacteristic as _InspCharc
           inner join I_InspectionLot as _InspLot                       on  _InspCharc.InspectionLot                  = _InspLot.InspectionLot
           inner join I_InspectionOperation as _InspOper                on  _InspCharc.InspectionLot                  = _InspOper.InspectionLot 
                                                                        and _InspCharc.InspPlanOperationInternalID    = _InspOper.InspPlanOperationInternalID
           inner join I_InspCharcFrmtdValues as _FrmtdVal               on  _InspCharc.InspectionLot                  = _FrmtdVal.InspectionLot
                                                                        and _InspCharc.InspPlanOperationInternalID    = _FrmtdVal.InspPlanOperationInternalID
                                                                        and _InspCharc.InspectionCharacteristic       = _FrmtdVal.InspectionCharacteristic
 
  association [0..1] to I_InspectionResultTP as _InspResult             on  $projection.InspectionLot                 = _InspResult.InspectionLot
                                                                        and $projection.InspPlanOperationInternalID   = _InspResult.InspPlanOperationInternalID
                                                                        and $projection.InspectionCharacteristic      = _InspResult.InspectionCharacteristic
                                                                          
  association [0..*] to I_InspectionResultValueTP as _InspResultValue   on  $projection.InspectionLot                 = _InspResultValue.InspectionLot
                                                                        and $projection.InspPlanOperationInternalID   = _InspResultValue.InspPlanOperationInternalID
                                                                        and $projection.InspectionCharacteristic      = _InspResultValue.InspectionCharacteristic

  association [1..*] to I_InspSampleCharcTP as _InspSmplCharc           on  $projection.InspectionLot                 = _InspSmplCharc.InspectionLot
                                                                        and $projection.InspPlanOperationInternalID   = _InspSmplCharc.InspPlanOperationInternalID
                                                                        and $projection.InspectionCharacteristic      = _InspSmplCharc.InspectionCharacteristic
                                                                        
  association [1..*] to I_InspSampleResultTP as _InspSmplResult         on  $projection.InspectionLot                 = _InspSmplResult.InspectionLot
                                                                        and $projection.InspPlanOperationInternalID   = _InspSmplResult.InspPlanOperationInternalID
                                                                        and $projection.InspectionCharacteristic      = _InspSmplResult.InspectionCharacteristic
                                                                 
  //Extension  

  association [1..1] to E_InspectionCharacteristic   as _Extension      on  $projection.InspectionLot                 = _Extension.InspectionLot
                                                                        and $projection.InspPlanOperationInternalID   = _Extension.InspPlanOperationInternalID
                                                                        and $projection.InspectionCharacteristic      = _Extension.InspectionCharacteristic
   
{
     //I_InspectionCharacteristic

     key _InspCharc.InspectionLot,  
     key _InspCharc.InspPlanOperationInternalID, 
     key _InspCharc.InspectionCharacteristic, 
     _InspCharc.InspectionSpecificationText, 
     _InspCharc.HasInspCharcPrtlSmpl, 
     _InspCharc.InspSpecIsQuantitative, 
     _InspCharc.InspSpecIsMeasuredValueRqd, 
     _InspCharc.InspSpecIsSelectedSetRequired, 
     _InspCharc.InspSpecIsLongTermInspection, 
     _InspCharc.InspSpecRecordingType, 
     _InspCharc.InspResultIsDocumentationRqd, 
     _InspCharc.InspSpecCharcCategory, 
     _InspCharc.InspSpecResultCalculation, 
     _InspCharc.InspCharcIsNotPlanned, 
     _InspCharc.InspectionMethod, 
     _InspCharc.InspectionMethodPlant, 
     _InspCharc.InspectionMethodVersion, 
     _InspCharc.InspectionSpecificationPlant, 
     _InspCharc.InspectionSpecification, 
     _InspCharc.InspectionSpecificationVersion, 
     _InspCharc.InspectionCharacteristicStatus, 
     _InspCharc.InspSpecDecimalPlaces,
     @ObjectModel.foreignKey.association: '_InspectionSpecificationUnit' 
     @Semantics.unitOfMeasure: true
     _InspCharc.InspectionSpecificationUnit, 
     _InspCharc.InspSampleValuationRule, 
     @ObjectModel.foreignKey.association: '_QuantityUnit'
     @Semantics.unitOfMeasure: true
     _InspCharc.QuantityUnit, 
     _InspCharc.InspCharacteristicSampleSize, 
     @ObjectModel.foreignKey.association: '_InspCharacteristicSampleUnit'
     @Semantics.unitOfMeasure: true
     _InspCharc.InspCharacteristicSampleUnit, 
     _InspCharc.InspSpecSampleQuantityFactor, 
     @Semantics.quantity.unitOfMeasure: 'InspectionSpecificationUnit'
     _InspCharc.InspSpecTargetValue, 
     _FrmtdVal.InspSpecFrmtdTargetValue,
     _InspCharc.InspSpecHasTargetValue, 
     @Semantics.quantity.unitOfMeasure: 'InspectionSpecificationUnit'
     _InspCharc.InspSpecUpperLimit, 
     _FrmtdVal.InspSpecFrmtdUpperLimit,
     _InspCharc.InspSpecHasUpperLimit, 
     @Semantics.quantity.unitOfMeasure: 'InspectionSpecificationUnit'
     _InspCharc.InspSpecLowerLimit, 
     _FrmtdVal.InspSpecFrmtdLowerLimit,
     _InspCharc.InspSpecHasLowerLimit, 
     _InspCharc.InspSpecImportanceCode, 
     _InspCharc.InspLotTestEquipInternalID, 
     _InspCharc.SelectedCodeSet, 
     _InspCharc.SelectedCodeSetPlant, 
     _InspCharc.InspectorQualification, 
     _InspCharc.InspSpecFormula1,
     _InspCharc.InspSpecFormula2,
     _InspCharc.InspSpecInformationField1, 
     _InspCharc.InspSpecInformationField2, 
     _InspCharc.InspSpecInformationField3, 
     _InspCharc.InspSpecDefectCodeGrpRjcnLower,
     _InspCharc.InspSpecDefectCodeRjcnLower,
     _InspCharc.InspSpecDefectCodeGrpRjcnUpper,
     _InspCharc.InspSpecDefectCodeRjcnUpper,
     _InspCharc.InspSpecDefectCodeGrpRejection,
     _InspCharc.InspSpecDefectCodeRejection,
     @API.element.releaseState: #DEPRECATED
     @API.element.successor:    'InspCharcQuantity'   
     _InspCharc.InspectionScope,
     @Semantics.quantity.unitOfMeasure: 'QuantityUnit'  
     _InspCharc.InspCharcQuantity,
     _InspCharc.InspSpecControlIndicators, 
     _InspCharc.CharacteristicAttributeCatalog, 
     _InspCharc.UnplndCharcInspSubsetIntID, 
     _InspCharc.InspLotDynamicRule, 
     _InspCharc.QualityLevelInternalID, 
     _InspCharc.BOOCharcGroup, 
     _InspCharc.BOOCharcSourceCharc, 
     _InspCharc.BOOCharcGroupDivision, 
     _InspCharc.ProductionOrderOperationActy, 
     _InspCharc.ProductionOrderOpActyVers,
     @ObjectModel.readOnly: true
     _InspCharc.InspCharcConfirmationNumber,
     _InspCharc.InspCharcCreationDate, 
     
     _InspCharc.InspSpecAdditionalCatalog2,
     _InspCharc.InspSpecAdditionalCatalog3,
     _InspCharc.InspSpecAdditionalCatalog4,
     _InspCharc.InspSpecAdditionalCatalog5,
     _InspCharc.InspSpecAddlSeldCodeSetPlant2,
     _InspCharc.InspSpecAddlSeldCodeSetPlant3,
     _InspCharc.InspSpecAddlSeldCodeSetPlant4,
     _InspCharc.InspSpecAddlSeldCodeSetPlant5,
     _InspCharc.InspSpecAdditionalSelectedSet2,
     _InspCharc.InspSpecAdditionalCodeGroup2,
     _InspCharc.InspSpecAdditionalSelectedSet3,
     _InspCharc.InspSpecAdditionalCodeGroup3,
     _InspCharc.InspSpecAdditionalSelectedSet4,
     _InspCharc.InspSpecAdditionalCodeGroup4,
     _InspCharc.InspSpecAdditionalSelectedSet5,
     _InspCharc.InspSpecAdditionalCodeGroup5,      
 
        //eTag - taken from Inspection Lot (Hint: Using the association seems not possible! When I tried I got errors from BO generation!!)

      @ObjectModel.readOnly: true
     _InspLot.ChangedDateTime,

//    InspSpecRecordingType,


  // for Auth Check only

   @Consumption.hidden: true
   _InspLot.Plant,
   @Consumption.hidden: true
   _InspLot.IsBusinessPurposeCompleted,
   @Consumption.hidden: true
  _InspOper._WorkCenter.WorkCenter,
   @Consumption.hidden: true
   _InspLot.InspectionLotType,
   @Consumption.hidden: true
   _InspLot.MatlQualityAuthorizationGroup,   
    
    /* Object model relations */
    @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
    _InspResult,
    @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
    _InspResultValue,
    @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
    _InspSmplCharc,   
    @ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
    _InspSmplResult,
    
    _QuantityUnit,
    _InspectionSpecificationUnit,
    _InspCharacteristicSampleUnit

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPCHARCFRMTDVALUES",
"I_INSPECTIONCHARACTERISTIC",
"I_INSPECTIONLOT",
"I_INSPECTIONOPERATION",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"E_INSPECTIONCHARACTERISTIC",
"I_INSPECTIONRESULTTP",
"I_INSPECTIONRESULTVALUETP",
"I_INSPSAMPLECHARCTP",
"I_INSPSAMPLERESULTTP",
"I_UNITOFMEASURE"
],
"BASE":
[
"I_INSPECTIONCHARACTERISTIC"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/