I_FMEANODE

@AbapCatalog.sqlViewName: 'IFMEANODE'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Function or other node of FMEA'
@AccessControl.privilegedAssociations:  [ '_FMEANodeLongText' ]
@ObjectModel.representativeKey: 'FMEANodeUUID'
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #TRANSACTIONAL }
define view I_FMEANode
  as select from plmm_quest_res
  association [1..1] to I_FMEANodeAssignment        as _FMEANodeAssignment        on  $projection.FMEANodeUUID = _FMEANodeAssignment.FMEANodeUUID

  association [0..1] to I_FailureModeEffectAnalysis as _FailureModeEffectAnalysis on  $projection.FMEAHeaderUUID = _FailureModeEffectAnalysis.FMEAHeaderUUID
  association [1..1] to I_FMEAHeader                as _FMEAHeader                on  $projection.FMEAHeaderUUID = _FMEAHeader.FMEAHeaderUUID
  association [0..1] to I_FMEANodeHierarchy         as _FMEANodeParent            on  $projection.FMEANodeUUID = _FMEANodeParent.FMEANodeUUID
  association [0..*] to I_FMEANodeHierarchy         as _FMEANodeChild             on  $projection.FMEANodeUUID = _FMEANodeChild.FMEAParentNodeUUID
  association [0..1] to I_FMEAValuationProfile      as _FMEAValuationProfile      on  $projection.FMEAValuationProfile = _FMEAValuationProfile.FMEAValuationProfile
  association [0..1] to I_InspectionCodeGroup       as _InspectionCodeGroup       on  $projection.InspectionCatalog   = _InspectionCodeGroup.InspectionCatalog
                                                                                  and $projection.InspectionCodeGroup = _InspectionCodeGroup.InspectionCodeGroup
  association [0..1] to I_InspectionCode            as _InspectionCode            on  $projection.InspectionCatalog   = _InspectionCode.InspectionCatalog
                                                                                  and $projection.InspectionCodeGroup = _InspectionCode.InspectionCodeGroup
                                                                                  and $projection.InspectionCode      = _InspectionCode.InspectionCode
  association [0..*] to I_FMEATask                  as _FMEATask                  on  $projection.FMEANodeUUID = _FMEATask.FMEAParentNodeUUID
  association [0..*] to I_FMEANodeText              as _FMEANodeText              on  $projection.FMEANodeUUID = _FMEANodeText.FMEANodeUUID
  //Reference to node of other FMEA

  association [1..1] to I_FMEANodeAssignment        as _FMEAReferenceAssignment   on  $projection.FMEANodeReferenceUUID = _FMEAReferenceAssignment.FMEANodeUUID
  association [0..1] to I_FMEANode                  as _FMEAReferenceNode         on  $projection.FMEANodeReferenceUUID = _FMEAReferenceNode.FMEANodeUUID
  //Reference to other FMEA

  association [1..1] to I_FMEAHeader                as _FMEAReference             on  $projection.FMEANodeReferenceUUID = _FMEAReference.FMEAHeaderUUID
  association [0..1] to I_FMEAValuationProcedure    as _FMEAValuationProcedure    on  $projection.FMEAValuationProcedure = _FMEAValuationProcedure.FMEAValuationProcedure
  association [0..*] to I_FMEALongText              as _FMEANodeLongText          on  $projection.FMEANodeUUID = _FMEANodeLongText.FMEANodeUUID
                                                                                  and _FMEANodeLongText.LongTextInternalNumber = 1
  association [0..1] to I_FMEAText              as _FMEAHeaderText            on $projection.FMEAHeaderUUID = _FMEAHeaderText.FMEAHeaderUUID 
                                                                                  and _FMEAHeaderText.Language = $session.system_language
                                                                                  
  //Extension

  association [1..1] to E_FMEANode                  as _Extension                 on  $projection.FMEANodeUUID = _Extension.FMEANodeUUID

{
  key cast( plmm_quest_res.guid as plmt_fmea_node_guid preserving type )         as FMEANodeUUID,
      cast( plmm_quest_res.project_guid as plmt_fmea_node_guid preserving type ) as FMEAHeaderUUID,
      plmm_quest_res.hierarchy_profil                                            as FMEAHierarchyProfile,
      plmm_quest_res.hierarchy_level                                             as FMEAHierarchyProfileLevel,
      plmm_quest_res.node_type                                                   as FMEANodeType,
      plmm_quest_res.listtyp                                                     as FMEANodeListType,
      plmm_quest_res.listityp                                                    as FMEAItemType,
      cast( reference as plmt_fmea_node_guid preserving type )                   as FMEANodeReferenceUUID,
      reference_obtyp                                                            as FMEANodeReferenceObjectType,
      plmm_quest_res.assessm_profil                                              as FMEAValuationProfile,
      plmm_quest_res.assessment_rec                                              as FMEAHasValuation,
      plmm_quest_res.assessment_res                                              as FMEAValnProfileValuation,
      plmm_quest_res.score_rec                                                   as FMEAValuationScoreValue,
      plmm_quest_res.score_res                                                   as FMEAValuationResultValue,
      plmm_quest_res.katalgart                                                   as InspectionCatalog,
      plmm_quest_res.gruppe                                                      as InspectionCodeGroup,
      plmm_quest_res.code                                                        as InspectionCode,
      plmm_quest_res.fekat                                                       as DefectCodeCatalog,
      plmm_quest_res.urkat                                                       as DefectCauseCodeCatalog,
      plmm_quest_res.functioncat                                                 as FMEAFunctionCodeCatalog,
      plmm_quest_res.effectcat                                                   as FMEAEffectCodeCatalog,
      plmm_quest_res.makat                                                       as QualityTaskCodeCatalog,
      plmm_quest_res.verwmerkm                                                   as InspectionSpecification,
      plmm_quest_res.qpmk_werks                                                  as InspectionSpecificationPlant,
      plmm_quest_res.merkgew                                                     as InspSpecImportanceCode,
      plmm_quest_res.char_type                                                   as FMEACharacteristicType,
      plmm_quest_res.changeddatetime                                             as ChangedDateTime,
      plmm_quest_res.audit_calculate                                             as FMEAValuationProcedure,
      plmm_quest_res.classification_code                                         as FMEARating,

      //Associations

      _FailureModeEffectAnalysis,
      _FMEAHeader,
      _FMEANodeAssignment,
      _FMEANodeParent,
      _FMEANodeChild,
      _FMEATask,
      _FMEAValuationProfile,
      _FMEANodeText,
      _FMEAReferenceAssignment,
      _FMEAReferenceNode,
      _FMEAReference,
      _InspectionCodeGroup,
      _InspectionCode,
      _FMEAValuationProcedure,
      _FMEANodeLongText,
      _FMEAHeaderText
}
where
  (
       plmm_quest_res.listtyp = '010'
    or plmm_quest_res.listtyp = '011'
    or plmm_quest_res.listtyp = '012'
  )
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"PLMM_QUEST_RES"
],
"ASSOCIATED":
[
"E_FMEANODE",
"I_FAILUREMODEEFFECTANALYSIS",
"I_FMEAHEADER",
"I_FMEALONGTEXT",
"I_FMEANODEASSIGNMENT",
"I_FMEANODEHIERARCHY",
"I_FMEANODETEXT",
"I_FMEATASK",
"I_FMEATEXT",
"I_FMEAVALUATIONPROCEDURE",
"I_FMEAVALUATIONPROFILE",
"I_INSPECTIONCODE",
"I_INSPECTIONCODEGROUP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/