I_FMEACauseNodeTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'FMEA Node - TP'
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #M,
    serviceQuality: #C
}
define view entity I_FMEACauseNodeTP
  as select from I_FMEANode

  association        to parent I_FailureModeEffectAnalysisTP as _FailureModeEffectAnalysisTP on  $projection.FMEAHeaderUUID = _FailureModeEffectAnalysisTP.FMEAHeaderUUID
  association [0..1] to I_FMEARating                         as _FMEARating                  on  $projection.fmearatingprofile = _FMEARating.FMEARatingProfile
                                                                                             and $projection.FMEARating        = _FMEARating.FMEARating
  association [0..1] to I_FMEAValuationProcedure             as _FMEAValuationProcedure      on  $projection.fmeavaluationprocedure = _FMEAValuationProcedure.FMEAValuationProcedure
  association [0..1] to I_FMEANode                           as _FMEAReferenceNode           on  $projection.FMEANodeReferenceUUID = _FMEAReferenceNode.FMEANodeUUID

  association [0..1] to I_FMEANodeUsage                      as _FMEANodeUsage               on  $projection.FMEANodeUUID = _FMEANodeUsage.FMEANodeUUID
  association [0..1] to I_QltyMgmtSystAndUsrTmeZn            as _QltyMgmtSystAndUsrTmeZn     on  1 = 1

{
  key I_FMEANode.FMEANodeUUID,
      I_FMEANode._FMEANodeAssignment.FMEANode,
      I_FMEANode.FMEAHeaderUUID,
      I_FMEANode.FMEANodeType,
      I_FMEANode.FMEANodeListType,
      I_FMEANode.FMEAItemType,
      I_FMEANode.FMEANodeReferenceUUID,
      I_FMEANode.FMEANodeReferenceObjectType,
      I_FMEANode._FMEANodeParent.FMEAParentNodeUUID,
      I_FMEANode.FMEARating,
      _FailureModeEffectAnalysisTP.FMEARatingProfile,
      _FailureModeEffectAnalysisTP.FMEAValuationProcedure,
      1 as FMEARatingCriticality,
      I_FMEANode.FMEAValuationResultValue,
      I_FMEANode.ChangedDateTime,
      
         //Associations

      _FailureModeEffectAnalysisTP,
      I_FMEANode._FailureModeEffectAnalysis,
      I_FMEANode._FMEANodeParent,
      I_FMEANode._FMEANodeChild,
      I_FMEANode._FMEATask,
      I_FMEANode._FMEANodeText,
      
      _FMEARating,
      _FMEAValuationProcedure,
      _FMEAReferenceNode,
      I_FMEANode._FMEAHeader,
      _FailureModeEffectAnalysisTP._FMEARatingProfile
}
where
  (
        I_FMEANode.FMEAItemType                = '804'
    and I_FMEANode.FMEANodeReferenceObjectType is initial
  )
  or(
        I_FMEANode.FMEAItemType                = '821'
    and _FMEANodeUsage.FMEANodeNumberOfUsages  is not null
  )
 
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_FAILUREMODEEFFECTANALYSISTP",
"I_FMEANODE",
"I_FMEANODEASSIGNMENT",
"I_FMEANODEHIERARCHY",
"I_FMEANODEUSAGE"
],
"ASSOCIATED":
[
"I_FAILUREMODEEFFECTANALYSIS",
"I_FAILUREMODEEFFECTANALYSISTP",
"I_FMEAHEADER",
"I_FMEANODE",
"I_FMEANODEHIERARCHY",
"I_FMEANODETEXT",
"I_FMEARATING",
"I_FMEARATINGPROFILE",
"I_FMEATASK",
"I_FMEAVALUATIONPROCEDURE"
],
"BASE":
[
"I_FAILUREMODEEFFECTANALYSISTP",
"I_FMEANODE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/