I_FldLogsProcRcptFollowOnDocs

@AbapCatalog.sqlViewName: 'IFLFOLDOC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Field Logistics Follow on Documents'
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #M
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
define view I_FldLogsProcRcptFollowOnDocs
  as select from           I_PurchasingDocumentItem  as PO
    inner join             I_FldLogsPlants           as _FldLogsAllPlants       on PO.Plant = _FldLogsAllPlants.Plant
    inner join  I_FldLogsMatlDocItems as _MaterialDocumentRecord on  PO.PurchasingDocument     = _MaterialDocumentRecord.PurchaseOrder
                                                                   and PO.PurchasingDocumentItem = _MaterialDocumentRecord.PurchaseOrderItem
    
    left outer to one join I_FldLogsSuplrReceiptItem as _SupplierItem           on  PO.PurchasingDocument                        = _SupplierItem.PurchasingDocument
                                                                                and _MaterialDocumentRecord.MaterialDocument     = _SupplierItem.MaterialDocument
                                                                                and _MaterialDocumentRecord.MaterialDocumentItem = _SupplierItem.MaterialDocumentItem
                                                                                and _MaterialDocumentRecord.MaterialDocumentYear = _SupplierItem.MaterialDocumentYear

    left outer to one join I_FldLogsInspectionLot    as _InspectionLot          on  _MaterialDocumentRecord.MaterialDocument     = _InspectionLot.MaterialDocument
                                                                                and _MaterialDocumentRecord.MaterialDocumentItem = _InspectionLot.MaterialDocumentItem
                                                                                and _MaterialDocumentRecord.MaterialDocumentYear = _InspectionLot.MaterialDocumentYear
{

  key PO.PurchasingDocument,
  key PO.PurchasingDocumentItem,
  key _MaterialDocumentRecord.MaterialDocument                        as MaterialDocument,
  key _MaterialDocumentRecord.MaterialDocumentItem                    as MaterialDocumentItem,
  key _MaterialDocumentRecord.MaterialDocumentYear                    as MaterialDocumentYear,
  key coalesce(_MaterialDocumentRecord.DeliveryDocument,'')           as DeliveryDocument,
  key coalesce(_MaterialDocumentRecord.DeliveryDocumentItem,'000000') as DeliveryDocumentItem,
  key case when _SupplierItem.FldLogsSuplrItemUUID is null
      then hextobin('00000000000000000000000000000000')
      else _SupplierItem.FldLogsSuplrItemUUID end                     as FldLogsSuplrItemUUID,
      _InspectionLot.InspectionLot,
      @VDM.lifecycle.status: #DEPRECATED
      cast('          ' as ebeln)                                     as StockTransportOrder,
      @VDM.lifecycle.status: #DEPRECATED
      cast(' ' as vbeln )                                             as OutboundDelivery,
      @VDM.lifecycle.status: #DEPRECATED
      cast(' ' as /scdl/dl_docno_int )                                as EWMOutboundDelivery,
      _MaterialDocumentRecord._ReversedMatDocItem.MaterialDocument    as ReversedMaterialDocument
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FLDLOGSINSPECTIONLOT",
"I_FLDLOGSMATLDOCITEMS",
"I_FLDLOGSPLANTS",
"I_FLDLOGSSUPLRRECEIPTITEM",
"I_PURCHASINGDOCUMENTITEM"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/