C_ChgRecdRefCutPlngPrflMatVH

DDL: C_CHGRECDREFCUTPLNGPRFLMATVH SQL: CCPPMATVH Type: view CONSUMPTION

Material for Cut Planning Profile

C_ChgRecdRefCutPlngPrflMatVH is a Consumption CDS View that provides data about "Material for Cut Planning Profile" in SAP S/4HANA. It reads from 1 data source (I_BillOfOperations) and exposes 7 fields with key fields Material, Plant, BillOfOperationsGroup, BillOfOperationsVariant, BillOfOperationsType.

1 data source(s) 7 fields

Data Sources (1)

SourceAliasJoin Type
I_BillOfOperations _BillOfOperations from

Annotations (13)

NameValueLevelField
AbapCatalog.sqlViewName CCPPMATVH view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
VDM.viewType #CONSUMPTION view
EndUserText.label Material for Cut Planning Profile view
ObjectModel.representativeKey BillOfOperationsGroup view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.sizeCategory #S view
ClientHandling.algorithm #SESSION_VARIABLE view
AbapCatalog.preserveKey true view
Search.searchable true view
ObjectModel.dataCategory #VALUE_HELP view

Fields (7)

KeyFieldSource TableSource FieldDescription
KEY Material _BOOMaterialAssgmtChangeState Material Material
KEY Plant _BOOMaterialAssgmtChangeState Plant
KEY BillOfOperationsGroup Group
KEY BillOfOperationsVariant BillOfOperationsVariant
KEY BillOfOperationsType BillOfOperationsType
BillOfOperationsUsage
_BOOMaterialAssgmtChangeState _BOOMaterialAssgmtChangeState 
@AbapCatalog.sqlViewName: 'CCPPMATVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION

@EndUserText.label: 'Material for Cut Planning Profile'

@ObjectModel.representativeKey: 'BillOfOperationsGroup'
@ObjectModel.usageType: {serviceQuality: #C,
                          dataClass: #MIXED,
                          sizeCategory: #S}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@Search.searchable: true
@ObjectModel.dataCategory: #VALUE_HELP

define view C_ChgRecdRefCutPlngPrflMatVH as select from I_BillOfOperations as _BillOfOperations
    
    association[0..*] to I_BOOMaterialAssgmtChangeState as _BOOMaterialAssgmtChangeState on $projection.BillOfOperationsType    = _BOOMaterialAssgmtChangeState.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup   = _BOOMaterialAssgmtChangeState.BillOfOperationsGroup
                                                                                        and $projection.BillOfOperationsVariant = _BOOMaterialAssgmtChangeState.BillOfOperationsVariant 
                                                                                       
 {
  @EndUserText.label: 'Material'
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  key _BOOMaterialAssgmtChangeState.Material, 
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  key _BOOMaterialAssgmtChangeState.Plant,
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.9
  @EndUserText.label: 'Group'
  key cast( BillOfOperationsGroup as r_plnnr preserving type) as BillOfOperationsGroup,
  @Search.defaultSearchElement: true
  key BillOfOperationsVariant,
  @Search.defaultSearchElement: true
  @UI.hidden: true
  key BillOfOperationsType,
  @Search.defaultSearchElement: true
  @Search.fuzzinessThreshold: 0.8
  cast(_BillOfOperations._BillOfOperationsChangeState[1: ValidityStartDate <= $session.system_date 
  and ValidityEndDate >= $session.system_date].BillOfOperationsDesc as r_rbez preserving type) as BillOfOperationsDesc ,
  @Search.defaultSearchElement: true
  _BillOfOperations._BillOfOperationsChangeState[1: ValidityStartDate <= $session.system_date
  and ValidityEndDate >= $session.system_date].BillOfOperationsUsage,
  @Search.defaultSearchElement: true
  cast(_BillOfOperations._BillOfOperationsChangeState[1: ValidityStartDate <= $session.system_date
  and ValidityEndDate >= $session.system_date].BillOfOperationsStatus as r_statu preserving type) as BillOfOperationsStatus,
      
  _BOOMaterialAssgmtChangeState
} 
    where BillOfOperationsType = '3'
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BILLOFOPERATIONS",
"I_BILLOFOPERATIONSCHANGESTATE",
"I_BOOMATERIALASSGMTCHANGESTATE"
],
"ASSOCIATED":
[
"I_BOOMATERIALASSGMTCHANGESTATE"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/

Learn More