I_BusinessUser

@AbapCatalog.sqlViewName: 'IBUSINESSUSER'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Business User'
@VDM.viewType: #COMPOSITE
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@AccessControl.privilegedAssociations: ['_User']
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.representativeKey: 'BusinessPartner'
//@ObjectModel.alternativeKey: [ { id : 'BusinessPartnerUUID', uniqueness: #UNIQUE, element: ['BusinessPartnerUUID'] },

//                               { id : 'UserID', uniqueness: #UNIQUE, element: ['UserID'] } ]

@Metadata.ignorePropagatedAnnotations:true
@ClientHandling.type: #CLIENT_DEPENDENT
@ClientHandling.algorithm : #SESSION_VARIABLE
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'I_BusinessUserBasic'
define view I_BusinessUser
  as select from           P_BPUsrPerson           as _Person
    left outer to one join P_BPUSRPERSONEXTERNALID as _BusinessPartnerExternalID on _Person.BusinessPartner = _BusinessPartnerExternalID.BusinessPartner
    inner join             usr21                                                 on _Person.BusinessPartnerUUID = usr21.bpperson
                                                                                 and(
                                                                                   usr21.idadtype               = '02'
                                                                                   or usr21.idadtype            = '04'
                                                                                 )
  association [0..1] to I_User             as _User                on $projection.UserID = _User.UserID
  association [0..1] to I_WorkplaceAddress as _WorkplaceAddress    on $projection.BusinessPartnerUUID = _WorkplaceAddress.BusinessPartnerUUID
  association [0..*] to I_BPUsrRole        as _BusinessPartnerRole on $projection.BusinessPartner = _BusinessPartnerRole.BusinessPartner
{
  key _Person.BusinessPartner                           as BusinessPartner,
      _Person.BusinessPartnerUUID                       as BusinessPartnerUUID,
      _BusinessPartnerExternalID.BPIdentificationNumber as BPIdentificationNumber,
      _Person.LastName                                  as LastName,
      _Person.FirstName                                 as FirstName,
      _Person.PersonFullName                            as PersonFullName,
      _Person.PersonFullNameMaintStatus                 as PersonFullNameMaintStatus,
      _Person.FormOfAddress                             as FormOfAddress,
      _Person.AcademicTitle                             as AcademicTitle,
      _Person.AcademicSecondTitle                       as AcademicSecondTitle,
      _Person.CorrespondenceLanguage                    as CorrespondenceLanguage,
      _Person.MiddleName                                as MiddleName,
      _Person.AdditionalLastName                        as AdditionalLastName,
      _Person.BirthName                                 as BirthName,
      _Person.NickName                                  as NickName,
      _Person.Initials                                  as Initials,
      _Person.LastNamePrefix                            as LastNamePrefix,
      _Person.LastNameSecondPrefix                      as LastNameSecondPrefix,
      _Person.NameSupplement                            as NameSupplement,
      cast( usr21.bname as vdm_userid preserving type ) as UserID,
      _Person.IsMarkedForArchiving                      as IsMarkedForArchiving,
      _Person.BusinessPartnerIsBlocked                  as BusinessPartnerIsBlocked,
      _Person.CreatedByUser                             as CreatedByUser,
      _Person.CreationDateTime                          as CreationDateTime,
      _Person.LastChangedByUser                         as LastChangedByUser,
      _Person.LastChangeDateTime                        as LastChangeDateTime,
      _Person.IsBusinessPurposeCompleted                as IsBusinessPurposeCompleted,
      _Person.AuthorizationGroup                        as AuthorizationGroup,
      @Consumption.hidden:true
      _Person.DataControllerSet                         as DataControllerSet,
      @Consumption.hidden:true
      _Person.DataController1                           as DataController1,
      @Consumption.hidden:true
      _Person.DataController2                           as DataController2,
      @Consumption.hidden:true
      _Person.DataController3                           as DataController3,
      @Consumption.hidden:true
      _Person.DataController4                           as DataController4,
      @Consumption.hidden:true
      _Person.DataController5                           as DataController5,
      @Consumption.hidden:true
      _Person.DataController6                           as DataController6,
      @Consumption.hidden:true
      _Person.DataController7                           as DataController7,
      @Consumption.hidden:true
      _Person.DataController8                           as DataController8,
      @Consumption.hidden:true
      _Person.DataController9                           as DataController9,
      @Consumption.hidden:true
      _Person.DataController10                          as DataController10,
      _User,
      _WorkplaceAddress,
      _BusinessPartnerRole
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"P_BPUSRPERSON",
"P_BPUSRPERSONEXTERNALID",
"USR21"
],
"ASSOCIATED":
[
"I_BPUSRROLE",
"I_USER",
"I_WORKPLACEADDRESS"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/