C_TechnicalObjectForEditVH

@EndUserText.label: 'Technical Object Value Help For Edit'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CTECHOBJEDITVH'
@AccessControl.authorizationCheck: #CHECK

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@AbapCatalog.viewEnhancementCategory: [#UNION,#PROJECTION_LIST] //n3393459


@ObjectModel.representativeKey: 'TechnicalObjectLabel'
@Consumption.ranked:true
@Search.searchable: true

define view C_TechnicalObjectForEditVH
    as select from         I_EquipmentTimeSeg           as _EquipmentTimeSeg
    left outer to one join I_Equipment                                                 on I_Equipment.Equipment = _EquipmentTimeSeg.Equipment
    left outer to one join I_LocationAccountAssignment  as _LocationAccountAssignment  on _LocationAccountAssignment.MaintObjectLocAcctAssgmtNmbr = _EquipmentTimeSeg.MaintObjectLocAcctAssgmtNmbr

{
      @UI.hidden: true
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
  key cast ( _EquipmentTimeSeg.Equipment as eams_tec_obj )                                                           as TechnicalObject,

      @Environment.sql.passValue: true
      @UI.hidden: true
  key cast ( 'EAMS_EQUI' as eams_tec_obj_type_value)                                                                 as TechObjIsEquipOrFuncnlLoc,

      @ObjectModel.text.element: 'TechnicalObjectDescription'
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
  key cast ( _EquipmentTimeSeg.Equipment as eams_tech_obj_conv )                                                     as TechnicalObjectLabel,

      @Consumption.hidden: true
      _EquipmentTimeSeg.Equipment                                                                                    as EquipmentWithLeadingZeros,

      @UI.hidden: true
      cast ('' as ilom_strno)                                                                                        as FunctionalLocationLabelName,

      @Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
      cast( _EquipmentText[1: Language = $session.system_language].EquipmentName
            as eams_tec_obj_des preserving type )                                                                    as TechnicalObjectDescription,

      -- DCL:
      @Consumption.hidden: true
      _EquipmentTimeSeg.MaintenancePlanningPlant,
      @Consumption.hidden: true
      _EquipmentTimeSeg.MaintenancePlannerGroup,
      @Consumption.hidden: true
      I_Equipment.AuthorizationGroup,
      @Consumption.hidden: true
      cast( I_Equipment.EquipmentCategory as eams_tec_obj_cat )                                                      as TechnicalObjectCategory,
      @Consumption.hidden: true
      I_Equipment.TechnicalObjectType,
      @Consumption.hidden: true
      _EquipmentTimeSeg.MaintObjectLocAcctAssgmtNmbr,
      @Consumption.hidden: true
      _LocationAccountAssignment.MaintenancePlant,
      @Consumption.hidden: true
      _LocationAccountAssignment.CostCenter,
      @Consumption.hidden: true
      _LocationAccountAssignment.ControllingArea

}
where
      _EquipmentTimeSeg.ValidityEndDate                = '99991231'
  and _EquipmentTimeSeg.EquipUsagePeriodSequenceNumber = '001' -- HasEquipmentData = 'X'
  and _EquipmentTimeSeg.MaintenancePlanningPlant <> ''

union all
      select from I_FunctionalLocation
{
      @UI.hidden: true
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
  key cast ( I_FunctionalLocation.FunctionalLocation as eams_tec_obj )                                                as TechnicalObject,

      @UI.hidden: true
  key cast ( 'EAMS_FL' as eams_tec_obj_type_value)                                                                    as TechObjIsEquipOrFuncnlLoc,

      @ObjectModel.text.element: 'TechnicalObjectDescription'
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
  key cast(_FunctionalLocationLabel._FuncLocationLabelSearch.FunctionalLocationLabelName as eams_tech_obj_conv)       as TechnicalObjectLabel,

      @Consumption.hidden: true
      cast ('' as equnr)                                                                                              as EquipmentWithLeadingZeros,

      @UI.hidden: true
      _FunctionalLocationLabel._FuncLocationLabelSearch.FunctionalLocationLabelName                                   as FunctionalLocationLabelName,

      @Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
      cast( _FunctionalLocationText[1: Language = $session.system_language].FunctionalLocationName
            as eams_tec_obj_des preserving type )                                                                     as TechnicalObjectDescription,

      --DCL:
      @Consumption.hidden: true
      I_FunctionalLocation.MaintenancePlanningPlant,
      @Consumption.hidden: true
      I_FunctionalLocation.MaintenancePlannerGroup,
      @Consumption.hidden: true
      I_FunctionalLocation.AuthorizationGroup,
      @Consumption.hidden: true
      cast( I_FunctionalLocation.FunctionalLocationCategory as eams_tec_obj_cat )                                      as TechnicalObjectCategory,
      @Consumption.hidden: true
      I_FunctionalLocation.TechnicalObjectType,
      @Consumption.hidden: true
      I_FunctionalLocation.MaintObjectLocAcctAssgmtNmbr,
       @Consumption.hidden: true
      _LocationAccountAssignment.MaintenancePlant,
      @Consumption.hidden: true
      _LocationAccountAssignment.CostCenter,
      @Consumption.hidden: true
      _LocationAccountAssignment.ControllingArea

}
where I_FunctionalLocation.MaintenancePlanningPlant <> ''









/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_EQUIPMENT",
"I_EQUIPMENTTEXT",
"I_EQUIPMENTTIMESEG",
"I_FUNCLOCATIONLABELSEARCH",
"I_FUNCTIONALLOCATION",
"I_FUNCTIONALLOCATIONLABEL",
"I_FUNCTIONALLOCATIONTEXT",
"I_LOCATIONACCOUNTASSIGNMENT"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/