I_InspectionResultValueTP

@AbapCatalog.sqlViewName: 'IINSPRSLTVALTP'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Inspection Result Single Value'
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API  // Shall be set for #TRANSACTIONAL views

}
 
@ObjectModel: {
//    representativeKey: 'InspResultValueInternalID',

    semanticKey: ['InspectionLot','InspPlanOperationInternalID','InspectionCharacteristic','InspResultValueInternalID'],
    compositionRoot: false,
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: false,                    // Assume: Inspection Results shall never be deleted!?

    transactionalProcessingEnabled: true,
//    draftEnabled: true,                     // No draft, only 'active persistence'

//    writeDraftPersistence: 'QINSPRSLTVAL_D',         // Not necessary so far

    writeActivePersistence: 'VQASE_ACTIV',
    entityChangeStateId: 'ChangedDateTime',
    lifecycle.enqueue: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT15M'                   // Default 'PT15M'

      //  notificationBeforeExpiryInterval: 'PT1M'   // Default 'PT5M'

    },
    lifecycle.processing: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT30M'                        // Default 'PT30M'

      //  notificationBeforeExpiryInterval: 'PT3M'       // Default 'PT10M'

    },
    
    usageType: { dataClass: #TRANSACTIONAL, sizeCategory: #L, serviceQuality: #C }
}

