I_EnterpriseProjectRoleType

DDL: I_ENTERPRISEPROJECTROLETYPE Type: view BASIC

Role Type for Enterprise Projects

I_EnterpriseProjectRoleType is a Basic CDS View (Dimension) that provides data about "Role Type for Enterprise Projects" in SAP S/4HANA. It reads from 1 data source (dpr_part_role) and exposes 6 fields with key field ProjectRoleType. It has 3 associations to related views.

1 data source(s) 6 fields

Data Sources (1)

SourceAliasJoin Type
dpr_part_role dpr_part_role from

Associations (3)

CardinalityTargetAliasCondition
[1..1] I_EntProjectRoleCategory _ProjectRoleTypeCategory $projection.ProjectRoleCategory = _ProjectRoleTypeCategory.ProjectRoleCategory
[1..1] I_PartnerFunction _PartnerFunction $projection.PartnerFunction = _PartnerFunction.PartnerFunction
[0..*] I_EntProjectRoleTypeText _Text

Annotations (19)

NameValueLevelField
EndUserText.label Role Type for Enterprise Projects view
AccessControl.authorizationCheck #PRIVILEGED_ONLY view
Analytics.dataCategory #DIMENSION view
Analytics.internalName #LOCAL view
ClientHandling.algorithm #SESSION_VARIABLE view
AbapCatalog.sqlViewName IENTPROJROLETYPE view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AbapCatalog.dataMaintenance #RESTRICTED view
Metadata.ignorePropagatedAnnotations true view
Metadata.allowExtensions true view
ObjectModel.compositionRoot true view
ObjectModel.representativeKey ProjectRoleType view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.sizeCategory #S view
Search.searchable true view
VDM.lifecycle.contract.type #PUBLIC_LOCAL_API view
VDM.viewType #BASIC view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY ProjectRoleType participant_role
ProjectRoleCategory role_category
PartnerFunction
_Text _Text
_ProjectRoleTypeCategory _ProjectRoleTypeCategory
_PartnerFunction _PartnerFunction 
@EndUserText.label: 'Role Type for Enterprise Projects'

@AccessControl: {
    authorizationCheck:     #PRIVILEGED_ONLY
}

@Analytics.dataCategory: #DIMENSION
//@Analytics.dataExtraction.enabled: true

@Analytics.internalName: #LOCAL

@ClientHandling.algorithm: #SESSION_VARIABLE

@AbapCatalog: { 
    sqlViewName: 'IENTPROJROLETYPE',
    compiler.compareFilter: true,
    preserveKey:true,
    dataMaintenance: #RESTRICTED  
}

@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions:true

@ObjectModel: {
    compositionRoot: true,
    representativeKey: 'ProjectRoleType',
    supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ],
    usageType: {
     serviceQuality:  #A,
     dataClass:       #CUSTOMIZING,
     sizeCategory:    #S
    }
//  ,sapObjectNodeType.name: 'EnterpriseProjectRoleType' DCL0

}

@Search.searchable: true

@VDM.lifecycle.contract.type:  #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC

define root view I_EnterpriseProjectRoleType as select from dpr_part_role
  composition [0..*] of I_EntProjectRoleTypeText       as _Text
  
  association [1..1] to I_EntProjectRoleCategory       as _ProjectRoleTypeCategory        on $projection.ProjectRoleCategory = _ProjectRoleTypeCategory.ProjectRoleCategory
  association [1..1] to I_PartnerFunction              as _PartnerFunction                on $projection.PartnerFunction     = _PartnerFunction.PartnerFunction
  
{
  @Search.defaultSearchElement: true
  @Search.ranking: #HIGH
  @ObjectModel.text.association: '_Text'
  key participant_role  as ProjectRoleType,
  @ObjectModel.foreignKey.association: '_ProjectRoleTypeCategory'
  role_category         as ProjectRoleCategory,
  @ObjectModel.foreignKey.association: '_PartnerFunction'
  cast ( dpr_part_role.partner_function as /s4ppm/tv_partner_function preserving type ) as PartnerFunction,

  @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
  _Text,
  
  _ProjectRoleTypeCategory,
  _PartnerFunction
}

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"DPR_PART_ROLE"
],
"ASSOCIATED":
[
"I_ENTPROJECTROLECATEGORY",
"I_ENTPROJECTROLETYPETEXT",
"I_PARTNERFUNCTION"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More