I_EngmntProjectRoleAssgmt

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog: {
    sqlViewName: 'IENGPRJROLASSGMT',
    compiler.compareFilter: true,
    preserveKey: true
}
@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #BLOCKED_DATA_EXCLUDED,
    personalData.blockingIndicator: 'IsBusinessPurposeCompleted'
}
@ObjectModel: {
    representativeKey: 'EngagementProjectTeamRole',
    usageType.serviceQuality: #D,
    usageType.sizeCategory: #XL,
    usageType.dataClass: #MIXED,
    modelingPattern: #ANALYTICAL_DIMENSION,
    supportedCapabilities: [#ANALYTICAL_DIMENSION,
                            #CDS_MODELING_ASSOCIATION_TARGET,
                            #CDS_MODELING_DATA_SOURCE,
                            #SQL_DATA_SOURCE]
}
@EndUserText.label: 'Role Assignment in Engagement Project'

@Analytics: {
  dataExtraction.enabled: true,
  dataCategory: #DIMENSION,
  internalName: #LOCAL
}

@VDM: {
    viewType: #COMPOSITE,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}

@Metadata: {
ignorePropagatedAnnotations: true,
allowExtensions:true
}

define view I_EngmntProjectRoleAssgmt
  as select from P_EngmntProjectRoleAssgmt as B
    inner join   P_WFPersonIdentification  as C on B.BusinessPartner = C.BusinessPartner
  association [0..1] to I_BusinessUserBasic         as _BusinessUserBasic on  $projection.BusinessPartner = _BusinessUserBasic.BusinessPartner
  // ***** I_BusinessUser is deprecated, It's successor view is I_BusinessUserBasic

  association [0..1] to I_BusinessUser              as _BusinessUser      on  $projection.BusinessPartner = _BusinessUser.BusinessPartner
  // ***** I_BusinessPartner has DCL check for blocked employee. Do not remove this association.

  association [0..1] to I_BusinessPartner           as _BusinessPartner   on  $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_WorkplaceAddress          as _WorkplaceAddress  on  $projection.BusinessPartnerUUID = _WorkplaceAddress.BusinessPartnerUUID
  association [0..1] to I_WorkforcePersonImageURL   as _Image             on  _Image.Person = B.BusinessPartner
  association [0..1] to I_EnterpriseProjectRoleType as _ProjectRole       on  $projection.EngagementProjectTeamRole = _ProjectRole.ProjectRoleType
  association [1]    to I_EngagementProject         as _EngagementProject on  $projection.EngagementProject = _EngagementProject.EngagementProject
  association [0..1] to I_PPM_ProjectRoleTypeText   as _ProjectRoleText   on  _ProjectRoleText.LanguageCode    = $session.system_language
                                                                          and _ProjectRoleText.ProjectRoleType = $projection.EngagementProjectTeamRole
  association [1..1] to I_EngmntProjWithUserInvlmnt as _UserInvlmnt       on  $projection.EngagementProjectUUID = _UserInvlmnt.ProjectUUID
{

      @ObjectModel.foreignKey.association: '_EngagementProject'
      @EndUserText.label: 'Engagement Project ID'
  key B.EngagementProject,

      @EndUserText.label: 'Project Role'
  key B.EngagementProjectTeamRole,

      @EndUserText.label: 'Created On'
      B.CreationDateTime,

      @ObjectModel.foreignKey.association: '_BusinessPartner'
      @EndUserText.label: 'Business Partner ID'
      B.BusinessPartner,

      @EndUserText.label: 'Project Role Name'
      @Semantics.name.jobTitle: true
      _ProjectRoleText.ObjectName,

      @Consumption.hidden: true
      B.EngagementProjectUUID,

      @Consumption.hidden: true
      B.EngagementProjectTeamRoleUUID,

      @Consumption.hidden: true
      B.EngmtProjTeamMemberUUID,

      @Consumption.hidden: true
      B.EngagementProjectMemberUUID,

      @Consumption.hidden: true
      B.BusinessPartnerUUID,

      @EndUserText.label: 'Business Partner Name'
      B.BusinessPartnerFullName,

      @EndUserText.label: 'Business Partner Type'
      B.BusinessPartnerType,

      @EndUserText.label: 'Business User'
      _BusinessUserBasic.UserID as BusinessUser,

      @EndUserText.label: 'User name'
      C.BPIdentificationNumber  as PersonExternalID,
      
      _BusinessUserBasic,

      @API.element: {
             successor: '_BusinessUserBasic',
             releaseState: #DEPRECATED
      }
      @VDM.lifecycle: {
             successor: '_BusinessUserBasic',
             status: #DEPRECATED
      }
      _BusinessUser,
      _Image,
      _ProjectRole,
      _ProjectRoleText,
      _EngagementProject,
      _WorkplaceAddress,
      _BusinessPartner,
      @Consumption.hidden: true
      _UserInvlmnt

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BUSINESSUSERBASIC",
"I_PPM_PROJECTROLETYPETEXT",
"P_ENGMNTPROJECTROLEASSGMT",
"P_WFPERSONIDENTIFICATION"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_BUSINESSUSER",
"I_BUSINESSUSERBASIC",
"I_ENGAGEMENTPROJECT",
"I_ENGMNTPROJWITHUSERINVLMNT",
"I_ENTERPRISEPROJECTROLETYPE",
"I_PPM_PROJECTROLETYPETEXT",
"I_WORKFORCEPERSONIMAGEURL",
"I_WORKPLACEADDRESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/