I_BillOfOperationsVersion

@AbapCatalog.sqlViewName: 'IBOOVERSION'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@Analytics: {dataCategory: #DIMENSION}
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@ObjectModel.representativeKey: 'BillOfOperationsVersion'
@EndUserText.label: 'Bill of Operations Version'
@Metadata.allowExtensions:true
define view I_BillOfOperationsVersion
  as select from plvk

  association [1..1] to I_BillOfOperationsType  as _BillOfOperationsType  on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [1..1] to I_BillOfOperationsGroup as _BillOfOperationsGroup on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                          and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup

  association [1..1] to I_BillOfOperations      as _BillOfOperations      on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                          and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                          and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  /*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
  association [1..1] to I_BOOVersionStatus      as _BOOVersionStatus      on  $projection.BillOfOperationsVersionStatus = _BOOVersionStatus.BillOfOperationsVersionStatus

  association [1..1] to I_User                  as _CreatedByUser         on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                  as _LastChangedByUser     on  $projection.LastChangedByUser = _LastChangedByUser.UserID

{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plnty                                                       as   BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plnnr                                                       as   BillOfOperationsGroup,
      @ObjectModel.foreignKey.association: '_BillOfOperations'
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BillOfOperationsStdVH', element: 'BillOfOperationsVariant' } } ]
  key plnal                                                       as   BillOfOperationsVariant,
  key versn                                                       as   BillOfOperationsVersion,

      @ObjectModel.foreignKey.association: '_BOOVersionStatus'
      status                                                      as   BillOfOperationsVersionStatus,
      last_versn                                                  as   IsLatestBOOVersion,
      num_suc                                                     as   NumberOfBOOVersionSuccessors,

      -- Order specific Routing
      aufnr                                                       as   OrderID,

      -- Reference to Origin
      source_plnty                                                as   BillOfOperationsRefType,
      source_plnnr                                                as   BillOfOperationsRefGroup,
      source_plnal                                                as   BillOfOperationsRefVariant,
      source_versn                                                as   BOOReferenceVersion,

      -- Administrative Data
      @Semantics.user.createdBy: true
      cast(created_by as vdm_createdbyuserid preserving type)     as   CreatedByUser,
      //@Semantics.systemDateTime.createdAt: true

      created_at                                                  as   CreationDateTime,
      @Semantics.user.lastChangedBy: true
      cast(changed_by as vdm_lastchangedbyuserid preserving type) as   LastChangedByUser,
      //@Semantics.systemDateTime.lastChangedAt: true

      changed_at                                                  as   LastChangeDateTime,

      // **************************** Associations *****************************


      _BOOVersionStatus,
      _BillOfOperations,
      _BillOfOperationsGroup,
      _BillOfOperationsType,
      _CreatedByUser,
      _LastChangedByUser
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"PLVK"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_BOOVERSIONSTATUS",
"I_USER"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/