I_CmplRqRsltGHSClfnTP

@EndUserText.label: 'GHS Classification - TP'

@AbapCatalog:
{
  sqlViewName: 'IGHSCLFNTP',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #CHECK,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}

--Client Handling of the view
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM:
{
  viewType: #TRANSACTIONAL,
  lifecycle.contract.type:#SAP_INTERNAL_API
}

@ObjectModel:
{
  --Transactional Annotations for the generated BO
  modelCategory: #BUSINESS_OBJECT,
  transactionalProcessingEnabled: true,
  createEnabled: true,
  updateEnabled: true,
  deleteEnabled: true,
  writeDraftPersistence: 'EHSDSW_GHS_CLFN',
  writeActivePersistence: 'EHSDSV_GHS_CLFN',
  semanticKey:  [ 'GHSClassificationUUID' ],
  usageType:
  {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #XL,
    serviceQuality: #C
  }
}
 
define view I_CmplRqRsltGHSClfnTP
  --Select data from basic view 'GHS Classification'
  as select from I_CmplRqRsltGHSClfn

  --Link to root
  association [1..1] to I_CmplRqRsltGHSClfnAssmtTP     as _CmplRqRsltGHSClfnAssmt     on $projection.CmplRqRsltUUID = _CmplRqRsltGHSClfnAssmt.CmplRqRsltUUID

  --Target Organ Assignment for Hazard Statement 1
  association [0..*] to I_CmplRqRsltGHSClfnTgtOrgan1TP as _CmplRqRsltGHSClfnTgtOrgan1 on $projection.GHSClassificationUUID = _CmplRqRsltGHSClfnTgtOrgan1.GHSClassificationUUID

  --Target Organ Assignment for Hazard Statement 2
  association [0..*] to I_CmplRqRsltGHSClfnTgtOrgan2TP as _CmplRqRsltGHSClfnTgtOrgan2 on $projection.GHSClassificationUUID = _CmplRqRsltGHSClfnTgtOrgan2.GHSClassificationUUID

  --Regulatory Additional Information
  association [0..*] to I_CmplRqRsltGHSClfnAddlInfoTP  as _CmplRqRsltGHSClfnAddlInfo  on $projection.GHSClassificationUUID = _CmplRqRsltGHSClfnAddlInfo.GHSClassificationUUID

  --Additional Statements
  association [0..*] to I_CmplRqRsltGHSClfnAddlStmntTP as _CmplRqRsltGHSClfnAddlStmnt on $projection.GHSClassificationUUID = _CmplRqRsltGHSClfnAddlStmnt.GHSClassificationUUID

{
      --GHS Classification UUID
      @ObjectModel.mandatory: true
  key GHSClassificationUUID, 

      --cmplrqrsltuuid
      @ObjectModel.mandatory: true
      CmplRqRsltUUID, 

      --Hazard Class UUID
      @ObjectModel.mandatory: true
      GHSClfnHazardClassUUID,

      --Hazard Category UUID
      @ObjectModel.mandatory: true
      GHSClfnHazardCategoryUUID,

      --Route of Exposure UUID
      @ObjectModel.mandatory: false
      GHSClfnRouteOfExposureUUID,

      --Hazard Statement 1 UUID
      @ObjectModel.mandatory: false
      GHSClfnHazardStatement1UUID,

      --Hazard Statement 2 UUID
      @ObjectModel.mandatory: false
      GHSClfnHazardStatement2UUID,

      --Classification Procedure
      @ObjectModel.mandatory: false
      GHSClfnClassfctnProcedUUID,

      --Create at date/time and by user
      @ObjectModel.readOnly: true
      CreationDateTime,
      @ObjectModel.readOnly: true
      CreatedByUser,

      --Update at date/time and by user
      @ObjectModel.readOnly: true
      LastChangeDateTime,
      @ObjectModel.readOnly: true
      LastChangedByUser,

      /* Associations */
      _CreatedByUser,
      _LastChangedByUser,

      @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _CmplRqRsltGHSClfnAssmt,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltGHSClfnTgtOrgan1,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltGHSClfnTgtOrgan2,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltGHSClfnAddlInfo,

      @ObjectModel.association.type:  [ #TO_COMPOSITION_CHILD ]
      _CmplRqRsltGHSClfnAddlStmnt
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CMPLRQRSLTGHSCLFN"
],
"ASSOCIATED":
[
"I_CMPLRQRSLTGHSCLFNADDLINFOTP",
"I_CMPLRQRSLTGHSCLFNADDLSTMNTTP",
"I_CMPLRQRSLTGHSCLFNASSMTTP",
"I_CMPLRQRSLTGHSCLFNTGTORGAN1TP",
"I_CMPLRQRSLTGHSCLFNTGTORGAN2TP",
"I_USER"
],
"BASE":
[
"I_CMPLRQRSLTGHSCLFN"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/