I_ChgImpactMBOMRoutingLink

@AbapCatalog.sqlViewName:'ICHIMPMBOMROULNK'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Manufacturing BOMs Linked with Routing'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
define view I_ChgImpactMBOMRoutingLink

  as select from I_BOOVersionBOMAssignment as MfgBOMRoutingLink
  inner join   I_BillOfOperationsVersion as BOOVersion on  BOOVersion.BillOfOperationsGroup   = MfgBOMRoutingLink.BillOfOperationsGroup
                                                         and BOOVersion.BillOfOperationsType    = MfgBOMRoutingLink.BillOfOperationsType
                                                         and BOOVersion.BillOfOperationsVariant = MfgBOMRoutingLink.BillOfOperationsVariant
                                                         and BOOVersion.BillOfOperationsVersion = MfgBOMRoutingLink.BillOfOperationsVersion
  
  association [0..*] to I_MaterialBOM          as _MaterialBOM          on  MfgBOMRoutingLink.BillOfMaterial             = _MaterialBOM.BillOfMaterial
                                                                        and MfgBOMRoutingLink.BillOfMaterialVariant      = _MaterialBOM.BillOfMaterialVariant
                                                                        and MfgBOMRoutingLink.BillOfMaterialVariantUsage = _MaterialBOM.BillOfMaterialVariantUsage
                                                                        and MfgBOMRoutingLink.BillOfMaterialVersion      = _MaterialBOM.BillOfMaterialVersion
  association [0..1] to I_BOOVersionStatusText as _BOOVersionStatusText on  $projection.billofoperationsversionstatus = _BOOVersionStatusText.BillOfOperationsVersionStatus
                                                                        and _BOOVersionStatusText.Language            = $session.system_language
{

  key    MfgBOMRoutingLink.BillOfOperationsGroup,
  key    MfgBOMRoutingLink.BillOfOperationsType,
  key    MfgBOMRoutingLink.BillOfOperationsVariant,
  key    MfgBOMRoutingLink.BillOfOperationsVersion,
  key    _MaterialBOM.BillOfMaterialHeaderUUID as MfgBillOfMaterialHeaderUUID,
  key    MfgBOMRoutingLink.BillOfMaterial,
  key    MfgBOMRoutingLink.BillOfMaterialVariant,
  key    MfgBOMRoutingLink.BillOfMaterialVersion,
  key    MfgBOMRoutingLink.ProdnRtgVersBOMInternalID,
  key    MfgBOMRoutingLink.BillOfMaterialVariantUsage,
  key    MfgBOMRoutingLink.BillOfMaterialCategory,
         MfgBOMRoutingLink.Material,
         MfgBOMRoutingLink.Plant,
         @ObjectModel.text.association:'_BOOVersionStatusText'
         MfgBOMRoutingLink._BillOfOperationsVersion.BillOfOperationsVersionStatus,
         MfgBOMRoutingLink._BillOfOperations.BillOfOperationsSubtype,
         _BillOfOperationsVersion._CreatedByUser.UserID,

         //_BillOfOperations._BillOfOperationsChangeState.ValidityStartDate,

         //_BillOfOperations._BillOfOperationsChangeState.ValidityEndDate,


         _MaterialBOM,
         MfgBOMRoutingLink._BillOfOperations,
         _BOOVersionStatusText
         //  _Plant,

         //  _Material



//Changes done with respect to order specific routing - to filter out Order specific routings - 1909

//If there is an Order ID associated with the routing - filter it out

//This view will give only master routings

}
where
  BOOVersion.OrderID = ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSVERSION",
"I_BOOVERSIONBOMASSIGNMENT",
"I_MATERIALBOM",
"I_USER"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONS",
"I_BOOVERSIONSTATUSTEXT",
"I_MATERIALBOM"
],
"BASE":
[
"I_BOOVERSIONBOMASSIGNMENT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/