I_CMPLRQRSLTGHSCLFN

@EndUserText.label: 'GHS Classification'
@AbapCatalog:
{
  sqlViewName: 'IGHSCLFN',
 --If it's true, the filter conditions are compared and, if they match, the associated join expression is evaluated only once
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #CHECK,
  privilegedAssociations:  [ '_CreatedByUser', '_LastChangedByUser' ]
}

--Client Handling of the view
@ClientHandling:
{
  algorithm: #SESSION_VARIABLE
}

--VDM view type
@VDM.viewType: #BASIC


@ObjectModel:
{
  --Performance Annotations
  usageType:
  {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #L,
    serviceQuality: #B
  }
}
 
define view I_CmplRqRsltGHSClfn
  as select from ehsdsv_ghs_clfn as ghsclass

  --Link to root
  association [1..1] to I_CmplRqRslt                 as _CmplRqRsltGHSClfnAssmt     on $projection.CmplRqRsltUUID = _CmplRqRsltGHSClfnAssmt.CmplRqRsltUUID

  --Link to child
  --Target Organ Assignment for Hazard Statement 1
  association [0..*] to I_CmplRqRsltGHSClfnTgtOrgan1 as _CmplRqRsltGHSClfnTgtOrgan1 on $projection.GHSClassificationUUID = _CmplRqRsltGHSClfnTgtOrgan1.GHSClassificationUUID

  --Target Organ Assignment for Hazard Statement 2
  association [0..*] to I_CmplRqRsltGHSClfnTgtOrgan2 as _CmplRqRsltGHSClfnTgtOrgan2 on $projection.GHSClassificationUUID = _CmplRqRsltGHSClfnTgtOrgan2.GHSClassificationUUID

  --Regulatory Additional Information
  association [0..*] to I_CmplRqRsltGHSClfnAddlInfo  as _CmplRqRsltGHSClfnAddlInfo  on $projection.GHSClassificationUUID = _CmplRqRsltGHSClfnAddlInfo.GHSClassificationUUID

  --Additional Statement
  association [0..*] to I_CmplRqRsltGHSClfnAddlStmnt as _CmplRqRsltGHSClfnAddlStmnt on $projection.GHSClassificationUUID = _CmplRqRsltGHSClfnAddlStmnt.GHSClassificationUUID

  --Link to user data
  association [0..1] to I_User                       as _CreatedByUser              on $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                       as _LastChangedByUser          on $projection.LastChangedByUser = _LastChangedByUser.UserID

{
      --GHS Classification UUID
  key ghsclass.ghsclassificationuuid                                                as GHSClassificationUUID, 

      --cmplrqrsltuuid
      ghsclass.cmplrqrsltuuid                                                       as CmplRqRsltUUID,

      --Hazard Class UUID
      ghsclass.ghsclfnhazardclassuuid                                               as GHSClfnHazardClassUUID,

      --Hazard Category UUID
      ghsclass.ghsclfnhazardcategoryuuid                                            as GHSClfnHazardCategoryUUID,

      --Route of Exposure UUID
      ghsclass.ghsclfnrouteofexposureuuid                                           as GHSClfnRouteOfExposureUUID,

      --Hazard Statement 1 UUID
      ghsclass.ghsclfnhazardstatement1uuid                                          as GHSClfnHazardStatement1UUID,

      --Hazard Statement 2 UUID
      ghsclass.ghsclfnhazardstatement2uuid                                          as GHSClfnHazardStatement2UUID,

      --Classification Procedure
      ghsclass.ghsclfnclassfctnproceduuid                                           as GHSClfnClassfctnProcedUUID,

      --Create at date/time and by user
      @Semantics.systemDateTime.createdAt: true
      cast(ghsclass.creationdatetime as ehfnd_bo_crea_date_time preserving type )   as CreationDateTime,

      @ObjectModel.readOnly: true
      @Semantics.user.createdBy: true
      cast(ghsclass.createdbyuser as ehfnd_bo_crea_uname preserving type )          as CreatedByUser,

      --Update at date/time and by user
      @Semantics.systemDateTime.lastChangedAt: true
      cast(ghsclass.lastchangedatetime as ehfnd_bo_lchg_date_time preserving type ) as LastChangeDateTime,

      @ObjectModel.readOnly: true
      @Semantics.user.lastChangedBy: true
      cast(ghsclass.lastchangedbyuser as ehfnd_bo_lchg_uname preserving type )      as LastChangedByUser,

      /* Associations */
      _CmplRqRsltGHSClfnAssmt,
      _CmplRqRsltGHSClfnTgtOrgan1,
      _CmplRqRsltGHSClfnTgtOrgan2,
      _CmplRqRsltGHSClfnAddlInfo,
      _CmplRqRsltGHSClfnAddlStmnt,
      _CreatedByUser,
      _LastChangedByUser
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"EHSDSV_GHS_CLFN"
],
"ASSOCIATED":
[
"I_CMPLRQRSLT",
"I_CMPLRQRSLTGHSCLFNADDLINFO",
"I_CMPLRQRSLTGHSCLFNADDLSTMNT",
"I_CMPLRQRSLTGHSCLFNTGTORGAN1",
"I_CMPLRQRSLTGHSCLFNTGTORGAN2",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/