I_FMEACauseTaskTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'FMEA Cause Task Node - TP'
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #M,
    serviceQuality: #C
}
define view entity I_FMEACauseTaskTP
  as select from            I_FMEANode
    left outer to many join I_FMEATask as FMEATask on I_FMEANode.FMEANodeUUID          = FMEATask.FMEAParentNodeUUID
                                                   or I_FMEANode.FMEANodeReferenceUUID = FMEATask.FMEAParentNodeUUID

  association        to parent I_FailureModeEffectAnalysisTP as _FailureModeEffectAnalysisTP on  $projection.FMEAHeaderUUID = _FailureModeEffectAnalysisTP.FMEAHeaderUUID
  association [1..1] to I_FMEATaskAssignment                 as _FMEATaskAssignment          on  FMEATask.FMEATaskUUID = _FMEATaskAssignment.FMEATaskUUID
  association [0..1] to I_FMEARating                         as _FMEARating                  on  $projection.fmearatingprofile = _FMEARating.FMEARatingProfile
                                                                                             and $projection.FMEARating        = _FMEARating.FMEARating
  association [0..1] to I_FMEAValuationProcedure             as _FMEAValuationProcedure      on  $projection.fmeavaluationprocedure = _FMEAValuationProcedure.FMEAValuationProcedure
  association [0..1] to I_FMEANode                           as _FMEAReferenceNode           on  $projection.FMEANodeReferenceUUID = _FMEAReferenceNode.FMEANodeUUID
  association [0..1] to I_FMEATaskTP                         as _FMEARelatedTask             on  $projection.FMEATaskUUID = _FMEARelatedTask.FMEATaskUUID
  association [0..1] to I_FMEANodeUsage                      as _FMEANodeUsage               on  $projection.FMEANodeUUID = _FMEANodeUsage.FMEANodeUUID
  association [0..1] to I_QltyMgmtSystAndUsrTmeZn            as _QltyMgmtSystAndUsrTmeZn     on  1 = 1

