I_EquipmentText

@EndUserText.label: 'Equipment - Text'
@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #BASIC
@AbapCatalog: { sqlViewName: 'IEQUIPMENTTEXT', compiler.compareFilter, preserveKey }
@AccessControl.authorizationCheck:#CHECK
@ObjectModel.representativeKey: 'Equipment'
@Search.searchable: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET, #EXTRACTION_DATA_SOURCE]
@Analytics: {
    dataExtraction: { 
        enabled: true,
        delta.changeDataCapture: {
              automatic: true
        }
    }
}

define view I_EquipmentText
  as select from eqkt // EQKT = Equipment Short Texts

  association [0..1] to I_Equipment as _Equipment on _Equipment.Equipment = $projection.Equipment
  association [0..1] to I_Language  as _Language  on _Language.Language = $projection.Language
  -- Extensions, do not expose as association:
  association [0..1] to E_Equipment as _EquipmentExtension on _EquipmentExtension.Equipment = $projection.Equipment
{
      @ObjectModel.foreignKey.association: '_Equipment'
  key eqkt.equnr as Equipment,

      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key eqkt.spras as Language,
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}  // Optimize Type ahead for value helps - 2302

      @Semantics.text: true
      @EndUserText.label: 'Description'
      eqkt.eqktx as EquipmentName,

      eqkt.txasp as IsPrimaryLanguage,

      eqkt.kzltx as EquipmentHasLongText,
      
      @Semantics.systemDateTime.lastChangedAt: true
      eqkt.textchangeddatetime as LastChangeDateTime,
      
      @Semantics.businessDate.from: true
      _Equipment.CreationDate as ValidityStartDate,
      
      @Semantics.businessDate.to: true
       cast( '99991231' as datbi ) as ValidityEndDate,
    

      // Propagate association

      _Equipment,
      _Language
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EQUIPMENT",
"EQKT"
],
"ASSOCIATED":
[
"E_EQUIPMENT",
"I_EQUIPMENT",
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/