I_InspSampleResultTP

@AbapCatalog.sqlViewName: 'IINSPSAMPLERESTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Inspection Result for Inspection Point'
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM: {
    viewType: #TRANSACTIONAL,
    lifecycle.contract.type: #SAP_INTERNAL_API  // Shall be set for #TRANSACTIONAL views

}
@ObjectModel: {
    semanticKey: ['InspectionLot','InspPlanOperationInternalID','InspectionCharacteristic','InspectionSubsetInternalID'],
    compositionRoot: false,
    createEnabled: true,
    updateEnabled: true,
    deleteEnabled: false,
    transactionalProcessingEnabled: true,
    //draftEnabled: false,

    writeActivePersistence: 'VQASR_ACTIV',
    entityChangeStateId: 'ChangedDateTime',
    lifecycle.enqueue: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // = Default

        expiryInterval: 'PT15M'                    // = Default

      //  notificationBeforeExpiryInterval: 'PT1M'   // Default 'PT5M'

    },
    lifecycle.processing: {
        expiryBehavior: #RELATIVE_TO_LAST_CHANGE,  // Default #RELATIVE_TO_LAST_CHANGE

        expiryInterval: 'PT30M'                        // Default 'PT30M'

      //  notificationBeforeExpiryInterval: 'PT3M'       // Default 'PT10M'

    },
    
    usageType: { dataClass: #TRANSACTIONAL, sizeCategory: #L, serviceQuality: #C }
}

define view I_InspSampleResultTP as select from I_InspSubsetResult as _InspSampleResult 
// join relevant fields for authorization check: I_InspectionLot & I_InspectionOperation

  inner join I_InspectionLot       as _InspLot                on  _InspSampleResult.InspectionLot               = _InspLot.InspectionLot
  inner join I_InspectionOperation as _InspOper               on  _InspSampleResult.InspectionLot               = _InspOper.InspectionLot 
                                                              and _InspSampleResult.InspPlanOperationInternalID = _InspOper.InspPlanOperationInternalID
  // join eTAG

  inner join  I_InspectionResultTP as _InspectionResult       on  _InspSampleResult.InspectionLot               = _InspectionResult.InspectionLot
                                                              and _InspSampleResult.InspPlanOperationInternalID = _InspectionResult.InspPlanOperationInternalID
                                                              and _InspSampleResult.InspectionCharacteristic    = _InspectionResult.InspectionCharacteristic
  // join formatted values

  inner join I_InspSampleResultFrmtdValues as _FrmtdVal       on  _InspSampleResult.InspectionLot               = _FrmtdVal.InspectionLot
                                                              and _InspSampleResult.InspPlanOperationInternalID = _FrmtdVal.InspPlanOperationInternalID
                                                              and _InspSampleResult.InspectionCharacteristic    = _FrmtdVal.InspectionCharacteristic
                                                              and _InspSampleResult.InspectionSubsetInternalID  = _FrmtdVal.InspectionSubsetInternalID
                                                              
  // Root & Parent association: Inspection Characteristic

  association [1..1] to I_InspCharacteristicTP as _InspCharc  on  $projection.InspectionLot                    = _InspCharc.InspectionLot
                                                              and $projection.InspPlanOperationInternalID      = _InspCharc.InspPlanOperationInternalID
                                                              and $projection.InspectionCharacteristic         = _InspCharc.InspectionCharacteristic


