I_FailureModeEffectAnalysisTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'FMEA - TP'
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.sapObjectNodeType.name: 'FailureModeEffectAnalysis' 
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #M,
    serviceQuality: #C
}
@ObjectModel: {
  semanticKey: [ 'FMEAHeader'  ]
}
define root view entity I_FailureModeEffectAnalysisTP
  as select from I_FailureModeEffectAnalysis
  composition [0..*] of I_FMEANodeTP              as _FMEANode
  composition [0..*] of I_FMEANodeHierarchyTP     as _FMEANodeHierarchyTP
  composition [0..*] of I_FMEAPartnerTP           as _FMEAPartnerTP
  composition [0..*] of I_FMEAObjectTP            as _FMEAObjectTP
  composition [0..*] of I_FMEATextTP              as _FMEATextTP
  composition [0..*] of I_FMEADescriptionTP       as _FMEADescriptionTP
  //Special node types

  composition [0..*] of I_FMEAElementNodeTP       as _ElementNode
  composition [0..*] of I_FMEAFunctionNodeTP      as _FunctionNode
  composition [0..*] of I_FMEAFailureNodeTP       as _FailureNode
  composition [0..*] of I_FMEACauseNodeTP         as _CauseNode
  composition [0..*] of I_FMEACauseTaskTP         as _CauseTaskNode
  composition [0..*] of I_FMEAEffectNodeTP        as _EffectNode
  //Hierarchical associations

  association [0..*] to I_FMEAInternalFunctionNet as _FMEAInternalFunctionNet on  $projection.FMEAHeaderUUID = _FMEAInternalFunctionNet.FMEAHeaderUUID
  association [0..*] to I_FMEAFunctionNet         as _FMEAFunctionNet         on  $projection.FMEAHeaderUUID = _FMEAFunctionNet.FMEAHeaderUUID
  association [0..*] to I_FMEAFailureNet          as _FailureNet              on  $projection.FMEAHeaderUUID = _FailureNet.FMEAHeaderUUID
  //Association to not changeable data

  association [0..*] to I_FMEATypeText            as _FMEATypeText            on  $projection.FMEAType = _FMEATypeText.FMEAType
  association [0..*] to I_FMEAConfidentialityLevelText as _FMEAConfidentialityLevelText on $projection.FMEAConfidentialityLevel = _FMEAConfidentialityLevelText.FMEAConfidentialityLevel
  association [0..*] to I_FMEAAuthorizationGroupT as _FMEAAuthorizationGroupT on  $projection.FMEAAuthorizationGroup = _FMEAAuthorizationGroupT.FMEAAuthorizationGroup
  association [0..*] to I_FMEAStatusText          as _FMEAStatusText          on  $projection.FMEAStatus = _FMEAStatusText.FMEAStatus
  association [0..1] to I_FMEAObjectAggregate     as _FMEAObjectAggregate     on  $projection.FMEAHeaderUUID = _FMEAObjectAggregate.FMEAHeaderUUID
  association [0..1] to I_FMEATaskAggregate       as _FMEATaskAggregate       on  $projection.FMEAHeaderUUID = _FMEATaskAggregate.FMEAHeaderUUID
  association [0..1] to I_FMEATextTP              as _FMEATextTP1             on  $projection.FMEAHeaderUUID = _FMEATextTP1.FMEAHeaderUUID
                                                                              and _FMEATextTP1.Language      = $session.system_language
  association [0..1] to I_FMEATextTP              as _FMEATextTP2             on  $projection.FMEAHeaderUUID   = _FMEATextTP2.FMEAHeaderUUID
                                                                              and $projection.OriginalLanguage = _FMEATextTP2.Language                                                                                                                                                          
  association [0..1] to I_FMEADescriptionTP       as _FMEADescriptionTP1      on  $projection.FMEAHeaderUUID = _FMEADescriptionTP1.FMEANodeUUID
                                                                              and _FMEADescriptionTP1.Language  = $session.system_language                                                               
  association [0..1] to I_QltyMgmtSystAndUsrTmeZn as _QltyMgmtSystAndUsrTmeZn on 1 = 1

