C_Bank

@AbapCatalog.sqlViewName: 'CBANKFS'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Bank Factsheet'
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #M
@VDM.viewType: #CONSUMPTION
@Consumption.semanticObject: 'Bank'

@UI.headerInfo:{

  typeName: 'Bank',
  typeNamePlural: 'Bank',
  title:{label:'Bank',value:'Bank'},
  description:{label:'Bank Name',value:'BankName'}

}
define view C_Bank as select from I_Bank_2 as Bank
association[0..*] to C_HouseBank as _HouseBank on $projection.Bank = _HouseBank.Bank
                                                 and $projection.BankCountry = _HouseBank.BankCountry
association[0..1] to I_CountryText as _CountryText on $projection.BankCountry = _CountryText.Country
                                                  and _CountryText.Language = $session.system_language
association[0..1] to I_RegionText as _RegionText on $projection.Region = _RegionText.Region
                                                and $projection.BankCountry = _RegionText.Country
                                                and _RegionText.Language = $session.system_language                                              
{

    @UI.facet:[
              {
                label:'General Information',
                id:'GeneralInfo',
                type:#COLLECTION,
                position:10
              },
              {
                label:'House Banks',
                id:'HouseBank',
                type:#LINEITEM_REFERENCE,
                position:20,
                targetElement:'_HouseBank'
              },
              {
                label:'Address',
                id:'Address',
                type:#FIELDGROUP_REFERENCE,
                position:20,
                parentId:'GeneralInfo',
                targetQualifier:'Address'
              },
              {
                label:'Control Data',
                id:'ControlData',
                type:#FIELDGROUP_REFERENCE,
                position:10,
                parentId:'GeneralInfo',
                targetQualifier:'ControlData'
              }

   ]
   @UI.lineItem:{position:10, importance:#HIGH}
   @UI.dataPoint:{title:'Bank Country/Region'}
   @ObjectModel.text.element: 'CountryName'
   @UI.textArrangement: #TEXT_LAST
   @UI.selectionField: [{position:10 }]
   @Consumption.valueHelpDefinition: [
    { entity:  { name:    'C_BankCountryVH',
           element: 'BankCountry' }
    }]   
   key  Bank.BankCountry,
   @UI.lineItem:{position:20, importance:#HIGH}
   @ObjectModel.text.element: ['BankName']
   @UI.textArrangement: #TEXT_LAST
   @UI.selectionField: [{position:20 }]
   @Consumption.valueHelpDefinition: [
      { entity:  { name:    'I_BankStdVH',
                  element: 'BankInternalID' },
       additionalBinding: [{ localElement: 'BankCountry',
                             element: 'BankCountry' }]
      }]   
   key  Bank.BankInternalID as Bank,
   Bank.BankName,
   @UI.fieldGroup:{position:20,qualifier:'ControlData'}
   @UI.textArrangement: #TEXT_LAST
   @ObjectModel.text.element: ['InternalBankCategoryDesc']
   Bank._BankAdditionalFields.InternalBankCategory,
   Bank._BankAdditionalFields._BankCategory[1:Language = $session.system_language ].InternalBankCategoryDesc,   
   @UI.identification:{position:20,importance:#HIGH,label:'City'}
   @UI.dataPoint:{title:'City'}
   Bank.ShortCityName,
   @UI.identification:{position:10,importance:#HIGH,label:'Country/Region'}
   @EndUserText.label: 'Bank Country/Region Name'
   _CountryText.CountryName,
   @UI.fieldGroup:{position:10,qualifier:'Address'}
   @ObjectModel.text.element: 'RegionName'
   @UI.textArrangement: #TEXT_LAST
   Bank.Region,  
   _RegionText.RegionName,
   @UI.fieldGroup:{position:20,qualifier:'Address'}   
   Bank.ShortStreetName,
   @UI.fieldGroup:{position:30,qualifier:'Address'}
   Bank.BankBranch,
   @UI.fieldGroup:{position:10,label:'SWIFT Code',qualifier:'ControlData'}
   @UI.lineItem:{position:30,importance:#HIGH}
   Bank.SWIFTCode,
   @UI.fieldGroup:{position:40,label:'Is Postbank Account',qualifier:'ControlData'}
   Bank.IsPostBankAccount,
   @UI.fieldGroup:{position:30,label:'Bank Number',qualifier:'ControlData'}
   @UI.lineItem:{position:50,importance:#HIGH}
   Bank.Bank as BankNumber,
   @UI.fieldGroup:{position:50,label:'Post Bank Account Number',qualifier:'ControlData'}
   Bank.PostOfficeBankAccount,
   @UI.fieldGroup:{position:30,label:'Bank Group',qualifier:'ControlData'}
   @UI.lineItem:{position:40,importance:#HIGH}
   Bank.BankNetworkGrouping,
 //  _BankCategory.bintk as BankCategory,   

   _HouseBank

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_BANKADDITIONALFIELDS",
"I_BANK_2",
"I_COUNTRYTEXT",
"I_INTERNALBANKCATEGORY",
"I_REGIONTEXT"
],
"ASSOCIATED":
[
"C_HOUSEBANK",
"I_COUNTRYTEXT",
"I_REGIONTEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/