define view I_InspectionResultValueTP  as select from I_InspectionResultValue as _InspResultValue  
    inner join  I_InspectionResultTP   as _InspectionResult         on  _InspResultValue.InspectionLot               = _InspectionResult.InspectionLot
                                                                    and _InspResultValue.InspPlanOperationInternalID = _InspectionResult.InspPlanOperationInternalID
                                                                    and _InspResultValue.InspectionCharacteristic    = _InspectionResult.InspectionCharacteristic
                                                                     
    inner join I_InspectionLot as _InspLot                          on  _InspResultValue.InspectionLot               = _InspLot.InspectionLot
    
    inner join I_InspectionOperation as _InspOper                   on  _InspResultValue.InspectionLot               = _InspOper.InspectionLot 
                                                                    and _InspResultValue.InspPlanOperationInternalID = _InspOper.InspPlanOperationInternalID            

    inner join I_InspResultValueFrmtdValues as _FrmtdVal            on  _InspResultValue.InspectionLot               = _FrmtdVal.InspectionLot
                                                                    and _InspResultValue.InspPlanOperationInternalID = _FrmtdVal.InspPlanOperationInternalID
                                                                    and _InspResultValue.InspectionCharacteristic    = _FrmtdVal.InspectionCharacteristic
                                                                    and _InspResultValue.InspResultValueInternalID   = _FrmtdVal.InspResultValueInternalID

    association [1..1] to I_InspCharacteristicTP as _InspCharc      on  $projection.InspectionLot                    = _InspCharc.InspectionLot
                                                                    and $projection.InspPlanOperationInternalID      = _InspCharc.InspPlanOperationInternalID
                                                                    and $projection.InspectionCharacteristic         = _InspCharc.InspectionCharacteristic

    association [1..1] to E_InspectionResultValue  as _Extension // "_Extension is only defined, but not exposed because of Guideline !

                                                                    on  $projection.InspectionLot                    = _Extension.InspectionLot
                                                                    and $projection.InspPlanOperationInternalID      = _Extension.InspPlanOperationInternalID
                                                                    and $projection.InspectionCharacteristic         = _Extension.InspectionCharacteristic
                                                                    and $projection.InspResultValueInternalID        = _Extension.InspResultValueInternalID                                                                                  
{  
  key _InspResultValue.InspectionLot,
  key _InspResultValue.InspPlanOperationInternalID,
  key _InspResultValue.InspectionCharacteristic,
  key _InspResultValue.InspResultValueInternalID,
   
      _InspResultValue.InspectionResultAttribute,
      @ObjectModel.readOnly: true
      _InspResultValue.InspectionResultMeasuredValue,   
      _FrmtdVal.InspResultFrmtdMeasuredValue,
      @ObjectModel.readOnly: true
      _InspResultValue.InspResultHasMeasuredValue,
      _InspResultValue.InspectionResultOriginalValue,
      _InspResultValue.InspectionNumberOfDefects, 
      @ObjectModel.readOnly: true    
      _InspResultValue.DefectClass,
      @ObjectModel.readOnly: true      
      _InspResultValue.InspResultItemInternalID,
      _InspResultValue.InspectionSubsetInternalID,
      _InspResultValue.InspectionResultText,
      _InspResultValue.InspLotSingleUnitNumber,
      _InspResultValue.InspectionResultItem,
      _InspResultValue.InspRsltFreeDefinedTestEquip,
      _InspResultValue.InspectionValuationResult,
      _InspResultValue.CharacteristicAttributeCodeGrp,
      _InspResultValue.InspectionResultCodeGroup2,
      _InspResultValue.InspectionResultCodeGroup3,
      _InspResultValue.InspectionResultCodeGroup4,
      _InspResultValue.InspectionResultCodeGroup5,
      _InspResultValue.CharacteristicAttributeCode,
      _InspResultValue.InspectionResultCode2,
      _InspResultValue.InspectionResultCode3,
      _InspResultValue.InspectionResultCode4,
      _InspResultValue.InspectionResultCode5,
      @ObjectModel.readOnly: true
      _InspResultValue.CharcAttributeCodeVers,      
      @ObjectModel.readOnly: true
      _InspResultValue.InspectionResultCode2Vers,      
      @ObjectModel.readOnly: true
      _InspResultValue.InspectionResultCode3Vers,      
      @ObjectModel.readOnly: true
      _InspResultValue.InspectionResultCode4Vers,      
      @ObjectModel.readOnly: true
      _InspResultValue.InspectionResultCode5Vers,      
      @ObjectModel.readOnly: true
      _InspResultValue.CharacteristicAttributeCatalog,
      @ObjectModel.readOnly: true
      _InspResultValue.InspectionResultCatalog2,
      @ObjectModel.readOnly: true
      _InspResultValue.InspectionResultCatalog3,
      @ObjectModel.readOnly: true
      _InspResultValue.InspectionResultCatalog4,
      @ObjectModel.readOnly: true
      _InspResultValue.InspectionResultCatalog5,   
      _InspResultValue.Inspector,
      _InspResultValue.InspectionStartDate,
      _InspResultValue.InspectionStartTime,
      _InspResultValue.InspectionEndDate,
      _InspResultValue.InspectionEndTime,
      
//      // eTag - taken from summarized inspection result

      @ObjectModel.readOnly: true
      _InspectionResult.ChangedDateTime,

      @ObjectModel.readOnly: true
      _InspResultValue.CreationDate,
      @ObjectModel.readOnly: true
      _InspResultValue.CreatedByUser,
      @ObjectModel.readOnly: true
      _InspResultValue.LastChangedByUser,
      @ObjectModel.readOnly: true
      _InspResultValue.LastChangeDate,
      @ObjectModel.readOnly: true
      _InspResultValue.ChangedTime,
      @ObjectModel.readOnly: true
      _InspResultValue.CreationTime,

      // for Auth Check only

      @Consumption.hidden: true
      _InspLot.Plant,
      @Consumption.hidden: true
      _InspLot.IsBusinessPurposeCompleted,
      @Consumption.hidden: true
      _InspOper._WorkCenter.WorkCenter,
      @Consumption.hidden: true
      _InspLot.InspectionLotType,
      @Consumption.hidden: true
      _InspLot.MatlQualityAuthorizationGroup,   
          
      /* Object model relations */
      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT ]
      _InspCharc
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPECTIONLOT",
"I_INSPECTIONOPERATION",
"I_INSPECTIONRESULTTP",
"I_INSPECTIONRESULTVALUE",
"I_INSPRESULTVALUEFRMTDVALUES",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"E_INSPECTIONRESULTVALUE",
"I_INSPCHARACTERISTICTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/