I_BPFaxNumber

@AbapCatalog.sqlViewName: 'IBPFAXNUMBER'
@EndUserText.label: 'BP Fax number core view'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@Analytics : {dataCategory: #DIMENSION}      // Need to check

@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'AddressID' // Need to check


@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.dataClass: #MASTER
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true

define view I_BPFaxNumber
    as select from I_AddressFaxNumber_2
        inner join but020 on I_AddressFaxNumber_2.AddressID = but020.addrnumber

  association [1..1] to I_BusinessPartner as _BusinessPartner on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  
  association [0..1] to I_BPProtectedAddress as _BPProtectedAddress on $projection.BusinessPartner = _BPProtectedAddress.BusinessPartner
                                                                   and $projection.AddressID = _BPProtectedAddress.AddressID
  
{
  key but020.partner as BusinessPartner,
  key I_AddressFaxNumber_2.AddressID,
  key I_AddressFaxNumber_2.AddressPersonID as Person,
  key I_AddressFaxNumber_2.CommMediumSequenceNumber as OrdinalNumber,
      I_AddressFaxNumber_2.FaxNumberIsCurrentDefault as IsDefaultFaxNumber,
      I_AddressFaxNumber_2.FaxNumberCountry as FaxCountry,
      I_AddressFaxNumber_2.FaxAreaCodeSubscriberNumber as FaxNumber,
      I_AddressFaxNumber_2.FaxExtensionNumber as FaxNumberExtension,
      I_AddressFaxNumber_2.InternationalFaxNumber,
      cast ( '' as ad_flnouse ) as CommNumberIsNotUsed, 
      cast ( I_AddressFaxNumber_2.ValidityStartDate as ad_valfrom ) as ValidityStartDateTime,
      cast ( I_AddressFaxNumber_2.ValidityEndDate as ad_valto ) as ValidityEndDateTime, 
           
      _BusinessPartner,
      _BPProtectedAddress,
      I_AddressFaxNumber_2._FaxNumberCountry as _FaxNumberCountry,
      I_AddressFaxNumber_2._AddressCommunicationRemark
      
}
where
  (I_AddressFaxNumber_2.AddressPersonID = ' ' or _BusinessPartner.BusinessPartnerCategory = '1') //Do not return Person Workplace Addresses

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_ADDRESSFAXNUMBER_2",
"I_BUSINESSPARTNER",
"BUT020"
],
"ASSOCIATED":
[
"I_ADDRESSCOMMUNICATIONREMARK_2",
"I_BPPROTECTEDADDRESS",
"I_BUSINESSPARTNER",
"I_COUNTRY"
],
"BASE":
[
"I_ADDRESSFAXNUMBER_2"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/