I_FldLogsMatlDocItems

@AbapCatalog.sqlViewName: 'IFLMATDOCITMS'
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Material Document Items'

@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@ObjectModel: {
    usageType: {
        sizeCategory: #XXL,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    },
    representativeKey: 'MaterialDocumentItem'
}

define view I_FldLogsMatlDocItems
  as select from I_MaterialDocumentRecord as _MaterialDocumentRecord
    inner join   I_FldLogsPlants          as _FldLogsAllPlants on _MaterialDocumentRecord.Plant = _FldLogsAllPlants.Plant
  association [1..1] to I_MaterialDocumentHeader as _MaterialDocumentHeader on  $projection.MaterialDocumentYear         = _MaterialDocumentHeader.MaterialDocumentYear
                                                                            and $projection.MaterialDocument             = _MaterialDocumentHeader.MaterialDocument    
  association [0..1] to I_FldLogsMatlDocItems as _ReversedMatDocItem on  $projection.MaterialDocumentYear = _ReversedMatDocItem.ReversedMaterialDocumentYear
                                                                     and $projection.MaterialDocument     = _ReversedMatDocItem.ReversedMaterialDocument
                                                                     and $projection.MaterialDocumentItem = _ReversedMatDocItem.ReversedMaterialDocumentItem
{
  key _MaterialDocumentRecord.MaterialDocumentYear         as MaterialDocumentYear,
  key _MaterialDocumentRecord.MaterialDocument             as MaterialDocument,
  key _MaterialDocumentRecord.MaterialDocumentItem         as MaterialDocumentItem,
      _MaterialDocumentRecord.Material                     as Material,
      _MaterialDocumentRecord.Plant                        as Plant,
      _MaterialDocumentRecord.StorageLocation              as StorageLocation,
      _MaterialDocumentRecord.Batch                        as Batch,
      _MaterialDocumentRecord.ShelfLifeExpirationDate      as ShelfLifeExpirationDate,
      _MaterialDocumentRecord.ManufactureDate              as ManufactureDate,
      _MaterialDocumentRecord.InventoryStockType           as InventoryStockType,
      _MaterialDocumentRecord.GoodsMovementType            as GoodsMovementType,

      @Semantics.quantity.unitOfMeasure: 'MaterialBaseUnit'
      @DefaultAggregation: #SUM
      _MaterialDocumentRecord.QuantityInBaseUnit           as QuantityInBaseUnit,
      @Semantics.unitOfMeasure: true
      _MaterialDocumentRecord.MaterialBaseUnit             as MaterialBaseUnit,
      @Semantics.businessDate.at: true
      _MaterialDocumentRecord.PostingDate                  as PostingDate,
      @Semantics.businessDate.at: true
      _MaterialDocumentRecord.DocumentDate                 as DocumentDate,
      _MaterialDocumentRecord.InventoryValuationType       as InventoryValuationType,
      _MaterialDocumentRecord.PurchaseOrder                as PurchaseOrder,
      _MaterialDocumentRecord.PurchaseOrderItem            as PurchaseOrderItem,
      _MaterialDocumentRecord.DeliveryDocument             as DeliveryDocument,
      _MaterialDocumentRecord.DeliveryDocumentItem         as DeliveryDocumentItem,
      _MaterialDocumentRecord.ReversedMaterialDocumentYear as ReversedMaterialDocumentYear,
      _MaterialDocumentRecord.ReversedMaterialDocument     as ReversedMaterialDocument,
      _MaterialDocumentRecord.ReversedMaterialDocumentItem as ReversedMaterialDocumentItem,
      _MaterialDocumentHeader,
      _ReversedMatDocItem

}
where
  _MaterialDocumentRecord.MaterialDocumentRecordType = 'MDOC'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FLDLOGSPLANTS",
"I_MATERIALDOCUMENTRECORD"
],
"ASSOCIATED":
[
"I_MATERIALDOCUMENTHEADER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/