{
  key I_FMEANode.FMEANodeUUID,
  key FMEATask.FMEATaskUUID,
      cast ( I_FMEANode._FMEANodeAssignment.FMEANode as plmt_fmea_cause preserving type ) as FMEANode,
      I_FMEANode.FMEAHeaderUUID,
      I_FMEANode.FMEANodeType,
      I_FMEANode.FMEANodeListType,
      I_FMEANode.FMEAItemType,
      I_FMEANode.FMEANodeReferenceUUID,
      I_FMEANode.FMEANodeReferenceObjectType,
      I_FMEANode._FMEANodeParent.FMEAParentNodeUUID,
      I_FMEANode.FMEAValuationResultValue,
      I_FMEANode.FMEARating,
      I_FMEANode.InspectionCatalog,
      I_FMEANode.InspectionCodeGroup,
      I_FMEANode.InspectionCode,
      _FailureModeEffectAnalysisTP.FMEARatingProfile,
      _FailureModeEffectAnalysisTP.FMEAValuationProcedure,
      1                                                                                   as FMEARatingCriticality,
      //I_FMEANode.FMEAValuationResultValue,

      I_FMEANode.ChangedDateTime,

      cast( case
        when _FMEANodeUsage.FMEANodeNumberOfUsages is null then 1
        else _FMEANodeUsage.FMEANodeNumberOfUsages
      end as plmt_failuremode_count preserving type)                                      as FMEANodeNumberOfUsages,
      cast( case
      //1. Case: only simply cause below failure mode or element failure mode with reference to FMEA failure mode

      when I_FMEANode.FMEANodeReferenceObjectType is initial then ''
      //2. Case: element failure with reference

      else _FMEAReferenceNode._FMEAHeader.FMEAHeader
      end as plmt_fmea_cause_origin preserving type)                                      as FMEACauseElementFMEA,
      //provide text for Cause Origin - differentiate whether cause belongs to the same or sub FMEA

      cast( case
      when I_FMEANode.FMEANodeReferenceObjectType is initial
        then I_FMEANode._FMEANodeParent._FMEANode._FMEAHeaderText.FMEADescription
      else _FMEAReferenceNode._FMEAHeaderText.FMEADescription
      end as cgpl_text1 preserving type)                                                  as FMEACauseElementDescription,
      //Task fields

      FMEATask._FMEATaskAssignment.FMEATask,
      FMEATask.FMEAAuthorizationGroup,
      FMEATask.FMEATaskStatus,
      FMEATask._FMEATaskActionStatus.FMEATaskActionStatus,
      FMEATask.FMEATaskType,
      FMEATask.FMEATaskCompletionRate,
      FMEATask.FMEAValuationProfile,
      FMEATask.FMEAHasTargetValuation,
      FMEATask.FMEAValnPrflTargetValuation,
      FMEATask.FMEATargetValuationScoreValue,
      FMEATask.FMEATargetValnResultValue,
      FMEATask.FMEAValnProfileValuation,
      FMEATask.FMEAValuationScoreValue,
      //      FMEATask.FMEAValuationResultValue,

      FMEATask.FMEATaskGroup,
      FMEATask.FMEATaskConfirmationDateTime,
      FMEATask.QualityTaskCodeCatalog,
      FMEATask.QualityTaskCodeGroup,
      FMEATask.QualityTaskCode,
      @Semantics.booleanIndicator
      FMEATask.FMEATaskIsCancelled,
      @Semantics.booleanIndicator
      FMEATask.FMEATaskIsStartAction,
      FMEATask.ChangedDateTime                                                            as FMEATaskChangedDateTime,
      _FMEARelatedTask.FMEATaskLongText,
      _FMEARelatedTask.FMEATaskDescription,
      cast (tstmp_to_dats( _FMEATaskAssignment.FMEATaskPlannedStartDateTime ,
                           _QltyMgmtSystAndUsrTmeZn.QltyMgmtUserTimeZone,
                           $session.client,
                           'NULL' ) as plmt_planstartdate preserving type )               as FMEATaskPlannedStartDate,
      cast( tstmp_to_dats( _FMEARelatedTask.FMEATaskConfirmationDateTime,
                           _QltyMgmtSystAndUsrTmeZn.QltyMgmtUserTimeZone,
                           $session.client,
                           'NULL' ) as plmt_tv_confirm_date preserving type )             as FMEATaskConfirmationDate,
      cast( tstmp_to_dats( _FMEATaskAssignment.FMEATaskPlannedFinishDateTime,
                           _QltyMgmtSystAndUsrTmeZn.QltyMgmtUserTimeZone,
                           $session.client,
                           'NULL' ) as plmt_audit_date_final preserving type )            as FMEATaskPlannedFinishDate,

      _FMEARelatedTask.FMEATaskProcessor,
      _FMEARelatedTask.PersonFullName,
      _FMEARelatedTask.BusinessPartnerUUID,
      _FMEARelatedTask.FMEAPartnerUUID,

      //Associations

      _FailureModeEffectAnalysisTP,
      I_FMEANode._FailureModeEffectAnalysis,
      I_FMEANode._FMEANodeParent,
      I_FMEANode._FMEANodeChild,
      I_FMEANode._FMEATask,
      I_FMEANode._FMEANodeText,
      I_FMEANode._FMEANodeLongText,
      I_FMEANode._InspectionCodeGroup,
      I_FMEANode._InspectionCode,
      FMEATask._FMEATaskPartner,
      _FMEATaskAssignment,

      //

      _FMEARating,
      _FMEAValuationProcedure,
      _FMEAReferenceNode,
      _FMEARelatedTask,
      I_FMEANode._FMEAHeader,
      _FailureModeEffectAnalysisTP._FMEARatingProfile
}
where
  (
        I_FMEANode.FMEAItemType                = '804'
    and I_FMEANode.FMEANodeReferenceObjectType is initial
  )
  or(
        I_FMEANode.FMEAItemType                = '821'
    and _FMEANodeUsage.FMEANodeNumberOfUsages  is not null
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FAILUREMODEEFFECTANALYSISTP",
"I_FMEAHEADER",
"I_FMEANODE",
"I_FMEANODEASSIGNMENT",
"I_FMEANODEHIERARCHY",
"I_FMEANODEUSAGE",
"I_FMEATASK",
"I_FMEATASKASSIGNEDACTIONSTATUS",
"I_FMEATASKASSIGNMENT",
"I_FMEATASKTP",
"I_FMEATEXT",
"I_QLTYMGMTSYSTANDUSRTMEZN"
],
"ASSOCIATED":
[
"I_FAILUREMODEEFFECTANALYSIS",
"I_FAILUREMODEEFFECTANALYSISTP",
"I_FMEAHEADER",
"I_FMEALONGTEXT",
"I_FMEANODE",
"I_FMEANODEHIERARCHY",
"I_FMEANODETEXT",
"I_FMEARATING",
"I_FMEARATINGPROFILE",
"I_FMEATASK",
"I_FMEATASKASSIGNMENT",
"I_FMEATASKPARTNER",
"I_FMEATASKTP",
"I_FMEAVALUATIONPROCEDURE",
"I_INSPECTIONCODE",
"I_INSPECTIONCODEGROUP"
],
"BASE":
[
"I_FAILUREMODEEFFECTANALYSISTP",
"I_FMEANODE",
"I_FMEATASK"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/