I_BOOVERSIONBOMASSIGNMENT

CDS View

Bill of Operations Version BOM Assignment

I_BOOVERSIONBOMASSIGNMENT is a CDS View in S/4HANA. Bill of Operations Version BOM Assignment. It contains 13 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 13 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
C_ChgImpactRoutingMBOM view from CONSUMPTION MBOMs list for the Routing
I_ChgImpactMBOMRoutingLink view from COMPOSITE Manufacturing BOMs Linked with Routing
I_MfgWorkInstrnBOMAssgmtTP view from TRANSACTIONAL Embedded WI: Assigned MBOMs
I_ProductionModel view_entity inner COMPOSITE Production Model Header

Fields (13)

KeyField CDS FieldsUsed in Views
KEY BillOfMaterial BillOfMaterial 1
KEY BillOfMaterialCategory BillOfMaterialCategory 1
KEY BillOfMaterialVariant BillOfMaterialVariant 1
KEY BillOfMaterialVariantUsage BillOfMaterialVariantUsage 1
KEY BillOfMaterialVersion BillOfMaterialVersion 2
KEY BillOfOperationsGroup BillOfOperationsGroup 1
KEY BillOfOperationsType BillOfOperationsType 1
KEY BillOfOperationsVariant BillOfOperationsVariant 1
KEY BillOfOperationsVersion BillOfOperationsVersion 2
KEY ProdnRtgVersBOMInternalID ProdnRtgVersBOMInternalID 1
_BillOfOperations _BillOfOperations 1
Material Material 1
Plant Plant 1 
@AbapCatalog.sqlViewName: 'IBOOVERSBOMASS'
@AbapCatalog.compiler.compareFilter:true 
@AbapCatalog.preserveKey:true 
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #M, dataClass: #MASTER }
@ObjectModel.representativeKey: 'ProdnRtgVersBOMInternalID'
@EndUserText.label: 'Bill of Operations Version BOM Assignment'

define view I_BOOVersionBOMAssignment
  as select from plmb

  association [1..1] to I_BillOfOperationsType    as _BillOfOperationsType    on  $projection.BillOfOperationsType = _BillOfOperationsType.BillOfOperationsType
  association [1..1] to I_BillOfOperationsGroup   as _BillOfOperationsGroup   on  $projection.BillOfOperationsType  = _BillOfOperationsGroup.BillOfOperationsType
                                                                              and $projection.BillOfOperationsGroup = _BillOfOperationsGroup.BillOfOperationsGroup
  association [1..1] to I_BillOfOperations        as _BillOfOperations        on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                              and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                              and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  association [1..1] to I_BillOfOperationsVersion as _BillOfOperationsVersion on  $projection.BillOfOperationsType    = _BillOfOperationsVersion.BillOfOperationsType
                                                                              and $projection.BillOfOperationsGroup   = _BillOfOperationsVersion.BillOfOperationsGroup
                                                                              and $projection.BillOfOperationsVariant = _BillOfOperationsVersion.BillOfOperationsVariant
                                                                              and $projection.BillOfOperationsVersion = _BillOfOperationsVersion.BillOfOperationsVersion

  association [1..1] to I_Plant                   as _Plant                   on  $projection.Plant = _Plant.Plant
  association [1..1] to I_Material                as _Material                on  $projection.Material = _Material.Material

  association [1..1] to I_MaterialBOM             as _BOMVersion              on  $projection.BillOfMaterialVariantUsage = _BOMVersion.BillOfMaterialVariantUsage
                                                                              and $projection.BillOfMaterial             = _BOMVersion.BillOfMaterial
                                                                              and $projection.BillOfMaterialVariant      = _BOMVersion.BillOfMaterialVariant
                                                                              and $projection.BillOfMaterialCategory     = _BOMVersion.BillOfMaterialCategory
                                                                              and $projection.BillOfMaterialVersion      = _BOMVersion.BillOfMaterialVersion

{
      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plnty     as BillOfOperationsType,

      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plnnr     as BillOfOperationsGroup,

      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key plnal     as BillOfOperationsVariant,

      @ObjectModel.foreignKey.association: '_BillOfOperationsVersion'
  key versn     as BillOfOperationsVersion,

  key zuonr     as ProdnRtgVersBOMInternalID,

      @ObjectModel.foreignKey.association: '_Material'
      matnr     as Material,
      @ObjectModel.foreignKey.association: '_Plant'
      werks     as Plant,

      stlty     as BillOfMaterialCategory,
      stlan     as BillOfMaterialVariantUsage,
      stlnr     as BillOfMaterial,
      stlal     as BillOfMaterialVariant,
      @ObjectModel.foreignKey.association: '_BOMVersion'
      bom_versn as BillOfMaterialVersion,

      _BillOfOperationsType,
      _BillOfOperationsGroup,
      _BillOfOperations,
      _BillOfOperationsVersion,
      _Material,
      _Plant,
      _BOMVersion

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"PLMB"
],
"ASSOCIATED":
[
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSGROUP",
"I_BILLOFOPERATIONSTYPE",
"I_BILLOFOPERATIONSVERSION",
"I_MATERIAL",
"I_MATERIALBOM",
"I_PLANT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More