{

  key FMEAHeaderUUID,
      cast( bintohex( FMEAHeaderUUID ) as apoc_appl_object_id ) as OutputControlApplicationObject,
      OriginalLanguage,
      _FMEAHeader.FMEAHeader,
      FMEAType,
      FMEAAuthorizationGroup,
      FMEAStatus,
      FMEACalculationStatus,
      _FMEAHeader.CreatedByUser,
      _FMEAHeader.CreationDate,
      _FMEAHeader.LastChangedByUser,
      _FMEAHeader.LastChangedDate,
      _FMEAHeader.FMEAActualStartDateTime,
      ChangedDateTime,
      case when _FMEATextTP1.FMEADescription is null then _FMEATextTP2.FMEADescription
        else _FMEATextTP1.FMEADescription
      end as FMEAInCurLangDescription,
      _FMEADescriptionTP1.FMEALongText as FMEALongTextDesc,
      FMEAValuationResultValue,
      FMEAValuationProcedure,
      FMEARatingProfile,
      FMEARating,
      1 as FMEARatingCriticality,
      FMEAGroup,
      FMEASearchTermValue,
      FMEAIsHeaderFMEA,
      FMEAConfidentialityLevel,
      cast( tstmp_to_dats( _FMEAHeader.FMEAActualStartDateTime,
                     _QltyMgmtSystAndUsrTmeZn.QltyMgmtUserTimeZone,
                     $session.client,
                     'NULL' ) as plmt_actualstartdate preserving type ) as FMEAActualStartDate,
      cast( tstmp_to_tims( _FMEAHeader.FMEAActualStartDateTime,
                     _QltyMgmtSystAndUsrTmeZn.QltyMgmtUserTimeZone,
                     $session.client,
                     'NULL' ) as cgpl_actualstarttime preserving type ) as FMEAActualStartTime,
           
      //Associatons

      _FMEANode,
      _FMEANodeHierarchyTP,
      _FMEAPartnerTP,
      _FMEAObjectTP,
      _FMEATextTP,
      _FMEADescriptionTP,
      _FMEAHeaderLongText,
      _FMEAText,
      _FMEAHeader._CreatedByUserContactCard,
      _FMEAHeader._LastChangedByUserContactCard,
      _ElementNode,
      _FunctionNode,
      _FMEAFunctionNet,
      _FMEAInternalFunctionNet,
      _FailureNode,
      _FailureNet,
      _CauseNode,
      _CauseTaskNode,
      _EffectNode,
      //_FMEAType,

      _FMEAAuthorizationGroup,
      _FMEAStatus,
      _FMEATypeText,
      _FMEAConfidentialityLevelText,
      _FMEAAuthorizationGroupT,
      _FMEAStatusText,
      _FMEAObjectAggregate,
      _FMEATaskAggregate,
      _FMEAValuationProcedure,
      _FMEARatingProfile,
      _FMEARating,
      _FMEAConfidentialityLevel
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FAILUREMODEEFFECTANALYSIS",
"I_FMEADESCRIPTIONTP",
"I_FMEAHEADER",
"I_FMEATEXTTP",
"I_QLTYMGMTSYSTANDUSRTMEZN"
],
"ASSOCIATED":
[
"I_FMEAAUTHORIZATIONGROUP",
"I_FMEAAUTHORIZATIONGROUPT",
"I_FMEACAUSENODETP",
"I_FMEACAUSETASKTP",
"I_FMEACONFIDENTIALITYLEVEL",
"I_FMEACONFIDENTIALITYLEVELTEXT",
"I_FMEADESCRIPTIONTP",
"I_FMEAEFFECTNODETP",
"I_FMEAELEMENTNODETP",
"I_FMEAFAILURENET",
"I_FMEAFAILURENODETP",
"I_FMEAFUNCTIONNET",
"I_FMEAFUNCTIONNODETP",
"I_FMEAINTERNALFUNCTIONNET",
"I_FMEALONGTEXT",
"I_FMEANODEHIERARCHYTP",
"I_FMEANODETP",
"I_FMEAOBJECTAGGREGATE",
"I_FMEAOBJECTTP",
"I_FMEAPARTNERTP",
"I_FMEARATING",
"I_FMEARATINGPROFILE",
"I_FMEASTATUS",
"I_FMEASTATUSTEXT",
"I_FMEATASKAGGREGATE",
"I_FMEATEXT",
"I_FMEATEXTTP",
"I_FMEATYPETEXT",
"I_FMEAVALNPROCEDURECOMBINED",
"I_USERCONTACTCARD"
],
"BASE":
[
"I_FAILUREMODEEFFECTANALYSIS",
"I_FMEAHEADER"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/