I_FMEATaskTP

@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'FMEA Task - TP'
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #M,
    serviceQuality: #C
}
define view entity I_FMEATaskTP
  as select from I_FMEATask
  composition [0..*] of I_FMEATaskPartnerTP         as _FMEATaskPartnerTP
  composition [0..*] of I_FMEATaskTextTP            as _FMEATaskTextTP
  composition [0..*] of I_FMEATaskDescriptionTextTP as _FMEATaskDescription
  association        to parent I_FMEANodeTP                as _FMEANodeTP                  on  $projection.FMEAParentNodeUUID = _FMEANodeTP.FMEANodeUUID
  association [0..1] to I_FMEACauseTaskTP           as _FMEACauseTaskTP                    on  $projection.FMEAParentNodeUUID = _FMEACauseTaskTP.FMEANodeUUID
                                                                                           and $projection.FMEATaskUUID       = _FMEACauseTaskTP.FMEATaskUUID
  association        to I_FailureModeEffectAnalysisTP      as _FailureModeEffectAnalysisTP on  $projection.fmeaheaderuuid = _FailureModeEffectAnalysisTP.FMEAHeaderUUID
  association [0..1] to I_FMEATaskText              as _FMEATaskText                       on  $projection.FMEATaskUUID = _FMEATaskText.FMEATaskUUID
                                                                                           and _FMEATaskText.Language   = $session.system_language
  association [0..1] to I_FMEALongText              as _FMEATaskLangDepdntDescription      on  $projection.FMEATaskUUID                              = _FMEATaskLangDepdntDescription.FMEANodeUUID
                                                                                           and _FMEATaskLangDepdntDescription.Language               = $session.system_language
                                                                                           and _FMEATaskLangDepdntDescription.LongTextInternalNumber = 1

  association [0..1] to I_FMEATaskPartner           as _Responsible                        on  $projection.FMEATaskUUID     = _Responsible.FMEATaskUUID
                                                                                           and _Responsible.FMEAPartnerRole = '60'

{
  key FMEATaskUUID,
      _FMEATaskAssignment.FMEATask,
      _ParentNodeAssignment.FMEAHeaderUUID,
      _ParentNodeAssignment.FMEANode,
      FMEAAuthorizationGroup,
      FMEATaskStatus,
      _FMEATaskActionStatus.FMEATaskActionStatus,
      FMEATaskType,
      FMEAParentNodeUUID,
      FMEATaskCompletionRate,
      FMEAValuationProfile,
      FMEAHasTargetValuation,
      FMEAValnPrflTargetValuation,
      FMEATargetValuationScoreValue,
      FMEATargetValnResultValue,
      FMEAValnProfileValuation,
      FMEAValuationScoreValue,
      FMEAValuationResultValue,
      FMEATaskGroup,
      FMEATaskConfirmationDateTime,
      QualityTaskCodeCatalog,
      QualityTaskCodeGroup,
      QualityTaskCode,
      FMEATaskIsCancelled,
      FMEATaskIsStartAction,
      ChangedDateTime,
      _FMEATaskText.FMEATaskDescription,
      _FMEATaskAssignment.FMEATaskPlannedStartDateTime,
      _FMEATaskAssignment.FMEATaskPlannedFinishDateTime,
      _FMEATaskAssignment.FMEATaskActualFinishDateTime,
      cast( _FMEATaskAssignment.CreatedByUser as cgpl_created_by preserving type )     as CreatedByUser,
      _FMEATaskAssignment.CreationDate,
      cast( _FMEATaskAssignment.LastChangedByUser as cgpl_changed_by preserving type ) as LastChangedByUser,
      _FMEATaskAssignment.LastChangedDate,
      _FMEATaskLangDepdntDescription.FMEALongText                                      as FMEATaskLongText,
      _Responsible._Employee.BusinessPartner                                           as FMEATaskProcessor,
      _Responsible._Employee.PersonFullName,
      _Responsible.BusinessPartnerUUID,
      _Responsible.FMEAPartnerUUID,


      //Associations

      _FMEANodeTP,
      _FMEACauseTaskTP,
      _FailureModeEffectAnalysisTP,
      _FMEATaskPartnerTP,
      _FMEATaskTextTP,
      _FMEATaskHierarchy,
      _FMEAAuthorizationGroup,
      _FMEAValuationProfile,
      _FMEAValnProfileValuation,
      _FMEAValnProfileTargetValn,
      _FMEATaskStatus,
      _FMEATaskActionStatus,
      _ConfigurableCodesCodeGroup,
      _ConfigurableCodesCode,
      _FMEATaskDescription,
      _FMEATaskPartner,
      _BusinessPartner,
      _FMEATaskType,
      _Responsible
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSUSER",
"I_FMEALONGTEXT",
"I_FMEANODEASSIGNMENT",
"I_FMEATASK",
"I_FMEATASKASSIGNEDACTIONSTATUS",
"I_FMEATASKASSIGNMENT",
"I_FMEATASKPARTNER",
"I_FMEATASKTEXT"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CONFIGURABLECODESCODE",
"I_CONFIGURABLECODESCODEGROUP",
"I_FAILUREMODEEFFECTANALYSISTP",
"I_FMEAAUTHORIZATIONGROUP",
"I_FMEACAUSETASKTP",
"I_FMEANODETP",
"I_FMEASTATUS",
"I_FMEATASKASSIGNEDACTIONSTATUS",
"I_FMEATASKDESCRIPTIONTEXTTP",
"I_FMEATASKHIERARCHY",
"I_FMEATASKPARTNER",
"I_FMEATASKPARTNERTP",
"I_FMEATASKTEXTTP",
"I_FMEATASKTYPE",
"I_FMEAVALNPROFILEVALUATION",
"I_FMEAVALUATIONPROFILE"
],
"BASE":
[
"I_FMEATASK"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/