I_FMEATask

@AbapCatalog.sqlViewName: 'IFMEATSK'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Task of a FMEA'
@AccessControl.privilegedAssociations:  [ '_FMEATaskLongText' ]
@ObjectModel.representativeKey: 'FMEATaskUUID'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #TRANSACTIONAL }
define view I_FMEATask
  as select from           plmm_audit_act
    left outer to one join cgpl_hierarchy on plmm_audit_act.guid = cgpl_hierarchy.guid

  association [0..*] to I_FMEATaskPartner              as _FMEATaskPartner           on  $projection.FMEATaskUUID = _FMEATaskPartner.FMEATaskUUID
  association [0..*] to I_BusinessPartner              as _BusinessPartner           on  $projection.FMEATaskUUID = _BusinessPartner.BusinessPartnerUUID
  association [0..1] to I_FMEAAuthorizationGroup       as _FMEAAuthorizationGroup    on  $projection.FMEAAuthorizationGroup = _FMEAAuthorizationGroup.FMEAAuthorizationGroup
  association [0..1] to I_FMEAValuationProfile         as _FMEAValuationProfile      on  $projection.FMEAValuationProfile = _FMEAValuationProfile.FMEAValuationProfile
  association [0..1] to I_FMEAValnProfileValuation     as _FMEAValnProfileValuation  on  $projection.FMEAValuationProfile     = _FMEAValnProfileValuation.FMEAValuationProfile
                                                                                     and $projection.FMEAValnProfileValuation = _FMEAValnProfileValuation.FMEAValnProfileValuation
  association [0..1] to I_FMEAValnProfileValuation     as _FMEAValnProfileTargetValn on  $projection.FMEAValuationProfile        = _FMEAValnProfileTargetValn.FMEAValuationProfile
                                                                                     and $projection.FMEAValnPrflTargetValuation = _FMEAValnProfileTargetValn.FMEAValnProfileValuation
  association [0..1] to I_ConfigurableCodesCodeGroup   as _ConfigurableCodesCodeGroup on  $projection.QualityTaskCodeGroup = _ConfigurableCodesCodeGroup.ConfigurableCodesCodeGroup
                                                                                     and $projection.QualityTaskCodeCatalog = _ConfigurableCodesCodeGroup.ConfigurableCodesCatalog
  association [0..1] to I_ConfigurableCodesCode        as _ConfigurableCodesCode      on  $projection.QualityTaskCode      = _ConfigurableCodesCode.ConfigurableCodesCode
                                                                                     and $projection.QualityTaskCodeGroup = _ConfigurableCodesCode.ConfigurableCodesCodeGroup
                                                                                     and $projection.QualityTaskCodeCatalog = _ConfigurableCodesCode.ConfigurableCodesCatalog
  association [0..1] to I_FMEATaskHierarchy            as _FMEATaskHierarchy         on  $projection.FMEATaskUUID = _FMEATaskHierarchy.FMEATaskUUID
  association [1..1] to I_FMEATaskAssignment           as _FMEATaskAssignment        on  $projection.FMEATaskUUID = _FMEATaskAssignment.FMEATaskUUID
  association [0..1] to I_FMEANodeAssignment           as _ParentNodeAssignment      on  $projection.FMEAParentNodeUUID = _ParentNodeAssignment.FMEANodeUUID

  //for better description I_FMEAStatus might be replaced

  association [0..1] to I_FMEAStatus                   as _FMEATaskStatus            on  $projection.FMEATaskStatus = _FMEATaskStatus.FMEAStatus
  association [0..1] to I_FMEATaskType                 as _FMEATaskType              on  $projection.FMEATaskType = _FMEATaskType.FMEATaskType
  association [0..*] to I_FMEATaskText                 as _FMEATaskText              on  $projection.FMEATaskUUID = _FMEATaskText.FMEATaskUUID
  association [0..*] to I_FMEALongText                 as _FMEATaskLongText          on  $projection.FMEATaskUUID = _FMEATaskLongText.FMEANodeUUID
  association [0..1] to I_FMEATaskAssignedActionStatus as _FMEATaskActionStatus      on  $projection.FMEATaskUUID = _FMEATaskActionStatus.FMEATaskUUID
  //Extension

  association [1..1] to E_FMEATask                     as _Extension                 on  $projection.FMEATaskUUID = _Extension.FMEATaskUUID