{
key _InspSampleResult.InspectionLot,
key _InspSampleResult.InspPlanOperationInternalID,
key _InspSampleResult.InspectionCharacteristic,
key _InspSampleResult.InspectionSubsetInternalID,  // as InspectionSampleInternalID,

_InspSampleResult.Inspector,
_InspSampleResult.InspectionResultStatus,
_InspSampleResult.InspectionResultOrigin,
_InspSampleResult.InspectionStartDate,
_InspSampleResult.InspectionStartTime,
_InspSampleResult.InspectionEndDate,
_InspSampleResult.InspectionEndTime,
_InspSampleResult.InspectionResultAttribute,
_InspSampleResult.InspectionValuationResult,
@ObjectModel.readOnly: true
_InspSampleResult.InspResultDynModifValuation,
@ObjectModel.readOnly: true
_InspSampleResult.InspectionResultMeanValue,
_FrmtdVal.InspResultFrmtdMeanValue,
@ObjectModel.readOnly: true
_InspSampleResult.InspectionResultHasMeanValue,
@ObjectModel.readOnly: true
_InspSampleResult.InspectionResultMaximumValue,
_FrmtdVal.InspResultFrmtdMaximumValue,
@ObjectModel.readOnly: true
_InspSampleResult.InspResultHasMaximumValue,
@ObjectModel.readOnly: true
_InspSampleResult.InspectionResultMinimumValue,
_FrmtdVal.InspResultFrmtdMinimumValue,
@ObjectModel.readOnly: true
_InspSampleResult.InspResultHasMinimumValue,
@ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
_InspSampleResult.InspectionResultOriginalValue,
_InspSampleResult.InspResultValidValuesNumber,
_InspSampleResult.InspectionResultText,
 @ObjectModel.readOnly: true
_InspSampleResult.InspectionResultHasLongText,
@ObjectModel.readOnly: true
_InspSampleResult.Language,
_InspSampleResult.InspRsltFreeDefinedTestEquip,
_InspSampleResult.InspRsltBelowToleranceValsNmbr,
_InspSampleResult.InspRsltAboveToleranceValsNmbr,
@ObjectModel.readOnly: true    
_InspSampleResult.InspRsltAboveToleranceFraction,
@ObjectModel.readOnly: true        
_FrmtdVal.InspRsltFrmtdAbvTolFraction, 
@ObjectModel.readOnly: true       
_InspSampleResult.InspRsltBelowToleranceFraction,
@ObjectModel.readOnly: true        
_FrmtdVal.InspRsltFrmtdBelowTolFraction, 
@ObjectModel.readOnly: true       
_InspSampleResult.InspResultVariance,
_FrmtdVal.InspResultFrmtdVariance,
_InspSampleResult.InspRsltNonconformingValsNmbr,
_InspSampleResult.InspResultNmbrOfRecordedRslts,
 @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'  // allow dynamic field control via BOPF

_InspSampleResult.InspectionNumberOfDefects,
@ObjectModel.readOnly: true
_InspSampleResult.CharcAttributeCodeVers,
@ObjectModel.readOnly: true
_InspSampleResult.InspectionResultCode2Vers, 
@ObjectModel.readOnly: true
_InspSampleResult.InspectionResultCode3Vers, 
@ObjectModel.readOnly: true
_InspSampleResult.InspectionResultCode4Vers, 
@ObjectModel.readOnly: true
_InspSampleResult.InspectionResultCode5Vers, 
_InspSampleResult.CharacteristicAttributeCodeGrp,
_InspSampleResult.InspectionResultCodeGroup2,
_InspSampleResult.InspectionResultCodeGroup3,
_InspSampleResult.InspectionResultCodeGroup4,
_InspSampleResult.InspectionResultCodeGroup5,
_InspSampleResult.CharacteristicAttributeCode,
_InspSampleResult.InspectionResultCode2,
_InspSampleResult.InspectionResultCode3,
_InspSampleResult.InspectionResultCode4,
_InspSampleResult.InspectionResultCode5,
_InspSampleResult.CharacteristicAttributeCatalog,
_InspSampleResult.InspectionResultCatalog2,
_InspSampleResult.InspectionResultCatalog3,
_InspSampleResult.InspectionResultCatalog4,
_InspSampleResult.InspectionResultCatalog5,
@ObjectModel.readOnly: true
_InspSampleResult.DefectClass,
_InspSampleResult.CreatedByUser,
_InspSampleResult.CreationDate,
_InspSampleResult.CreationTime,
_InspSampleResult.LastChangedByUser,
_InspSampleResult.LastChangeDate,
_InspSampleResult.ChangedTime,

// eTag of the Inspection Result (QAMR-ChangedDateTime) must be checked

@ObjectModel.readOnly: true
_InspectionResult.ChangedDateTime,
    
// for Authorization Check only

@Consumption.hidden: true
_InspLot.Plant,
@Consumption.hidden: true
_InspLot.IsBusinessPurposeCompleted,
@Consumption.hidden: true
_InspOper._WorkCenter.WorkCenter,
@Consumption.hidden: true
_InspLot.InspectionLotType,
@Consumption.hidden: true
_InspLot.MatlQualityAuthorizationGroup,

    /* Object model relations */
 @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
 _InspCharc

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_INSPECTIONLOT",
"I_INSPECTIONOPERATION",
"I_INSPECTIONRESULTTP",
"I_INSPSAMPLERESULTFRMTDVALUES",
"I_INSPSUBSETRESULT",
"I_WORKCENTER"
],
"ASSOCIATED":
[
"I_INSPCHARACTERISTICTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/