{
  key cast( plmm_audit_act.guid as plmt_fmea_node_guid preserving type )   as FMEATaskUUID,
      cast( cgpl_hierarchy.up as plmt_fmea_node_guid preserving type )     as FMEAParentNodeUUID,
      plmm_audit_act.auth_group                                            as FMEAAuthorizationGroup,
      plmm_audit_act.proc_status                                           as FMEATaskStatus,
      cast( plmm_audit_act.acttyp as plmt_fmea_task_type preserving type ) as FMEATaskType,
      plmm_audit_act.complete_percent                                      as FMEATaskCompletionRate,
      plmm_audit_act.assessm_profil                                        as FMEAValuationProfile,
      plmm_audit_act.assessment_rec                                        as FMEAHasTargetValuation,
      plmm_audit_act.assessm_res                                           as FMEAValnPrflTargetValuation,
      plmm_audit_act.score_rec                                             as FMEATargetValuationScoreValue,
      plmm_audit_act.score_res                                             as FMEATargetValnResultValue,
      plmm_audit_act.assessm_res_old                                       as FMEAValnProfileValuation,
      plmm_audit_act.score_rec_old                                         as FMEAValuationScoreValue,
      plmm_audit_act.score_res_old                                         as FMEAValuationResultValue,
      plmm_audit_act.confirmation                                          as FMEATaskConfirmationDateTime,
      plmm_audit_act.makat                                                 as QualityTaskCodeCatalog,
      plmm_audit_act.gruppe                                                as QualityTaskCodeGroup,
      plmm_audit_act.code                                                  as QualityTaskCode,
      plmm_audit_act.act_cancel                                            as FMEATaskIsCancelled,
      plmm_audit_act.start_action                                          as FMEATaskIsStartAction,
      plmm_audit_act.changeddatetime                                       as ChangedDateTime,
      plmm_audit_act.grouping                                              as FMEATaskGroup,

      //Associations

      _FMEATaskPartner,
      _FMEAAuthorizationGroup,
      _FMEAValuationProfile,
      _FMEAValnProfileValuation,
      _FMEAValnProfileTargetValn,
      _FMEATaskStatus,
      _FMEATaskActionStatus,
      _FMEATaskHierarchy,
      _ParentNodeAssignment,
      _FMEATaskAssignment,
      // _FMEATaskActnStsCalc,

      _ConfigurableCodesCodeGroup,
      _ConfigurableCodesCode,
      _BusinessPartner,
      _FMEATaskType,
      _FMEATaskText,
      _FMEATaskLongText
}
where
     plmm_audit_act.acttyp = '800'
  or plmm_audit_act.acttyp = '801'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"CGPL_HIERARCHY",
"PLMM_AUDIT_ACT"
],
"ASSOCIATED":
[
"E_FMEATASK",
"I_BUSINESSPARTNER",
"I_CONFIGURABLECODESCODE",
"I_CONFIGURABLECODESCODEGROUP",
"I_FMEAAUTHORIZATIONGROUP",
"I_FMEALONGTEXT",
"I_FMEANODEASSIGNMENT",
"I_FMEASTATUS",
"I_FMEATASKASSIGNEDACTIONSTATUS",
"I_FMEATASKASSIGNMENT",
"I_FMEATASKHIERARCHY",
"I_FMEATASKPARTNER",
"I_FMEATASKTEXT",
"I_FMEATASKTYPE",
"I_FMEAVALNPROFILEVALUATION",
"I_FMEAVALUATIONPROFILE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/